UnityShader入门精要第十章代码解析（Cubemap折射）

最新推荐文章于 2025-02-24 19:32:37 发布

MeksQAQ

最新推荐文章于 2025-02-24 19:32:37 发布

阅读量168

点赞数

分类专栏： UnityShader入门精要笔记文章标签： unity 游戏引擎

本文链接：https://blog.youkuaiyun.com/weixin_63637185/article/details/129934209

版权

UnityShader入门精要笔记专栏收录该内容

25 篇文章

订阅专栏

该文章描述了一个自定义的UnityShader，名为Custom/11，用于实现物体表面的折射效果。Shader中定义了颜色调整属性如ColorTint、RefractionColor和RefractionAmount，以及折射率RefractRatio。在SubShader中，使用CG编程语言处理顶点和片段着色器，结合Cubemap实现环境折射，并通过_LightMode控制光照模式。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

Shader "Custom/11"
{
    Properties
    {
        _Color("Color Tint",Color) = (1,1,1,1)
        _RefractColor("Refraction Color",Color) = (1,1,1,1)
        _RefractAmount("Refraction Amount",Range(0,1)) = 1
        _RefractRatio("Refraction Ratio",Range(0.1,1)) = 0.5
        _Cubemap("Cubemap", Cube) = "_Skybox"{}
    }

    SubShader
    {
        Tags{"RenderType" = "Opaque" "Queue" = "Geometry"}

        pass
        {
            Tags{"LightMode" = "ForwardBase"}

            CGPROGRAM
            
            
            #pragma multi_compile_fwdbase	
			
			#pragma vertex vert
			#pragma fragment frag
			
			#include "Lighting.cginc"
			#include "AutoLight.cginc"


            fixed4 _Color;
			fixed4 _RefractColor;
			fixed _RefractAmount;
            
            //折射多一个折射率的参数
            fixed _RefractRatio;
			samplerCUBE _Cubemap;


            struct a2v
            {
                fixed4 vertex : POSITION;
                fixed3 normal : NORMAL;

            };

            struct v2f
            {
                fixed4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                fixed3 worldPos : TEXCOORD1;
                float3 worldViewDir : TEXCOORD2;
                float3 worldRefr : TEXCOORD3;
                
				SHADOW_COORDS(4)
            };

            v2f vert(a2v v)
            {
                v2f o;

                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

                o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);


                //refract（）获取折射方向
                //三个参数（入射方向，法线，折射率）
                o.worldRefr = refract(-normalize(o.worldViewDir), normalize(o.worldNormal), _RefractRatio);

                TRANSFER_SHADOW(o);
                return o;

            }

            fixed4 frag(v2f i) : SV_Target
            {
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 lightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                fixed3 viewDir = normalize(i.worldViewDir);

                fixed3 refrColor = texCUBE(_Cubemap,i.worldRefr).rgb * _RefractColor.rgb;

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * _Color.rgb;

                fixed3 diffuse = _LightColor0.rgb * _Color.rgb * max(0,dot(lightDir,worldNormal));

                UNITY_LIGHT_ATTENUATION(atten,i,i.worldPos);

                return fixed4((ambient + lerp(diffuse,refrColor,_RefractAmount))*atten,1.0);
            }
            ENDCG
        }
    }
    FallBack "Reflective/VertexLit"
}

效果：