unity shader 阴影强度颜色和自定义画阴影

有图有真相：

上图的操作需求
1： 头发部分不受阴影影响
2：面部阴影强度调节
3：面部阴影强度渐变调节（下巴处到额头处使用深浅渐变）
4：面部阴影颜色调节(这里面部阴影用了红色)
5：其他地方阴影效果不变(衣领部分)
上码：

Shader "Unlit/阴影强度"
{
	Properties
	{
		_MainTex ("_MainTex", 2D) = "white" {}
		_Shadows_mask ("Shadows_mask", 2D) = "white" {}
		_Shadows_mask_pw ("Shadows_mask_pw", 2D) = "white" {}// 用来自己画阴影图形和颜色
		_Shadows_PW ("Shadows_PW", Range(0, 2) ) = 1 // // 用来自己画阴影强度  黑色就是不受阴影区域
	}
	SubShader
	{
		Tags { "RenderType"="Opaque" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#pragma multi_compile_fwdbase  //必要 要想有正确的衰减内置变量等，必须要有这句
			#include "UnityCG.cginc"
		    #include "AutoLight.cginc" //必要
            #include "Lighting.cginc"
			uniform sampler2D _MainTex; uniform float4 _MainTex_ST;

			uniform sampler2D _Shadows_mask; uniform float4 _Shadows_mask_ST;
			uniform sampler2D _Shadows_mask_pw; uniform float4 _Shadows_mask_pw_ST;
			uniform float _Shadows_PW;
			struct v2f
			{
				float2 uv : TEXCOORD0;
				float3 normal : TEXCOORD1;
				float4 vertex : SV_POSITION;
				SHADOW_COORDS(2)  //宏表示为定义一个float4的采样坐标，放到编号为1的寄存器中
				 
			};
			v2f vert (appdata_base v)
			{
				v2f o;
				o.normal = mul(unity_ObjectToWorld, float4(v.normal,0)).xyz;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = v.texcoord;
				TRANSFER_SHADOW(o)   //根据变换求解上面结构体中的float4坐标，unity5中采用的是屏幕空间阴影贴图
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
			    i.normal = normalize(i.normal);
			    float4 MainTex = tex2D(_MainTex,TRANSFORM_TEX(i.uv, _MainTex));
			    fixed3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
			    fixed3 diffuse = _LightColor0 * max(0, dot(i.normal, lightDir)); 
			    diffuse*=MainTex;
				//*********************************// 阴影mask强度计算段
			    fixed attenuation = SHADOW_ATTENUATION(i);  //根据贴图与纹理坐标对纹理采样得到shadow值
				float4 _Shadows_mask_var = tex2D(_Shadows_mask,TRANSFORM_TEX(i.uv, _Shadows_mask));  // 用来自己画阴影图形和颜色
				float4 _Shadows_mask_pw_var = tex2D(_Shadows_mask_pw,TRANSFORM_TEX(i.uv, _Shadows_mask_pw)); // 用来自己画阴影强度
                diffuse = lerp(diffuse*_Shadows_mask_var.rgb,diffuse*pow(attenuation,-2),pow(attenuation,_Shadows_PW*(1-_Shadows_mask_pw_var.r)*10));
				//*******************************//
				return float4(diffuse,1);
			}
			ENDCG
		}
	}
	FallBack "Specular"
}