UnityShader两个Pass的使用

基于上一篇UnityShader的透明度混合，改进的双Pass，可以让一些物体看起来更真实。
建议阅读下面的解释再回过来看代码

Shader "ShaderPath/DoublePassAlphaShader"//shader的选择路径
{
	Properties//该Shader可控的属性
	{
		_DiffuseColor ("DiffuseColor",Color) = (1,1,1,1)//漫反射的主色调
		_SpecularColor ("SpecularColor",Color) = (1,1,1,1)//高光反射的主色调
		_Gloss ("Gloss",Range(1,100)) = 2 //光泽度（反光度） 控制高光区域的大小
		_AlphaScale ("AlphaScale", Range(0,1)) = 0 //透明度变化范围
	}
	SubShader//子着色器
	{
		Tags{"Queue"="Transparent" "IgnoreProject"="True" "RenderType"="Transparent"}
		Pass
		{
			ZWrite On //打开深度写入 PS其实默认就是这个状态
			// 设置颜色通道的掩码 ColorMask 0 | A |RGB | 任何RGBA的组合
			//其中0 表示该Pass不输出任何颜色 等效于ColorMask A  除了透明通道都不输出
			ColorMask 0  
		}

		Pass
		{
			Cull Off ZWrite Off ZTest LEqual
			Tags{"LightMode" = "ForwardBase"}
			Blend SrcAlpha OneMinusSrcAlpha  // 透明度混合的重中之重！另外还有其他参数看文末
			//与ENDCG相照应，将CG代码包裹
			CGPROGRAM
			//顶点函数定义
			#pragma vertex diffusevert  
			//片元函数定义
			#pragma fragment diffusefrag
			//引入必要的Unity库 如下面的UnityObjectToClipPos 就是库中函数
			#include "UnityCG.cginc"
			//引入光照库 _LightColor0需要用
			#include "Lighting.cginc"
			struct appdata
			{
				float4 vertex : POSITION;//每个顶点结构体必须有的
				float3 normal : NORMAL;//定义法线
			};

			struct v2f
			{
				fixed3 worldNormal : TEXCOORD0; 
				float3 worldPos : TEXCOORD1;
				float4 pos : SV_POSITION;//每个片元结构体必须有的
			};
			
			fixed4 _DiffuseColor;
			fixed4 _SpecularColor;
			float _Gloss;
			float _AlphaScale;


			v2f diffusevert (appdata v)
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);//把顶点从模型空间转换到剪裁空间
				o.worldNormal = normalize(UnityObjectToWorldNormal(v.normal));//把法线从模型空间转换到世界空间
				o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;//模型坐标转到世界坐标
				return o;
			}
			
			fixed4 diffusefrag (v2f i) : SV_Target//返回一个RGBA到模型上
			{
				fixed3 lightDir = UnityWorldSpaceLightDir(i.worldPos);//获取光源在世界空间下的方向（光源发射出来的方向）
				fixed3 diffuse = _LightColor0.rgb * _DiffuseColor * (1+dot(lightDir,i.worldNormal))/2;
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos);//计算眼睛的方向 相机位置-模型的世界坐标 向量
				//Blinn-Phong模型高光 
				fixed3 halfView = normalize(lightDir + viewDir);
				fixed3 specular = _LightColor0.rgb * _SpecularColor * pow(saturate(dot(i.worldNormal,halfView)),_Gloss);
				return fixed4(diffuse +specular,_AlphaScale); //a通道返回原图片纹理的a通道值+_AlphaScale
			}
			ENDCG
		}
	}
	Fallback "Transparent/VertexLit"
}

Tips: UnityShader多个Pass，Unity会从上到下依次执行多个Pass
与上一篇文章相比，将原本在SubShader包围下的 Cull 、 ZWrite 、 ZTest挪到了 Pass的包围下。
在SubShader的包围下，其下的每个Pass如果没有设置，则都与SubShader相同；
在Pass包围下，各个Pass使用各自的设置互不干扰；
以上面代码为例，SubShader没有设置，则全部都是默认数据Cull Back ZWrite On ZTest LEqual
1、此时第一个Pass设置了 ZWrite On，则第一个Pass是 Cull Back ZWrite On ZTest LEqual
2、第二个Pass设置了 Cull Off ZWrite Off ZTest LEqual，则第二个Pass是Cull Off ZWrite Off ZTest LEqual

接下来还有关于这方面的讲解请接着往下看（很多坑哦）

我们来观察一下不同Pass以及不同设置下的模型有什么变化

		Pass
		{
			ZWrite On 
			ColorMask 0  
		}

		Pass
		{
			Cull Off ZWrite Off ZTest LEqual
			.........
		}

		Pass
		{
			ColorMask 0  
		}

		Pass
		{
			Cull Off ZWrite Off ZTest LEqual
			.........
		}

		Pass
		{
			ColorMask 0  
		}

		Pass
		{
			.........
		}

神奇的事情发生了，这三种写法产生的效果都是一样的！
解释一下咯：
1、为什么我们这里要使用两个Pass，第一个Pass将模型的深度值写入，可以让模型自身离相机近的显示出来，离相机远的隐藏。模型自身会产生遮挡！！ 第二个Pass在第一个Pass的基础上做了透明度混合，让模型透明能看到后面的景象
2、 为什么上述三种写法的最终表现都先相同？
①明确一点，默认的设置是SubShder包裹下的设置 也就是 “Cull Back ZWrite On ZTest LEqual”
②经过第一个Pass之后，模型的背面已经被剪裁并且深度值已经写入，第二个Pass是在第一个Pass渲染的结果之下进行二次渲染，因而在第二个Pass无论怎么设置Cull 和ZWrite都不会对最终结果产生影响。

下面是单个Pass，没有提前进行深度写入的结果，可以明显看到模型自身会有一个穿帮的现象

		//Pass
		//{
		//	ColorMask 0  
		//}

		Pass
		{
			.........
		}