【猫猫的Unity Shader之旅】之Blend语句

　　上回说过，片段经过fragment处理后，会经过混合处理，最终变为缓冲区中的颜色数据。这里的混合，指的是处理后的片段颜色与已经存在于缓冲区中的颜色进行混合。具体的混合规则使用Blend语句来指定。

Blend {code for SrcFactor} {code for DstFactor}

　　这里的code for SrcFactor和DstFactor指的是下面表格的内容：

　　

　　当使用Blend时，最终颜色被计算为result = fragment_color * SrcFactor + pixel_color * DstFactor，这个fragment_color即是经过处理的片段颜色，也就是fragment返回的结果，pixel_color是原本存在于缓冲区的颜色，因为可能渲染过其他模型嘛~这个result颜色被重新写入缓冲区，等待被其他片段Blend或者变成最终颜色(如果没有被其他Blend)。

利用Blend实现透明效果

　　Blend的一个基本的用法就是用来实现透明。对于一个半透明物体，我们需要根据透明度将颜色分为两部分，比如透明度为70%，可以认为最终颜色是70%的该片段颜色和30%的背景颜色。所以Blend语句应该为Blend SrcAlpha OneMinusSrcAlpha，完整代码如下：

Shader "Custom/SimpleAlpha" {
    Properties {
        _MainTint ("Main Color", Color) = (1, 1, 1, 1)
    }
    SubShader {
        Tags { "Queue" = "Transparent" }
        LOD 200

        Pass
        {
            Blend SrcAlpha OneMinusSrcAlpha
            ZWrite Off
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            uniform float4 _MainTint;

            float4 vert(float4 vertPos : POSITION) : SV_POSITION
            {
                return mul(UNITY_MATRIX_MVP, vertPos);
            }

            float4 frag(float4 vertPos : SV_POSITION) : COLOR
            {
                return _MainTint;
            }
            ENDCG
        }
    } 
    FallBack "Diffuse"
}

　　注意到这里有一句ZWrite Off，用来关闭写入深度缓冲区。深度缓冲区用来判断哪些片段被遮挡，被遮挡的话就不会被渲染，对于透明物体，我们不需要这样，因为我么需要看到透明物体背后的东西。具体效果如下：

　　

颜色叠加效果

　　颜色叠加常用于粒子特效，多个粒子的颜色叠加后会产生更亮的颜色，Blend语句为Blend One One，下面是个简单的例子：

Shader "Custom/Additive" {
    Properties {
        _MainTint ("Main Color", Color) = (1, 1, 1, 1)
    }
    SubShader {
        Tags { "Queue" = "Geometry" }
        LOD 200

        Pass
        {
            Blend One One
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            uniform float4 _MainTint;

            float4 vert(float4 vertPos : POSITION) : SV_POSITION
            {
                return mul(UNITY_MATRIX_MVP, vertPos);
            }

            float4 frag(float4 vertPos : SV_POSITION) : COLOR
            {
                return _MainTint;
            }
            ENDCG
        }
    } 
    FallBack "Diffuse"
}

　　这次我们用粒子系统展示下实际效果：

　　

　　注意看颜色会随着叠加的粒子数增多而变亮，直至变成白色。

结束语

　　使用Blend语句进行混合操作可以非常灵活地实现多种效果。比较难的是需要某种效果的时能够想到使用Blend以及如果正确地使用SrcFactor和DstFactor。另外值得注意的一点是：Blend语句不是Cg代码，而是ShaderLab语法，类似于Tags，所以写在CGPROGRAM和ENDCG外面。