《Unity Shader入门精要》第六章-Unity中的基础光照

unity版本2018.1.1，有些内置方法用的是新的。

漫反射光照模型

// 漫反射光照模型-逐顶点光照（兰伯特光照模型）

Shader "Custom/DiffuseVertextLevelShader" {
	Properties {
		_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
	}

	SubShader {
		pass {
			Tags { "LightMode" = "ForwardBase" }

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"

			fixed4 _Diffuse;

			struct a2v {
				float4 vertex: POSITION;
				float3 normal : NORMAL;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				fixed3 color: COLOR;
			};
			
			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				// 获取环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz; 
				// 顶点法线转换到世界空间
				fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
				// 世界空间的光源方向
				fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
				// 计算漫反射
				fixed3 diffuse = _LightColor0.rgb  * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));

				o.color = diffuse + ambient;
				return o;
			}

			fixed4 frag(v2f i) : SV_TARGET {
				return fixed4(i.color, 1.0);
			}

			ENDCG
		}
	}
	FallBack "Diffuse"
}

// 漫反射光照模型-逐像素光照（兰伯特光照模型）

Shader "Custom/DiffuseVertextLevelShader" {
	Properties {
		_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
	}

	SubShader {
		pass {
			Tags { "LightMode" = "ForwardBase" }

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"


			fixed4 _Diffuse;

			struct a2v {
				float4 vertex: POSITION;
				float3 normal : NORMAL;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				fixed3 worldNormal: TEXCOORD0;
			};
			

			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				// 顶点法线转换到世界空间
				o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
				return o;
			}

			fixed4 frag(v2f i) : SV_TARGET {
				fixed3 worldNormal = normalize(i.worldNormal);
				// 获取环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				// 世界空间的光源方向
				fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
				// 计算漫反射
				fixed3 diffuse = _LightColor0.rgb  * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));
			
				fixed3 color = diffuse + ambient;
				return fixed4(color, 1.0);
			}

			ENDCG
		}
	}
	FallBack "Diffuse"
}

// 漫反射光照模型-逐顶点光照（半兰伯特光照模型）

Shader "Custom/DiffuseVertextLevelShader" {
	Properties {
		_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
	}

	SubShader {
		pass {
			Tags { "LightMode" = "ForwardBase" }

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"

			fixed4 _Diffuse;

			struct a2v {
				float4 vertex: POSITION;
				float3 normal : NORMAL;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				fixed3 color: COLOR;
			};
			
			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				// 获取环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz; 
				// 顶点法线转换到世界空间
				fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
				// 世界空间的光源方向
				fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
				// 计算漫反射
				fixed3 diffuse = _LightColor0.rgb  * _Diffuse.rgb * dot(worldNormal, worldLight) * 0.5 + 0.5;

			
				o.color = diffuse + ambient;
				return o;
			}

			fixed4 frag(v2f i) : SV_TARGET {
				return fixed4(i.color, 1.0);
			}

			ENDCG
		}
	}
	FallBack "Diffuse"
}

// 漫反射光照模型-逐像素光照（半兰伯特光照模型）

Shader "Custom/DiffuseVertextLevelShader" {
	Properties {
		_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
	}

	SubShader {
		pass {
			Tags { "LightMode" = "ForwardBase" }

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"


			fixed4 _Diffuse;

			struct a2v {
				float4 vertex: POSITION;
				float3 normal : NORMAL;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				fixed3 worldNormal: TEXCOORD0;
			};
			

			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				// 顶点法线转换到世界空间
				o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
				return o;
			}

			fixed4 frag(v2f i) : SV_TARGET {
				fixed3 worldNormal = normalize(i.worldNormal);
				// 获取环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				// 世界空间的光源方向
				fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
				// 计算漫反射
				fixed3 diffuse = _LightColor0.rgb  * _Diffuse.rgb * dot(worldNormal, worldLight) * 0.5 + 0.5;
			
				fixed3 color = diffuse + ambient;
				return fixed4(color, 1.0);
			}

			ENDCG
		}
	}
	FallBack "Diffuse"
}

 效果对比（和代码顺序一致）

高光反射光照模型

// 高光反射光照模型-逐顶点光照（Phong光照模型）

Shader "Custom/SpecularVertexLevelShader" {
	Properties {
		_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
		_Specular ("Specular", Color) = (1, 1, 1, 1)
		_Gloss ("Gloss", Range(8.0, 256)) = 20
	}

	SubShader {
		pass {
			Tags { "LightMode" = "ForwardBase" }

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"


			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;

			struct a2v {
				float4 vertex: POSITION;
				float3 normal : NORMAL;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				fixed3 color: COLOR;
			};
			

			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				// 获取环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz; 
				// 顶点法线转换到世界空间
				fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
				// 世界空间的光源方向
				fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
				// 计算漫反射
				fixed3 diffuse = _LightColor0.rgb  * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));
				// 世界空间的入射光线关于表面法线的反射方向
				fixed3 reflectDir = normalize(reflect(-worldLight, worldNormal));
				// 世界空间下的视角方向
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, v.vertex).xyz);
				// 高光反射
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);

				o.color = ambient + diffuse + specular;

				return o;
			}

			fixed4 frag(v2f i) : SV_TARGET {
				return fixed4(i.color, 1.0);
			}

			ENDCG
		}
	}
	FallBack "Diffuse"
}

