u-boot setenv.txt

setenv bootdelay 3
setenv bootfile "uImage"
setenv uboot_write 'protect off ${uboot_addr_f} +${uboot_len_f};cp.b ${uboot_addr_r} ${uboot_addr_f} ${filesize}'
setenv setboot 'setenv bootargs $(bootargs) video=dm64xxfb:output=$(videostd)'
setenv evn_version 20100525
setenv verify no
setenv uboot_file u-boot.bin
setenv rootpath '/opt/filesys'
setenv uboot_addr_r 80200000
setenv uboot_addr_f 2000000
setenv uboot_len_f 40000
setenv uboot_load 'tftp ${uboot_addr_r} ${uboot_file}'
setenv uboot_erase 'protect off ${uboot_addr_f} +${uboot_len_f};era ${uboot_addr_f} +${uboot_len_f}'
setenv uboot_update 'run uboot_load uboot_erase; cp.b ${uboot_addr_r} ${uboot_addr_f} ${filesize};protect on ${uboot_addr_f} +${uboot_len_f}'
setenv env_file env.bin
setenv env_addr_r 80400000
setenv env_addr_f 2040000
setenv env_len_f 20000
setenv env_load 'tftp ${env_addr_r} ${env_file}'
setenv env_erase 'protect off ${env_addr_f} +${env_len_f};era ${env_addr_f} +${env_len_f}'
setenv env_update 'run env_load env_erase; cp.b ${env_addr_r} ${env_addr_f} ${filesize};protect on ${env_addr_f} +${env_len_f}'
setenv kernel_addr_r 80400000
setenv kernel_len_f 400000
setenv kernel_addr_f 2060000
setenv kernel_load 'tftp ${kernel_addr_r} ${kernel_file}'
setenv kernel_erase 'protect off ${kernel_addr_f} +${kernel_len_f};era ${kernel_addr_f} +${kernel_len_f}'
setenv kernel_update 'run kernel_load kernel_erase;cp.b ${kernel_addr_r} ${kernel_addr_f} ${filesize};protect on ${kernel_addr_f} +${kernel_len_f}'
setenv ramdisk_addr_r 80800000
setenv ramdisk_len_f 400000
setenv ramdisk_addr_f 2460000
setenv ramdisk_load 'tftp ${ramdisk_addr_r} ${ramdisk_file}'
setenv ramdisk_erase 'protect off ${ramdisk_addr_f} +${ramdisk_len_f};era ${ramdisk_addr_f} +${ramdisk_len_f}'
setenv ramdisk_update 'run ramdisk_load ramdisk_erase; cp.b ${ramdisk_addr_r} ${ramdisk_addr_f} ${filesize};protect on ${ramdisk_addr_f} +${ramdisk_len_f}'
setenv jffs2_file jffs2.img
setenv jffs2_addr_r 80400000
setenv jffs2_addr_f 2660000
setenv jffs2_len_f 9a0000
setenv jffs2_load 'tftp ${jffs2_addr_r} ${jffs2_file}'
setenv jffs2_erase 'protect off ${jffs2_addr_f} +${jffs2_len_f};era ${jffs2_addr_f} +${jffs2_len_f}'
setenv jffs2_update 'run jffs2_load jffs2_erase; cp.b ${jffs2_addr_r} ${jffs2_addr_f} ${filesize};protect on ${jffs2_addr_f} +${jffs2_len_f}'
setenv os_update 'run kernel_update ramdisk_update jffs2_update'
setenv ram_args 'setenv bootargs root=/dev/ram rw'
setenv nfs_args 'setenv bootargs root=/dev/nfs nfsroot=${nfs_server}:${rootpath},nolock'
setenv addmem 'setenv bootargs ${bootargs} mem=90M'
setenv addtty 'setenv bootargs ${bootargs} console=ttyS0,115200n8'
setenv addip 'setenv bootargs ${bootargs} ip=${ipaddr}:${serverip}:${gatewayip}:${netmask}:${hostname}::off'
setenv addeth 'setenv bootargs ${bootargs} eth=${ethaddr}'
setenv addnetconsole 'setenv bootargs ${bootargs} console=netconsole netconsole=@${ipaddr}/,@${serverip}/'
setenv addinitrd 'setenv bootargs ${bootargs} initrd=${ramdisk_addr_f},${ramdisk_len_f}'
setenv videofb dm64xxfb
setenv vid0 'vid0=720x576@0,0'
setenv vid1 'vid1=off'
setenv osd0 'osd0=720x576@0,0'
setenv osd1 'osd1=0x0,0@0,0'
setenv addvideo 'setenv video video=${videofb}:output=${videostd}:${vid0}:${vid1}:${osd0}:${osd1}; setenv bootargs ${bootargs} ${video}'
setenv videomode pal
setenv addmode 'setenv bootargs ${bootargs} davinci_enc_mngr.ch0_mode=${videomode}'
setenv addmtdparts 'setenv bootargs ${bootargs} mtdparts=phys_mapped_flash:256k@0(hello)ro,512k@0x40000(world)ro'
setenv flash_self 'run ram_args addtty addmem addip addeth addvideo addmode;bootm ${kernel_addr_f} ${ramdisk_addr_f}'
setenv flash_nfs 'run nfs_args addtty addmem addip addeth addvideo addmode;bootm ${kernel_addr_f}'
setenv flash_net 'run ramdisk_load ram_args addtty addmem addip addeth addvideo addmode;bootm ${kernel_addr_f} ${ramdisk_addr_r}'
setenv net_self 'run kernel_load ram_args addtty addmem addip addeth addvideo addmode;bootm ${kernel_addr_r} ${ramdisk_addr_f}'
setenv net_nfs 'run kernel_load nfs_args addtty addmem addip addeth addvideo addmode addnetconsole;bootm'
setenv net_net 'run kernel_load ramdisk_load ram_args addtty addmem addip addeth addvideo addmode;bootm ${kernel_addr_r} ${ramdisk_addr_r}'
setenv ramdisk_file initrd.img.gz
setenv net_initrd 'run kernel_load ramdisk_load;setenv bootargs ;bootm ${kernel_addr_r}'
setenv kernel_file uImage.host
setenv target_kernel_load 'tftp ${kernel_addr_r} uImage.target'
setenv net_initramfs 'run target_kernel_load; setenv bootargs; bootm ${kernel_addr_r}'
setenv ipaddr 192.168.0.136
setenv video 'video=dm64xxfb:output=pal:vid0=720x576@0,0:vid1=off:osd0=720x576@0,0:osd1=0x0,0@0,0'
setenv bootargs 'root=/dev/ram rw console=ttyS0,115200n8 mem=90M ip=192.168.0.135:192.168.0.31:::::off eth=ce:ff:76:b2:2c:db setenv video=dm64xxfb:output=pal:vid0=720x576@0,0:vid1=off:osd0=720x576@0,0:osd1=0x0,0@0,0 davinci_enc_mngr.ch0_mode=pal'
setenv bootcmd 'run net_nfs'
setenv serverip 192.168.0.61
setenv nfs_server 192.168.0.61