unity ui被模型遮挡

最新推荐文章于 2024-10-25 14:43:43 发布

原创最新推荐文章于 2024-10-25 14:43:43 发布 · 1.3k 阅读

18 ·

CC 4.0 BY-SA版权

文章标签：

#unity #游戏引擎 #unity3d

unity 专栏收录该内容

12 篇文章

订阅专栏

本文介绍了如何在Unity中使用worldspace渲染模式的Canvas避免被其他物体遮挡，通过应用官方提供的UI/Overlayshader并将其材质应用于特定UI元素，确保其始终位于场景前方。

部署运行你感兴趣的模型镜像

将Canvas的render mode设置为world space，因为UI是直接放在了场景里面，很容易被其他物体挡住，Unity官方的一个VR例子中给出了一个shader的解决方案，将如下的shader挂在材质上，并将这个材质赋予需要总是显示在所有物体前面的UI控件上，就可以解决这个问题。

Shader "UI/Overlay"
{
	Properties
	{
		[PerRendererData] _MainTex("Font Texture", 2D) = "white" {}
		_Color("Tint", Color) = (1,1,1,1)
		_StencilComp("Stencil Comparison", Float) = 8
		_Stencil("Stencil ID", Float) = 0
		_StencilOp("Stencil Operation", Float) = 0
		_StencilWriteMask("Stencil Write Mask", Float) = 255
		_StencilReadMask("Stencil Read Mask", Float) = 255
		_ColorMask("Color Mask", Float) = 15
	}

		SubShader
		{
			LOD 100

			Tags
			{
				"Queue" = "Transparent"
				"IgnoreProjector" = "True"
				"RenderType" = "Transparent"
				"PreviewType" = "Plane"
				"CanUseSpriteAtlas" = "True"
			}

			Stencil
			{
				Ref[_Stencil]
				Comp[_StencilComp]
				Pass[_StencilOp]
				ReadMask[_StencilReadMask]
				WriteMask[_StencilWriteMask]
			}

			Cull Off
			Lighting Off
			ZWrite Off
			ZTest Always
			Offset -1, -1
			Blend SrcAlpha OneMinusSrcAlpha
			ColorMask[_ColorMask]

			Pass
			{
				CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "UnityUI.cginc"

				struct appdata_t
				{
					float4 vertex : POSITION;
					float2 texcoord : TEXCOORD0;
					float4 color : COLOR;
				};

				struct v2f
				{
					float4 vertex : SV_POSITION;
					half2 texcoord : TEXCOORD0;
					fixed4 color : COLOR;
				};

				sampler2D _MainTex;
				float4 _MainTex_ST;
				fixed4 _Color;
				fixed4 _TextureSampleAdd;

				v2f vert(appdata_t v)
				{
					v2f o;
					o.vertex = UnityObjectToClipPos(v.vertex);
					o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
					o.color = v.color * _Color;
#ifdef UNITY_HALF_TEXEL_OFFSET
					o.vertex.xy += (_ScreenParams.zw - 1.0)*float2(-1,1);
#endif
					return o;
				}

				fixed4 frag(v2f i) : SV_Target
				{
					fixed4 col = (tex2D(_MainTex, i.texcoord) + _TextureSampleAdd) * i.color;
					clip(col.a - 0.01);
					return col;
				}
				ENDCG
			}
		}
}

赋值给下图