uboot启动流程分析详解

链接脚本 uboot.lds详细分析

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
OUTPUT_ARCH(arm)
ENTRY(_start)
SECTIONS
{
 . = 0x00000000;
 . = ALIGN(4);
 .text :
 {
  *(.__image_copy_start)
  *(.vectors)
  arch/arm/cpu/armv7/start.o (.text*)
  *(.text*)
 }
 . = ALIGN(4);
 .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
 . = ALIGN(4);
 .data : {
  *(.data*)
 }
 . = ALIGN(4);
 . = .;
 . = ALIGN(4);
 .u_boot_list : {
  KEEP(*(SORT(.u_boot_list*)));
 }
 . = ALIGN(4);
 .image_copy_end :
 {
  *(.__image_copy_end)
 }
 .rel_dyn_start :
 {
  *(.__rel_dyn_start)
 }
 .rel.dyn : {
  *(.rel*)
 }
 .rel_dyn_end :
 {
  *(.__rel_dyn_end)
 }
 .end :
 {
  *(.__end)
 }
 _image_binary_end = .;
 . = ALIGN(4096);
 .mmutable : {
  *(.mmutable)
 }
 .bss_start __rel_dyn_start (OVERLAY) : {
  KEEP(*(.__bss_start));
  __bss_base = .;
 }
 .bss __bss_base (OVERLAY) : {
  *(.bss*)
   . = ALIGN(4);
   __bss_limit = .;
 }
 .bss_end __bss_limit (OVERLAY) : {
  KEEP(*(.__bss_end));
 }
 .dynsym _image_binary_end : { *(.dynsym) }
 .dynbss : { *(.dynbss) }
 .dynstr : { *(.dynstr*) }
 .dynamic : { *(.dynamic*) }
 .plt : { *(.plt*) }
 .interp : { *(.interp*) }
 .gnu.hash : { *(.gnu.hash) }
 .gnu : { *(.gnu*) }
 .ARM.exidx : { *(.ARM.exidx*) }
 .gnu.linkonce.armexidx : { *(.gnu.linkonce.armexidx.*) }
}

代码分析：

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
OUTPUT_ARCH(arm)
ENTRY(_start)

• OUTPUT_FORMAT: 指定输出文件的格式，这里是elf32-littlearm，表示32位小端ELF格式的ARM架构文件。
• OUTPUT_ARCH: 指定目标处理器架构为ARM。
• ENTRY: 指定程序的入口点，这里是_start，通常是程序执行的起始地址

SECTIONS
{
 . = 0x00000000;
 . = ALIGN(4);

• SECTIONS: 定义内存段的布局。
•  表示当前地址指针，初始设为0x00000000。
• ALIGN(4): 确保地址对齐到4字节边界，以满足ARM架构的对齐要求

定义各个断

1.text段

.text :
{
 *(.__image_copy_start)
 *(.vectors)
 arch/arm/cpu/armv7/start.o (.text*)
 *(.text*)
}

• *(.__image_copy_start): 从符号__image_copy_start开始拷贝数据。
• *.(.vectors): 包括中断向量表数据（通常是程序的前几部分）。
• arch/arm/cpu/armv7/start.o (.text*): ARMv7架构启动代码中的.text段。
• *(.text*): 所有普通代码段

2. .rodata 段

.rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }

• 定义只读数据段，存放常量和字符串字面量。
• 使用SORT_BY_ALIGNMENT和SORT_BY_NAME确保按对齐和名字排序

3. .data 段

.data : { *(.data*) }

定义数据段，用于存放全局和静态变量的初始化值

4. 特殊段

.u_boot_list 段