洛谷 P1090 合并果子

题目描述

在一个果园里，多多已经将所有的果子打了下来，而且按果子的不同种类分成了不同的堆。多多决定把所有的果子合成一堆。

每一次合并，多多可以把两堆果子合并到一起，消耗的体力等于两堆果子的重量之和。可以看出，所有的果子经过n-1次合并之后，就只剩下一堆了。多多在合并果子时总共消耗的体力等于每次合并所耗体力之和。

因为还要花大力气把这些果子搬回家，所以多多在合并果子时要尽可能地节省体力。假定每个果子重量都为1，并且已知果子的种类数和每种果子的数目，你的任务是设计出合并的次序方案，使多多耗费的体力最少，并输出这个最小的体力耗费值。

例如有3种果子，数目依次为1，2，9。可以先将1、2堆合并，新堆数目为3，耗费体力为3。接着，将新堆与原先的第三堆合并，又得到新的堆，数目为12，耗费体力为12。所以多多总共耗费体力=3+12=15。可以证明15为最小的体力耗费值。

输入输出格式

输入格式：
输入文件fruit.in包括两行，第一行是一个整数n(1<＝n<=10000)，表示果子的种类数。第二行包含n个整数，用空格分隔，第i个整数ai(1<＝ai<=20000)是第i种果子的数目。

输出格式：
输出文件fruit.out包括一行，这一行只包含一个整数，也就是最小的体力耗费值。输入数据保证这个值小于2^31。

输入输出样例

输入样例#1：
3
1 2 9
输出样例#1：
15
说明

对于30％的数据，保证有n<=1000：

对于50％的数据，保证有n<=5000；

对于全部的数据，保证有n<=10000。

分析：每次找两个最小的和并就好了。
（堆或者两个单调队列）

代码：

var
 a:array [0..10001] of longint;
 t,i,j,n,ans,x,y:longint;
procedure up(i:longint);
 var x,temp:longint;
begin
 inc(t);
 a[t]:=i;
 x:=t;
 while (x>1) and (a[x]<a[x div 2]) do
 begin
  temp:=a[x];
  a[x]:=a[x div 2];
  a[x div 2]:=temp;
  x:=x div 2;
 end;
end;
function down:longint;
 var x,s,temp:longint;
     sb:boolean;
begin
 down:=a[1];
 a[1]:=a[t];
 a[t]:=0;
 dec(t);
 x:=1;
 sb:=true;
 while sb and (x*2<=t) do
  begin
   if (x*2+1<=t) and (a[x*2+1]<a[x*2]) then s:=x*2+1
                                       else s:=x*2;
    if a[s]<a[x] then
     begin
      temp:=a[s];
      a[s]:=a[x];
      a[x]:=temp;
      x:=s;
     end
     else sb:=false;
  end;
end;
begin
 readln(n);
 for i:=1 to n do
 begin
  read(j);
  up(j);
 end;
 for i:=1 to n-1 do
  begin
  x:=down;
  y:=down;
  ans:=ans+x+y;
  up(x+y);
  end;
write(ans);
end.