Unity Shader-死亡溶解效果

最新推荐文章于 2025-05-02 10:52:29 发布

puppet_master

最新推荐文章于 2025-05-02 10:52:29 发布

阅读量4.7w

点赞数 66

CC 4.0 BY-SA版权

分类专栏：图形学 Unity3d Shader Unity Shader!!! 文章标签：图形学 shader Unity 溶解 dissolve

本文链接：https://blog.youkuaiyun.com/puppet_master/article/details/72455945

本文介绍了如何在Unity中创建具有死亡溶解效果的Shader，从基本的溶解效果开始，逐步增加过渡效果，直至实现物体沿着特定方向灰飞烟灭的视觉效果。同时，还探讨了溶解效果的多种应用场景和副产品。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

简介

游戏里面角色死亡的时候，有很多方式可以表现人物死亡效果。最简单粗暴的，播放完死亡动画直接删除或者直接Y轴逐渐降低，沉到地下；比较好的死亡效果就是今天要研究的这种效果-死亡溶解。个人印象比较深刻的就是《生化危机6》里面的克里斯篇，里面的功夫丧尸挂掉之后都是会有一个类似的死亡溶解效果。不过《生化危机6》这种3A大作的效果肯定不仅仅是一个shader能做出来的，还配合了粒子做出了消散以及着火的效果。

赶脚一般学习shader的童鞋，都会研究一下这个东东....毕竟这个效果灰常常用。今天，我也来研究一下死亡溶解效果的实现。

基本溶解效果

溶解，也就是让这个模型逐渐消失。那么，最简单的，直接让这个像素的Fragment Shader操作discard，这个像素就消失了。然后，我们要做的就是让这个溶解的对象一部分消失，另一部分存在，所以，这个时候我们就需要一个Mask图进行控制，我们采样这张Mask图，就可以得到这个像素点当前的Mask值，然后用这个Mask值与我们设定的一个阈值来进行比较，小于阈值的部分discard，大于的部分正常计算。最终，我们将这个阈值从0逐渐增加到1，就可以实现模型的一部分像素先消失，直至整个模型完全消失的效果。

简单的原理解释完了，先来一发基本的溶解效果：

//溶解效果
//by：puppet_master
//2017.5.18

Shader "ApcShader/DissolveEffect"
{
	Properties{
		_Diffuse("Diffuse", Color) = (1,1,1,1)
		_MainTex("Base 2D", 2D) = "white"{}
		_DissolveMap("DissolveMap", 2D) = "white"{}
		_DissolveThreshold("DissolveThreshold", Range(0,1)) = 0
	}
	
	CGINCLUDE
	#include "Lighting.cginc"
	uniform fixed4 _Diffuse;
	uniform sampler2D _MainTex;
	uniform float4 _MainTex_ST;
	uniform sampler2D _DissolveMap;
	uniform float _DissolveThreshold;
	
	struct v2f
	{
		float4 pos : SV_POSITION;
		float3 worldNormal : TEXCOORD0;
		float2 uv : TEXCOORD1;
	};
	
	v2f vert(appdata_base v)
	{
		v2f o;
		o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
		o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
		o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
		return o;
	}
	
	fixed4 frag(v2f i) : SV_Target
	{
		//采样Dissolve Map
		fixed4 dissolveValue = tex2D(_DissolveMap, i.uv);
		//小于阈值的部分直接discard
		if (dissolveValue.r < _DissolveThreshold)
		{
			discard;
		}
		//Diffuse + Ambient光照计算
		fixed3 worldNormal = normalize(i.worldNormal);
		fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
		fixed3 lambert = saturate(dot(worldNormal, worldLightDir));
		fixed3 albedo = lambert * _Diffuse.xyz * _LightColor0.xyz + UNITY_LIGHTMODEL_AMBIENT.xyz;
		fixed3 color = tex2D(_MainTex, i.uv).rgb * albedo;
		return fixed4(color, 1);
	}
	ENDCG
	
	SubShader
	{
		Tags{ "RenderType" = "Opaque" }
		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag	
			ENDCG
		}
	}
	FallBack "Diffuse"
}

最近找了个比较帅气的模型，先爆个照（开启了 Bloom和