HDLbits 记录_Q127 Lemmings4

相比上一题增加了掉落达到一定时间就死亡的机制，在这里要注意几点：

1、掉落一定时间后死亡，不是说掉落达到一定时间后直接死亡，而是掉落达到一定时间后接触到地面才死亡（ground = 1）；

2、判断掉落到地面的一瞬间判断是否应该死亡，则应该判断滞空时间的大小是否超过值，这就需要一个计数器对空中的时间进行计数，超过定值则锁存一个状态指示落地即死亡。

3、死亡之后不再输出任何信号，则需要一个空的状态代表死亡，这个状态是一个死胡同，进去后则不再出来，只有复位才能重新开始。

状态机如图所示

代码如下 

module top_module(
    input clk,
    input areset,    // Freshly brainwashed Lemmings walk left.
    input bump_left,
    input bump_right,
    input ground,
    input dig,
    output walk_left,
    output walk_right,
    output aaah,
    output digging ); 

    parameter WALK_L = 3'b000;
    parameter WALK_R = 3'b001;
    parameter FALL_L = 3'b010;
    parameter FALL_R = 3'b011;
    parameter DIG_L = 3'b100;
    parameter DIG_R = 3'b101;
    parameter SPLATTER = 3'b110;
    
    reg [2:0] curr_state;
    reg [2:0] next_state;
    reg [4:0] fall_time;
    reg 		die_flag;
    
    always @(posedge clk or posedge areset) begin
        if(areset==1'b1) begin
           curr_state <= WALK_L; 
        end
        else begin
           curr_state <= next_state;
        end
    end
    
    always @(*) begin
        case(curr_state)
            WALK_L: begin
                if(ground == 1'b0) begin
                   next_state <= FALL_L; 
                end
                else if(dig == 1'b1) begin
                   next_state <= DIG_L; 
                end
                else begin
                    if(bump_left == 1'b1) begin
                       next_state <= WALK_R; 
                    end
                    else begin
                       next_state <= WALK_L; 
                    end
                end
            end
            WALK_R: begin
                if(ground == 1'b0) begin
                   next_state <= FALL_R; 
                end
                else if(dig == 1'b1) begin
                   next_state <= DIG_R; 
                end
                else begin
                    if(bump_right == 1'b1) begin
                       next_state <= WALK_L; 
                    end
                    else begin
                       next_state <= WALK_R; 
                    end
                end
            end
            FALL_L: begin
                if(ground == 1'b1) begin
                    if(die_flag == 1'b1) begin
                    	next_state <= SPLATTER;
                	end
                    else begin
                        next_state <= WALK_L;
                    end
                end
                else begin
                    next_state <= FALL_L; 
                end
            end
            FALL_R: begin
                if(ground == 1'b1) begin
                    if(die_flag == 1'b1) begin
                    	next_state <= SPLATTER;
                	end
                    else begin
                        next_state <= WALK_R;
                    end
                end
                else begin
                    next_state <= FALL_R; 
                end
            end
            DIG_L: begin
                if(ground == 1'b0) begin
                   next_state <= FALL_L; 
                end
                else begin
                   next_state <= DIG_L;
                end
            end
            DIG_R: begin
                if(ground == 1'b0) begin
                   next_state <= FALL_R; 
                end
                else begin
                   next_state <= DIG_R;
                end
            end
            SPLATTER: begin
                next_state <= SPLATTER;
            end
            default:begin
            	next_state <= WALK_L;
            end
        endcase
    end
    
    always @(posedge clk or posedge areset) begin
        if(areset == 1'b1) begin
           fall_time <=1'b0; 
        end
        else begin
            if((curr_state == FALL_L)||(curr_state == FALL_R)) begin
               fall_time <= fall_time + 1'b1;
            end
            else begin
               fall_time <= 1'b0; 
            end
        end
    end
    
    always @(posedge clk or posedge areset) begin
        if(areset == 1'b1) begin
        	die_flag <= 1'b0;
        end
        else begin
            if(fall_time >= 5'd19) begin
            	die_flag <= 1'b1;
            end
            else begin
               die_flag <= die_flag; 
            end
        end
    end
    
    assign walk_left = (curr_state==WALK_L)?1'b1:1'b0;
    assign walk_right = (curr_state==WALK_R)?1'b1:1'b0;
    assign aaah = ((curr_state == FALL_R)||(curr_state == FALL_L))?1'b1:1'b0;
    assign digging = ((curr_state == DIG_L)||(curr_state == DIG_R))?1'b1:1'b0;
    
endmodule