UnityShader学习之路（02） 漫反射（半兰伯特模型）

 

上一篇只写了顶点着色器中的漫反射，并没有写片元着色器中的漫反射，在这里先补充一下，其实就是计算的位置写在片元着色器里面，直接上代码了：

Shader "MyShader/片元漫反射"
{
	Properties
	{
        //漫反射系数
		_Diffuse("Diffuse", Color) = (1,1,1,1)

	}

	SubShader
	{
		Tags { "RenderType"="Opaque" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			#include "Lighting.cginc"
            //漫反射系数
			fixed4 _Diffuse;

			struct v2f
			{
				float4 vertex : SV_POSITION;
				fixed3 worldNormal: TEXCOORD0;
			};

			v2f vert (appdata_base v)
			{
				v2f o;
                //把模型点从模型空间中转换到剪裁空间下
				o.vertex = UnityObjectToClipPos(v.vertex);
                //计算出世界空间下模型点的法线，提供给片元着色器使用
				fixed3 worldNormal = UnityObjectToWorldNormal( v.normal);
				o.worldNormal = worldNormal;
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
                //得到环境光的颜色
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                //计算世界空间下的入射光纤方向
				fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                //计算漫反射
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0,dot(worldLightDir,i.worldNormal));
                //混合漫反射颜色和环境光的颜色
				fixed3 color = ambient + diffuse;
				return fixed4(color,1);
			}
			ENDCG
		}
	}
	FallBack "Diffuse"
}

 

 

半兰伯特光照模型：

兰伯特光照模型有一个问题，先看图

点04和点05的入射光线方向与法线夹角大于90，此时余弦值小于0，所以模型的背面会出现全黑的现象，这个问题可以使用半兰伯特模型来解决，

半兰伯特：               漫反射 =  入射光线的颜色 * 漫反射系数 * （（入射光线与法线夹角的余弦值）*0.5 + 0.5）

有了一个乘0.5 再加0.5 操作，就可以保证漫反射亮度系数在 0 到1 之间，就不会出现全黑的现象

下面看 片元着色器中半兰伯特漫反射代码：

Shader "MyShader/片元半兰伯特漫反射"
{
	Properties
	{
		_Diffuse("Diffuse", Color) = (1,1,1,1)

	}

	SubShader
	{
		Tags { "RenderType"="Opaque" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			#include "Lighting.cginc"

			fixed4 _Diffuse;

			struct v2f
			{
				float4 vertex : SV_POSITION;
				fixed3 worldNormal: TEXCOORD0;
			};

			v2f vert (appdata_base v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				fixed3 worldNormal = UnityObjectToWorldNormal( v.normal);
				o.worldNormal = worldNormal;
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

				fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                //其实就是在这里加了一个乘0.5 加0.5的计算，别的跟兰伯特完全一样
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * (dot(worldLightDir,i.worldNormal) * 0.5 + 0.5);
				fixed3 color = ambient + diffuse;
				return fixed4(color,1);
			}
			ENDCG
		}
	}

	FallBack "Diffuse"
}