HDLbits 记录_Q126 Lemmings3

相比上一题增加了挖掘的状态，挖掘之后可能出现掉落，另外挖掘和掉落一样，碰撞不改变方向，此题采用多一个寄存器寄存原来方向的状态机一样出现了测试样例错误的问题，因为状态机是每次上升沿变化一次（T），而输入信号是每半个周期变化一次，输入信号改变密集的时候，状态机也会发生变化（@ *），导致状态机不随周期跳变因此还是改成多个状态锁定方向的解法，具体如下图所示

代码如下

module top_module(
    input clk,
    input areset,    // Freshly brainwashed Lemmings walk left.
    input bump_left,
    input bump_right,
    input ground,
    input dig,
    output walk_left,
    output walk_right,
    output aaah,
    output digging ); 

    parameter WALK_L = 3'b000;
    parameter WALK_R = 3'b001;
    parameter FALL_L = 3'b010;
    parameter FALL_R = 3'b011;
    parameter DIG_L = 3'b100;
    parameter DIG_R = 3'b101;
    
    reg [2:0] curr_state;
    reg [2:0] next_state;
    
    always @(posedge clk or posedge areset) begin
        if(areset==1'b1) begin
           curr_state <= WALK_L; 
        end
        else begin
           curr_state <= next_state;
        end
    end
    
    always @(*) begin
        case(curr_state)
            WALK_L: begin
                if(ground == 1'b0) begin
                   next_state <= FALL_L; 
                end
                else if(dig == 1'b1) begin
                   next_state <= DIG_L; 
                end
                else begin
                    if(bump_left == 1'b1) begin
                       next_state <= WALK_R; 
                    end
                    else begin
                       next_state <= WALK_L; 
                    end
                end
            end
            WALK_R: begin
                if(ground == 1'b0) begin
                   next_state <= FALL_R; 
                end
                else if(dig == 1'b1) begin
                   next_state <= DIG_R; 
                end
                else begin
                    if(bump_right == 1'b1) begin
                       next_state <= WALK_L; 
                    end
                    else begin
                       next_state <= WALK_R; 
                    end
                end
            end
            FALL_L: begin
                if(ground == 1'b1) begin
                   next_state <= WALK_L; 
                end
                else begin
                   next_state <= FALL_L; 
                end
            end
            FALL_R: begin
                if(ground == 1'b1) begin
                   next_state <= WALK_R; 
                end
                else begin
                   next_state <= FALL_R; 
                end
            end
            DIG_L: begin
                if(ground == 1'b0) begin
                   next_state <= FALL_L; 
                end
                else begin
                   next_state <= DIG_L;
                end
            end
            DIG_R: begin
                if(ground == 1'b0) begin
                   next_state <= FALL_R; 
                end
                else begin
                   next_state <= DIG_R;
                end
            end
            default:begin
            	next_state <= WALK_L;
            end
        endcase
    end
    
    assign walk_left = (curr_state==WALK_L)?1'b1:1'b0;
    assign walk_right = (curr_state==WALK_R)?1'b1:1'b0;
    assign aaah = ((curr_state == FALL_R)||(curr_state == FALL_L))?1'b1:1'b0;
    assign digging = ((curr_state == DIG_L)||(curr_state == DIG_R))?1'b1:1'b0;
    
endmodule