ESP32 FreeRTOS 任务通知4（使用直接任务通知当作邮箱）

最新推荐文章于 2025-04-20 23:26:06 发布

爱摄影的寸头怪

最新推荐文章于 2025-04-20 23:26:06 发布

阅读量128

点赞数

文章标签：笔记 mcu 单片机

本文链接：https://blog.youkuaiyun.com/weixin_56073998/article/details/134387025

版权

本文介绍如何在Arduino中利用直接任务通知将RGB值封装到32Bits中发送，接收端解析并控制NeoPixel灯的显示，展示了任务创建和通信过程。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

简介

巧用直接任务通知的32Bits来封装打包多个数据后传递，接收到后，如何对数据进行还原，如图所示。

程序实现

#include <Adafruit_NeoPixel.h>
#define NEOPIN 33
#define NUMPIXELS 16

#define RPIN 34
#define GPIN 35
#define BPIN 32
#define SPIN 36 // speed

static TaskHandle_t xTaskNeoRing = NULL;

void configTask(void *pvParam) {
  pinMode(RPIN, INPUT);
  pinMode(GPIN, INPUT);
  pinMode(BPIN, INPUT);
  pinMode(SPIN, INPUT);
  uint8_t r_value = 0;
  uint8_t g_value = 0;
  uint8_t b_value = 0;
  uint8_t s_value = 100;

  while (1) {
    r_value = map(analogRead(RPIN), 0, 4095, 0, 255);
    g_value = map(analogRead(GPIN), 0, 4095, 0, 255);
    b_value = map(analogRead(BPIN), 0, 4095, 0, 255);
    s_value = map(analogRead(SPIN), 0, 4095, 10, 200);

    uint32_t rgb = s_value << 24 | r_value << 16 | g_value << 8 | b_value << 0;

    xTaskNotify(xTaskNeoRing, rgb, eSetValueWithOverwrite);

    vTaskDelay(100);
  }
}

void neoRing(void *pvParam) {

  Adafruit_NeoPixel pixels(NUMPIXELS, NEOPIN, NEO_GRB + NEO_KHZ800);
  pixels.begin();

  uint32_t srgb = 0;
  uint8_t r = 0;
  uint8_t g = 0;
  uint8_t b = 0;
  uint8_t s = 100;

  while (1) {

    pixels.clear();
    for (int i = 0; i < NUMPIXELS; i++) {

      xTaskNotifyWait(0x00, 0x00, &srgb, 0);
      s = (srgb & 0xff000000) >> 24;
      r = (srgb & 0x00ff0000) >> 16;
      g = (srgb & 0x0000ff00) >> 8;
      b = (srgb & 0x000000ff) >> 0;

      pixels.setPixelColor(i, pixels.Color(r, g, b));
      pixels.show();
      vTaskDelay(s * 5);
    }
  }
}

void setup() {
  Serial.begin(115200);

  xTaskCreate(configTask, "Configuration", 1024 * 10, NULL, 1, NULL);
  xTaskCreate(neoRing, "Neo Ring", 1024 * 20, NULL, 1, &xTaskNeoRing);

  vTaskDelete(NULL); //没我啥事了，自宫ba
}


void loop() {
}