// 高光反射光照模型-逐像素光照（Phong光照模型）

Shader "Custom/SpecularPixelLevelShader" {
	Properties {
		_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
		_Specular ("Specular", Color) = (1, 1, 1, 1)
		_Gloss ("Gloss", Range(8.0, 256)) = 20
	}

	SubShader {
		pass {
			Tags { "LightMode" = "ForwardBase" }

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"

			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;

			struct a2v {
				float4 vertex: POSITION;
				float3 normal : NORMAL;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
			};
			

			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				// 顶点法线转换到世界空间
				o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
				// 世界空间的顶点坐标
				o.worldPos = mul(unity_ObjectToWorld, v.vertex);

				return o;
			}

			fixed4 frag(v2f i) : SV_TARGET {
				fixed3 worldNormal = normalize(i.worldNormal);
				// 获取环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz; 
				// 世界空间的光源方向
				fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
				// 计算漫反射
				fixed3 diffuse = _LightColor0.rgb  * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));
				// 世界空间的入射光线关于表面法线的反射方向
				fixed3 reflectDir = normalize(reflect(-worldLight, worldNormal));
				// 世界空间下的视角方向
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
				// 高光反射
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);

				return fixed4(ambient + diffuse + specular, 1.0);
			}

			ENDCG
		}
	}
	FallBack "Diffuse"
}

// 高光反射光照模型-逐顶点光照（Blinn-Phong光照模型）

Shader "Custom/SpecularVertexLevelBlinnPhongShader" {
	Properties {
		_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
		_Specular ("Specular", Color) = (1, 1, 1, 1)
		_Gloss ("Gloss", Range(8.0, 256)) = 20
	}

	SubShader {
		pass {
			Tags { "LightMode" = "ForwardBase" }

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"


			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;

			struct a2v {
				float4 vertex: POSITION;
				float3 normal : NORMAL;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				fixed3 color: COLOR;
			};
			

			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				// 获取环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz; 
				// 顶点法线转换到世界空间
				fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
				// 世界空间的光源方向
				fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
				// 计算漫反射
				fixed3 diffuse = _LightColor0.rgb  * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));
				// 世界空间的入射光线关于表面法线的反射方向
				fixed3 reflectDir = normalize(reflect(-worldLight, worldNormal));
				// 世界空间下的视角方向
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, v.vertex).xyz);
				// 视角方向和光照方向相加并归一化
				fixed3 halfDir = normalize(worldLight + viewDir);
				// 高光反射
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(worldNormal, halfDir)), _Gloss);

				o.color = ambient + diffuse + specular;

				return o;
			}

			fixed4 frag(v2f i) : SV_TARGET {
				return fixed4(i.color, 1.0);
			}

			ENDCG
		}
	}
	FallBack "Diffuse"
}

// 高光反射光照模型-逐像素光照（Blinn-Phong光照模型）

Shader "Custom/SpecularPixelLevelBlinnPhongShader" {
	Properties {
		_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
		_Specular ("Specular", Color) = (1, 1, 1, 1)
		_Gloss ("Gloss", Range(8.0, 256)) = 20
	}

	SubShader {
		pass {
			Tags { "LightMode" = "ForwardBase" }

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"

			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;

			struct a2v {
				float4 vertex: POSITION;
				float3 normal : NORMAL;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
			};
			

			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				// 顶点法线转换到世界空间
				o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
				// 世界空间的顶点坐标
				o.worldPos = mul(unity_ObjectToWorld, v.vertex);

				return o;
			}

			fixed4 frag(v2f i) : SV_TARGET {
				fixed3 worldNormal = normalize(i.worldNormal);
				// 获取环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz; 
				// 世界空间的光源方向
				fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
				// 计算漫反射
				fixed3 diffuse = _LightColor0.rgb  * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));
				// 世界空间的入射光线关于表面法线的反射方向
				fixed3 reflectDir = normalize(reflect(-worldLight, worldNormal));
				// 世界空间下的视角方向
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
				// 视角方向和光照方向相加并归一化
				fixed3 halfDir = normalize(worldLight + viewDir);
				// 高光反射
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(worldNormal, halfDir)), _Gloss);

				return fixed4(ambient + diffuse + specular, 1.0);
			}

			ENDCG
		}
	}
	FallBack "Diffuse"
}

 效果对比（和代码顺序一致）