简介
写了两篇简单光照模型的shader的文章，虽然Unity自带的shader就有diffuse和specular，效果还比自己写的好，然而要想学好shader，基础还是很重要的。不然到网上到处找shader，扔到项目里，能用就好，完全不看性能的话，迟早会出事的。今天不看光照模型了，物理渲染还没搞懂，所以只好先来个简单的shader玩一玩。正好最近在和某基友玩黑魂，这货一出来总是自带一个特效-边缘光。于是本人强迫症发作，决定研究一下这个怎么实现。
RimLight--边缘发光效果，是一个比较常用的效果，实现简单，在普通的光照计算后只需要两步操作，就可以实现边缘光效果。看下面一幅图，简单介绍一下RimLight的原理：
所谓RimLight边缘发光，也就是说对应我们当前视角方向，物体上位于边缘的地方额外加一个光的效果。那么，怎么判断一个点是否在物体的边缘呢？就是通过法线方向和视线方向的夹角来判断。当视线方向V与法线方向N垂直时，这个法线对应的面就与视线方向平行，说明当前这个点对于当前视角来说，就处在边缘；而视线方向与法线方向一致时，这个法线对应的面就垂直于视线方向，说明当前是直视这个面。所以，我们就可以根据dot（N,V）来获得视线方向与法线方向的余弦值，通过这个值来区分该像素是否处在边缘，进而判断是否需要增加以及增加边缘光的强弱。
边缘光效果Unity下的实现
上面已经说完了边缘光效果的实现原理，下面附上完整的边缘光效果shader，基于之前介绍过的
兰伯特光照模型，增加了边缘光效果：
白色边缘光效果：
黄色边缘光效果：
通过Mask图控制边缘光
我们把边缘光效果加大到一定程度，就快成了自发光效果，但是上面的shader有个问题，就是全身都会自发光。如下图所示：
如果只希望盔甲部分有自发光效果，而其他部分没有自发光，我们就需要用Mask图来控制了，我们用一张Alpha8的灰度图来控制是否开启边缘光效果，将上面的shader简单修改一下，增加Mask图的通道：
//边缘发光Shader
//by：puppet_master
//2016.12.11
Shader "ApcShader/RimLight"
{
//属性
Properties{
_Diffuse("Diffuse", Color) = (1,1,1,1)
_RimColor("RimColor", Color) = (1,1,1,1)
_RimPower("RimPower", Range(0.000001, 20.0)) = 0.1
_RimMask("RimMask", 2D) = "white"{}
_MainTex("Base 2D", 2D) = "white"{}
}
//子着色器
SubShader
{
Pass
{
//定义Tags
Tags{ "RenderType" = "Opaque" }
CGPROGRAM
//引入头文件
#include "Lighting.cginc"
//定义Properties中的变量
fixed4 _Diffuse;
sampler2D _MainTex;
//使用了TRANSFROM_TEX宏就需要定义XXX_ST
float4 _MainTex_ST;
sampler2D _RimMask;
fixed4 _RimColor;
float _RimPower;
//定义结构体：vertex shader阶段输出的内容
struct v2f
{
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float2 uv : TEXCOORD1;
//在vertex shader中计算观察方向传递给fragment shader
float3 worldViewDir : TEXCOORD2;
};
//定义顶点shader,参数直接使用appdata_base（包含position, noramal, texcoord）
v2f vert(appdata_base v)
{
v2f o;
o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
//通过TRANSFORM_TEX宏转化纹理坐标，主要处理了Offset和Tiling的改变,默认时等同于o.uv = v.texcoord.xy;
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
o.worldNormal = mul(v.normal, (float3x3)_World2Object);
//顶点转化到世界空间
float3 worldPos = mul(_Object2World, v.vertex).xyz;
//可以把计算计算ViewDir的操作放在vertex shader阶段，毕竟逐顶点计算比较省
o.worldViewDir = _WorldSpaceCameraPos.xyz - worldPos;
return o;
}
//定义片元shader
fixed4 frag(v2f i) : SV_Target
{
//unity自身的diffuse也是带了环境光，这里我们也增加一下环境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * _Diffuse.xyz;
//归一化法线，即使在vert归一化也不行，从vert到frag阶段有差值处理，传入的法线方向并不是vertex shader直接传出的
fixed3 worldNormal = normalize(i.worldNormal);
//把光照方向归一化
fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
//根据半兰伯特模型计算像素的光照信息
fixed3 lambert = 0.5 * dot(worldNormal, worldLightDir) + 0.5;
//最终输出颜色为lambert光强*材质diffuse颜色*光颜色
fixed3 diffuse = lambert * _Diffuse.xyz * _LightColor0.xyz + ambient;
//进行纹理采样
fixed4 color = tex2D(_MainTex, i.uv);
//以下为本篇主题：计算RimLight
//把视线方向归一化
float3 worldViewDir = normalize(i.worldViewDir);
//计算视线方向与法线方向的夹角，夹角越大，dot值越接近0，说明视线方向越偏离该点，也就是平视，该点越接近边缘
float rim = 1 - max(0, dot(worldViewDir, worldNormal));
//计算RimLight
fixed3 rimColor = _RimColor * pow(rim, 1 / _RimPower);
//通过RimMask控制是否有边缘光,Rim目前存在一张Alpha8类型的图片中
fixed rimMask = tex2D(_RimMask, i.uv).a;
//输出颜色+边缘光颜色
color.rgb = color.rgb* diffuse + rimColor * (1 - rimMask);
return fixed4(color);
}
//使用vert函数和frag函数
#pragma vertex vert
#pragma fragment frag
ENDCG
}
}
//前面的Shader失效的话，使用默认的Diffuse
FallBack "Diffuse"
}
我们把下面这张自发光Mask图赋给材质：
通过采样这张Mask就能控制那部分开启自发光，那部分关闭自发光了：
调整Mask图，也可以得到一些比较好玩的效果：
动态RimLight效果
看了一篇博文，其中的边缘光使用了一张动态图，达到了流动的效果，感谢
作者的无私分享，于是我也尝试一下动态RimLight的效果。其实思路跟上面的Mask图一样，只不过这次改成一张扫面线类型的纹理，然后通过这张纹理的采样滚动，达到动态的效果。一提到动态效果，我们第一个想到的应该就是_Time向量，这个向量中几个值都是跟时间相关的，我们如果做动态效果，肯定少不了和这个变量打交道，关于_Time及其变种，可以参考
这篇文章，我们这里用_Time.y就可以获得时间了。
我们用一张Mask纹理，白色代表有边缘光，黑色无边缘光，通过采样这张Mask纹理，控制模型上显示边缘光的部分：
动态RimLight的shader如下：
Unity Shader中可用的变量类型整理
在传递参数时总是忘了能传递哪些类型的参数，记录一下，方便以后查找，这种东西也没必要死记硬背下来，需要的时候几秒钟之内能找到就好了。
原文地址：http://blog.youkuaiyun.com/puppet_master/article/details/53548134
168
扫一扫
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
