ESP32_HTTP请求获取天气，含json解析

1、HTTP请求接口

ESP32可以连上WiFi后就能上网了呀，获取天气和之前写过的ESP8266差不多，也是去年的事情了复习下。

心知天气的链接：未来15天逐日天气预报和昨日天气 (yuque.com)，以及获取天气的接口：

2、代码

乐鑫是有个链接关于Arduino开发esp32的文档支持的：Welcome to ESP32 Arduino Core’s documentation — Arduino-ESP32 2.0.6 documentation (espressif.com)，但是在这里并没有找到httpclient的相关资料，不过这个链接是个不错的资料，其中关于WiFi部分的最后其实也是有HTTP请求的内容的。而httpclient的资料就从Arduino安装esp32驱动文件夹中的libraries中就可以获得，有示例以及源码；

#include "WiFi.h"
#include "HTTPClient.h"

//**********宏、常量********************
//WIFI名和密码
const char *ssid = "402";                         //SSID
const char *password = "xcx13711265178@.";        //PASSWORD

//心知天气配置
const char *private_key = "SJo8p9FiiIu6gDNz4";    //私钥
const char *city = "guangzhou";                   //查询的城市
const char *day = "3";                            //查询几日内的天气（免费用户最多可查3日）

//**********全局变量********************
String http_req;           //http请求
String http_rsp;           //http应答
HTTPClient http_client;

//***********函数声明*******************
void WIFI_Config(void);           //连接WIFI
void set_weather_httpclient(void);//设置获取天气的接口

//***********初始化*********************
void setup()
{
  Serial.begin(115200);
  WIFI_Config();                
  set_weather_httpclient();
}

//***********循环************************
void loop()
{
  int http_code = http_client.GET();
  Serial.printf("HTTP get code: %d\n", http_code);
  if (http_code == HTTP_CODE_OK) {
    http_rsp = http_client.getString();
    Serial.println(http_rsp);
    while(1);
  }
  delay(5000);
}

//***********函数实现*******************
//连接WIFI
void WIFI_Config()
{
  Serial.println("connecting WIFI");
  WiFi.begin(ssid, password);
  while (!WiFi.isConnected()){        //等待连接
    Serial.print(".");
    delay(500);
  }
  Serial.println("Wifi connected");   //连接成功
}

//设置获取天气的接口
void set_weather_httpclient()
{
  http_req = (String)"https://api.seniverse.com/v3/weather/daily.json?key=" + private_key ;
  http_req += (String)"&location=" + city + "&language=en&unit=c&start=0&days=" + day;
  Serial.println(http_req);
  if (http_client.begin(http_req)){
    Serial.println("set_weather_httpclient ok.");
  }
}

3、HTTP返回内容及在线网站的json解析

 

4、代码解析json数据

既然在线网站解析json是没错的，顺便也给看一目了然地看了各个数据，接下来就写代码解析了。

首先，给Arduino安装解析json的库，GitHub - bblanchon/ArduinoJson: 📟 JSON library for Arduino and embedded C++. Simple and efficient.，下载解压到安装目录的libraries就好了。

然后，加一个根据格式解析json的函数anylasize_weather_json（暂时解析了其中一天的白天天气和温度数据），就OK啦~

#include "WiFi.h"
#include "HTTPClient.h"
#include "ArduinoJson.h"

//**********宏、常量********************
//WIFI名和密码
const char *ssid = "402";                         //SSID
const char *password = "xcx13711265178@.";        //PASSWORD

//心知天气配置
const char *private_key = "SJo8p9FiiIu6gDNz4";    //私钥
const char *city = "guangzhou";                   //查询的城市
const char *day = "3";                            //查询几日内的天气（免费用户最多可查3日）

//**********全局变量********************
String http_req;           //http请求
String http_rsp;           //http应答
HTTPClient http_client;
DynamicJsonDocument doc(2048);  //json

//***********函数声明*******************
void WIFI_Config(void);           //连接WIFI
void set_weather_httpclient(void);//设置获取天气的接口
void anylasize_weather_json(String jsonStr);

//***********初始化*********************
void setup()
{
  Serial.begin(115200);
  WIFI_Config();                
  set_weather_httpclient();
}

//***********循环************************
void loop()
{
  int http_code = http_client.GET();
  
  if (http_code == HTTP_CODE_OK) {
    http_rsp = http_client.getString();
    //Serial.println(http_rsp);             //打印原始的http响应
    anylasize_weather_json(http_rsp);
    while(1);
  }else{
    Serial.printf("HTTP get code: %d\n", http_code);
  }
  delay(5000);
}

//***********函数实现*******************
//连接WIFI
void WIFI_Config()
{
  Serial.println("connecting WIFI");
  WiFi.begin(ssid, password);
  while (!WiFi.isConnected()){        //等待连接
    Serial.print(".");
    delay(500);
  }
  Serial.println("Wifi connected\n");   //连接成功
}

//设置获取天气的接口
void set_weather_httpclient()
{
  http_req = (String)"https://api.seniverse.com/v3/weather/daily.json?key=" + private_key ;
  http_req += (String)"&location=" + city + "&language=en&unit=c&start=0&days=" + day;
  Serial.println(http_req);
  if (http_client.begin(http_req)){
    Serial.println("set_weather_httpclient ok.\n");
  }
}

//解析JSON字符串
void anylasize_weather_json(String jsonStr)
{ 
  int index = jsonStr.indexOf('{');         //找到json的{
  jsonStr = jsonStr.substring(index);
    
  deserializeJson(doc, jsonStr);            //字符串解析成json格式 
  JsonObject root = doc.as<JsonObject>();   //doc转换成的JsonObject对象root  
  
  JsonArray results = root["results"];      //JsonObject对象root里有JsonArray数组results
  
  JsonObject location = results[0]["location"]; //results[0]中的子JsonObject对象location  
  const char *name = location["name"];          //JsonObject对象location中取出name（城市名）
  Serial.println(name);

  JsonArray daily = results[0]["daily"];        //results[0]中的JsonArray数组daily
  const char *date = daily[0]["date"];          //JsonArray数组daily中[0]的“date”（日期）
  Serial.println(date);
  const char *weather = daily[0]["text_day"];   //JsonArray数组daily中[0]的“text_day”（天气）
  Serial.println(weather);
  const char *low = daily[0]["low"];            //JsonArray数组daily中[0]的最低和最高气温
  const char *high = daily[0]["high"];
  Serial.println((String)"temper is "+low+"~"+high+" deg");  
}