opengl高级光照-Blinn-Phong

官方文档

blinn-phong

高级光照-Blinn-Phong

• 冯氏光照不仅对真实光照有很好的近似，而且性能也很高。但是它的镜面反射会在一些情况下出现问题，特别是物体反光度很低时，会导致大片（粗糙的）高光区域。下面这张图展示了当反光度为1.0时地板会出现的效果：
  
  可以看到，在镜面高光区域的边缘出现了一道很明显的断层。出现这个问题的原因是观察向量和反射向量间的夹角不能大于90度。如果点积的结果为负数，镜面光分量会变为0.0。你可能会觉得，当光线与视线夹角大于90度时你应该不会接收到任何光才对，所以这不是什么问题。然而，这种想法仅仅只适用于漫反射分量。当考虑漫反射光的时候，如果法线和光源夹角大于90度，光源会处于被照表面的下方，这个时候光照的漫反射分量的确是为0.0。但是，在考虑镜面高光时，我们测量的角度并不是光源与法线的夹角，而是视线与反射光线向量的夹角。看一下下面这两张图：
  
  现在问题就应该很明显了。左图中是我们熟悉的冯氏光照中的反射向量，其中$\theta$角小于90度。而右图中，视线与反射方向之间的夹角明显大于90度，这种情况下镜面光分量会变为0.0。这在大多数情况下都不是什么问题，因为观察方向离反射方向都非常远。然而，当物体的反光度非常小时，它产生的镜面高光半径足以让这些相反方向的光线对亮度产生足够大的影响。在这种情况下就不能忽略它们对镜面光分量的贡献了。

• James F. Blinn在冯氏着色模型上加以拓展，引入了Blinn-Phong着色模型。Blinn-Phong模型与冯氏模型非常相似，但是它对镜面光模型的处理上有一些不同，让我们能够解决之前提到的问题。Blinn-Phong模型不再依赖于反射向量，而是采用了所谓的半程向量(Halfway Vector)，即光线与视线夹角一半方向上的一个单位向量。当半程向量与法线向量越接近时，镜面光分量就越大。
  

  当视线正好与（现在不需要的）反射向量对齐时，半程向量就会与法线完美契合。所以当观察者视线越接近于原本反射光线的方向时，镜面高光就会越强。

  现在，不论观察者向哪个方向看，半程向量与表面法线之间的夹角都不会超过90度（除非光源在表面以下）。它产生的效果会与冯氏光照有些许不同，但是大部分情况下看起来会更自然一点，特别是低高光的区域。Blinn-Phong着色模型正是早期固定渲染管线时代时OpenGL所采用的光照模型。

  获取半程向量的方法很简单，只需要将光线的方向向量和观察向量加到一起，并将结果正规化(Normalize)就可以了：
  

  vec3 lightDir   = normalize(lightPos - FragPos);
  vec3 viewDir    = normalize(viewPos - FragPos);
  vec3 halfwayDir = normalize(lightDir + viewDir);
  //接下来，镜面光分量的实际计算只不过是对表面法线和半程向量进行一次约束点乘(Clamped Dot Product)
  //让点乘结果不为负，从而获取它们之间夹角的余弦值，之后我们对这个值取反光度次方：
  float spec = pow(max(dot(normal, halfwayDir), 0.0), shininess);
  vec3 specular = lightColor * spec;
  

• 结果对比
  

代码：

• 顶点着色器（只不过用了一个接口块）：

  #version 330 core
  layout (location = 0) in vec3 aPos;
  layout (location = 1) in vec3 aNormal;//VAO法线值传递
  layout (location = 2) in vec2 aTexCoords;
  
  // declare an interface block; see 'Advanced GLSL' for what these are.
  out VS_OUT {
      vec3 FragPos;
      vec3 Normal;
      vec2 TexCoords;
  } vs_out;
  
  uniform mat4 projection;
  uniform mat4 view;
  
  void main()
  {
      vs_out.FragPos = aPos;
      vs_out.Normal = aNormal;
      vs_out.TexCoords = aTexCoords;
      gl_Position = projection * view * vec4(aPos, 1.0);
  }
  

• 片段着色器：最重要的是镜面光
  镜面光与View相关，是反射光和人眼取的角度值。
  当人眼与反射光大于90度，在冯氏光照中是0（点乘结果是负值么），效果不好。
  如果是官方文章中的例子BP光照设成32和P光照的8是差不多的

  #version 330 core
  out vec4 FragColor;
  
  in VS_OUT {
      vec3 FragPos;
      vec3 Normal;
      vec2 TexCoords;
  } fs_in;
  
  uniform sampler2D floorTexture;
  uniform vec3 lightPos;
  uniform vec3 viewPos;
  uniform bool blinn;//这里我们肯定用的是blinn-phong模型
  
  void main()
  {           
      vec3 color = texture(floorTexture, fs_in.TexCoords).rgb;
      // 环境光
      vec3 ambient = 0.05 * color;
      
      // 漫反射
      vec3 lightDir = normalize(lightPos - fs_in.FragPos);
      vec3 normal = normalize(fs_in.Normal);
      float diff = max(dot(lightDir, normal), 0.0);//取的法线和光源点乘的值和0进行比较，取最大值
      vec3 diffuse = diff * color;
      
      // 高光
      vec3 viewDir = normalize(viewPos - fs_in.FragPos);
      vec3 reflectDir = reflect(-lightDir, normal);
      float spec = 0.0;
      //blinn-phong
      if(blinn)
      {
          vec3 halfwayDir = normalize(lightDir + viewDir); 	//求出半程向量(Halfway Vector) 
          spec = pow(max(dot(normal, halfwayDir), 0.0), 32.0);//法线和半程向量的点乘就会出现0-1之间的数的次方而不是0（出现边界）
      }
      else
      {
          vec3 reflectDir = reflect(-lightDir, normal);//取反射会出现负值
          spec = pow(max(dot(viewDir, reflectDir), 0.0), 8.0);
      }
      vec3 specular = vec3(0.3) * spec; // assuming bright white light color
      FragColor = vec4(ambient + diffuse + specular, 1.0);
  }
  

• 例子中光源位置不好我们要做到光源和人眼一个位置，让人眼和反射光线的夹角大于90度,然后把片段着色器中blinn-phong的32也调成8就明显了。（如果是官方文章中的例子BP光照设成32和P光照的8是差不多的）
  

  	//相机位置是
  	//光源位置
      // lighting info
      // -------------
      glm::vec3 lightPos(0.0f, 0.0f, 4.0f);
  

  	//修改blinn-phong光照的大小
      if(blinn)
      {
          vec3 halfwayDir = normalize(lightDir + viewDir);  
          spec = pow(max(dot(normal, halfwayDir), 0.0), 8.0);
      }
  

  phong光照结果
  
  blinn-phong光照结果亮一些