bzoj2751&CodeVS1853 容易题

最新推荐文章于 2020-03-19 13:36:53 发布

原创最新推荐文章于 2020-03-19 13:36:53 发布 · 623 阅读

0 ·

CC 4.0 BY-SA版权

本文介绍了一种求解特定约束条件下数列所有可能组合的积之和的问题。该问题涉及大数运算、快速幂算法及高效的数据处理方法。文章通过实例解释了如何通过统计可取数值之和的方法简化计算过程。

http://www.lydsy.com/JudgeOnline/problem.php?id=2751 http://codevs.cn/problem/1853/

题意：有一个数列共有m项，其中每一项的值都是不大于n的正整数，并且给出k个形如第i项不能为j的约束。求出所有可能的数列的各项之积之和对1,000,000,007取模的结果。

例如n=2,m=2,约束第1项不能填1，则数列可以是2,1或2,2，每个数列的各项之积依次为2和4，则答案为2+4=6。n,m<=1,000,000,000，k<=1

这里不可能把所有情况都枚举一次，毕竟可能的数列的数量还是指数级别的。

应该注意到，答案也等于各项可取的数之和之积，如在上面的例子中，第1项可取2和为2，第2项可取1或2和为3，则答案为2*3=6。

由于k远小于n，因此只要统计出某些项不能取哪些数，用总和相减就能得到能取的数之和。统计任务可以用快排和哈希完成，还要注意给约束判重。

又因为k也远小于m，实际上绝大部分项是没有约束的，所以即能取的数之和都是总和，由于m很大，因此可以用快速幂来解决。

代码：

const
  R=1000000007;
type
  node=record x,y:longint; end;
var
  a:array[1..100005]of node;
  n,m,k,i,j,s:longint;
  nn,ans:int64;
procedure qsort(l,r:longint);
  var
    i,j:longint;
    k,t:node;
  begin
    i:=l; j:=r; k:=a[(l+r) shr 1];
    while i<=j do
      begin
        while (a[i].x<k.x) or (a[i].x=k.x) and (a[i].y<k.y) do inc(i);
        while (a[j].x>k.x) or (a[j].x=k.x) and (a[j].y>k.y) do dec(j);
        if i<=j then
          begin
            t:=a[i]; a[i]:=a[j]; a[j]:=t;
            inc(i); dec(j);
          end;
      end;
    if i<r then qsort(i,r);
    if l<j then qsort(l,j);
  end;
function power(x:longint):int64;
  var
    t:int64;
  begin
    if x=0 then exit(1);
    t:=power(x shr 1);
    t:=t*t mod R;
    if x and 1=1 then t:=t*nn mod R;
    exit(t);
  end;
begin
  readln(n,m,k); nn:=n*(n+1) shr 1 mod R;
  for i:=1 to k do
    with a[i] do readln(x,y);
  qsort(1,k);
  i:=0; j:=m; ans:=1;
  while i<k do
    begin
      inc(i); dec(j);
      s:=nn-a[i].y;
      while (a[i].x=a[i+1].x) and (i<k) do
        begin
          inc(i);
          if a[i].y<>a[i-1].y then dec(s,a[i].y);
        end;
      ans:=ans*s mod R;
    end;
  ans:=ans*power(j) mod R;
  writeln((ans+R) mod R);
end.