unity-shader前向渲染中shadowcast阴影和光照衰减

先上效果图后上代码最后解释知识点：（如果感觉此篇讲的不够详细，请查看前面两篇 前向渲染和阴影产生和投射的介绍）
（1）一个主光源效果：3个plane，2个cube搭建场景
两盏方向光的效果：

再添加三盏点光源的效果：可以看到墙面上红色箭头指向的3个阴影

（2）代码如下：

Shader "Unlit/shadowCast02"
{
    Properties
	{
		_Diffuse("Diffuse",Color) = (1,1,1,1)
		_Specular("Specular",Color) = (1,1,1,1)
		_Gloss("Gloss",Range(8.0,256)) = 20
	}
		SubShader
	{
		Tags { "RenderType" = "Opaque" }
		LOD 100

		Pass
		{
			Tags{"LightMode"="ForwardBase"}
			CGPROGRAM
			#pragma multi_compile_fwdbase
			#pragma vertex vert
			#pragma fragment frag


			#include "UnityCG.cginc"
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
				float3 normal:NORMAL;
            };

            struct v2f
            {

				float4 pos : SV_POSITION;
				float3 worldNormal:TEXCOORD0;
				float3 worldPos:TEXCOORD1;
				float3 vertexLight : TEXCOORD2;
				//仅仅是阴影
                //SHADOW_COORDS(3)
                LIGHTING_COORDS(3,4) //阴影+衰减
                //#define LIGHTING_COORDS(idx1, idx2) DECLARE_LIGHT_COORDS(idx1) SHADOW_COORDS(idx2)
            };

            v2f vert (appdata v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
#ifdef LIGHTMAP_OFF
				float3 shLight = ShadeSH9(float4(v.normal,1.0));
				o.vertexLight = shLight;
#ifdef VERTEXLIGHT_ON
				float3 vertexLight = Shade4PointLights(unity_4LightPosX0, unity_4LightPosY0, unity_4LightPosZ0,unity_LightColor[0].rgb,
					unity_LightColor[1].rgb, unity_LightColor[2].rgb, unity_LightColor[3].rgb,
					unity_4LightAtten0,o.worldPos,o.worldNormal);
				o.vertexLight += vertexLight;
#endif
#endif
				//只含阴影
				//TRANSFER_SHADOW(o);
                //包含光照衰减和阴影				
                TRANSFER_VERTEX_TO_FRAGMENT(o);
                //#define TRANSFER_VERTEX_TO_FRAGMENT(a) COMPUTE_LIGHT_COORDS(a) TRANSFER_SHADOW(a)
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));

				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
				fixed3 halfDir = normalize(viewDir + worldLightDir);
				fixed3 specualr = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
                //包含光照衰减以及阴影，但是base光源一般没有衰减
				UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
                return fixed4((ambient + diffuse + specualr)*atten,1);
			}
				ENDCG
	}
		Pass
		{
				Tags{ "LightMode" = "ForwardAdd" }
					Blend One One
					CGPROGRAM
					//特别注意此处，不添加“_fullshadows”是不能正确计算阴影的
					#pragma multi_compile_fwdadd_fullshadows
					#pragma vertex vert
					#pragma fragment frag
					#include "UnityCG.cginc"
					#include "Lighting.cginc"
					#include "AutoLight.cginc"

					fixed4 _Diffuse;
					fixed4 _Specular;
					float _Gloss;

					struct a2v {
						float3 vertex:POSITION;
						float3 normal : NORMAL;
					};
					struct v2f {
						float4 pos:SV_POSITION;
						float3 worldNormal:TEXCOORD0;
						float3 worldPos : TEXCOORD1;
						LIGHTING_COORDS(2,3)
					};

					v2f vert(a2v v)
					{
						v2f o;
						o.pos = UnityObjectToClipPos(v.vertex);
						o.worldNormal = UnityObjectToWorldNormal(v.normal);
						o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
						TRANSFER_VERTEX_TO_FRAGMENT(o);
						return o;
					}
					fixed4 frag(v2f i) :SV_Target
					{
						fixed3 worldNormal = normalize(i.worldNormal);
						fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

						fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));

						fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
						fixed3 halfDir = normalize(worldLightDir + viewDir);
						fixed3 specualr = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);

						fixed atten = LIGHT_ATTENUATION(i);


						return fixed4((diffuse + specualr)*atten, 1);
					}
				ENDCG
		}
        Pass 
		{
			Tags { "LightMode" = "ShadowCaster" }

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#pragma target 2.0
			#pragma multi_compile_shadowcaster
			#pragma multi_compile_instancing // allow instanced shadow pass for most of the shaders
			#include "UnityCG.cginc"

			struct v2f {
				V2F_SHADOW_CASTER;
				UNITY_VERTEX_OUTPUT_STEREO
			};

			v2f vert( appdata_base v )
			{
				v2f o;
				UNITY_SETUP_INSTANCE_ID(v);
				UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(o);
				TRANSFER_SHADOW_CASTER_NORMALOFFSET(o)
				return o;
			}

			float4 frag( v2f i ) : SV_Target
			{
				SHADOW_CASTER_FRAGMENT(i)
			}
			ENDCG

		}
    
    }
}

将主光源外的光都设置为important：

查看FrameDebug：在产生阴影映射纹理的阶段，共渲染了三次RenderShadowMap,第一次主光源，第二次另一个平行光，第三次剩余的点光源（高达70次drawcall）
从frameDubeg可以看出：最后的渲染阶段（红框内）和普通的前向渲染没有区别，耗费的都是计算shadowMap上面了。
（3）将主光源外的光都设置为notImport，然后查看效果，阴影只有base光源的计算了，球谐光照和逐顶点光照并没有计算阴影：
（4）关于阴影和衰减统一到一个函数中计算，代码中都有注释解释和函数的定义代码
（5）相关的知识点前面都讲过了，这篇就不再多说了，说一下常用的Blend命令的总结：
Blend One One：//效果叠加
Blend SrcAlpha OneMinusSrcAlpha // 传统透明度
Blend One OneMinusSrcAlpha // 预乘透明度
Blend One One // 叠加
Blend OneMinusDstColor One // 柔和叠加
Blend DstColor Zero // 相乘——正片叠底
Blend DstColor SrcColor // 两倍相乘