【linux-汇编-点灯之思路-程序】

暴力蘑菇

已于 2024-05-03 22:07:37 修改

阅读量1.1k

点赞数 13

分类专栏： Linux 文章标签： I.MXULL Linux 汇编正点原子点灯

于 2024-05-02 16:24:48 首次发布

本文链接：https://blog.youkuaiyun.com/w384829981/article/details/138391208

版权

Linux 专栏收录该内容

20 篇文章

订阅专栏

本文详细介绍了ARM汇编中MOV和LDR指令的区别，以及在IMXULL芯片上通过汇编实现LED点灯的过程，包括开时钟、配置引脚功能、电气属性设定和输出控制等步骤。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

1. ARM汇编中的一些注意事项

在 ARM 中，MOV 指令和 LDR 指令的区别主要体现在以下几个方面：

数据传输方向：MOV 指令只能在寄存器之间移动数据，或者将立即数移动到寄存器中；而 LDR 指令可以将数据从内存中读取到寄存器中。
立即数的使用：MOV 指令对立即数的范围有要求，只能是由 8 位连续有效位通过偶数次移位能得到的数；LDR 指令的伪指令形式（如 LDR R0, =0xabcdef）则没有立即数范围的限制。
功能差异：MOV 不能用于将数据从内存移动到 CPU，而 LDR 可以。LDR 伪指令和 LDR 指令虽然名字相似，但作用不同，LDR 伪指令可以将立即数或地址值写入寄存器，而 LDR 指令用于从内存中读取数据到寄存器。

汇编也是一种编程语言，既然是语言就是有通用的逻辑，和C语言的逻辑一样，汇编也有包括，赋值，逻辑运算，循环，跳转，以及对应硬件的部分的中断之类的，具体对用要实现什么逻辑功能，可以百度对用的逻辑指令和注意事项，多用才能记得熟练；

2. IMXULL汇编点灯的前序：

在STM32学习过程中，对应的要把一个LED灯点亮，总体思路就是控制对应的硬件引脚的高低电平，那么对于IMXULL而言，也是同样的；
在STM32中配置一个引脚的具体步骤如下：

开时钟
定电气属性，包括速度、模式、上下拉之类的
有没有复用，把复用功能指定好
定IO口是输出还是输入，IO口（Input/Ouput的缩写，不指定输出或者输出模式，就无法进行有效的控制）如下图：

因此对于IMXULL而言，步骤也是如此；但是在STM32中是用C语言实现的，但是IMXULL中是由汇编实现的，但是具体的内在逻辑是一致的；

3. IMXULL汇编点灯之确定引脚：

每个芯片厂商对自己的引脚都有自己的一套命名规则，而对于NXP一个引脚命令规则有两个，因为其采用了：IOMUXC（Input-Ouput-Muxing-Control）模式，也就是一个引脚可以进行很多种复用功能
关注两点，一个引脚有两个名称，对应两个不同的寄存器地址，分别是MUX（Muxng）配置模式和PAD（Pad）配置电器属性：

IOMUXC_SW_MUX_CTL_PAD_GPIO1_IO03:配置GPIO1_IO03引脚的功能，MUX配置模式，PAD配置电气属性
IOMUXC_SW_PAD_CTL_PAD_GPIO1_IO03：配置电气属性，与MUX是一一对应的，PAD的意思是焊盘

IOMUXC_SW_MUX_ CTL_PAD_GPIO1_IO03:数据手册说明
在这里插入图片描述
IOMUXC_SW_PAD_CTL_PAD_GPIO1_IO03:数据手册说明

4. IMXULL汇编点灯之引脚功能编写：

4.1 第一步，开时钟

确定完引脚后，第一步就是开启时钟，这里为了简便表示可以把时钟全部打开，找到GPIO1时钟介绍的数据手册：把对应位设置为11就是开启时钟，这里为了简便，把CCR0~CCR6的时钟全部开启：
在这里插入图片描述
具体汇编实现如下：这里不用MOV指令，是因为这些文件是烧录在SD卡上，启动后加载到RAM内存中，也就是在存储中对这些值进行访问，取到这些值后再放到寄存器中，因此取值用的是ldr

.global _start @全局标号

_start:
    /*初始化使能所有外设时钟*/
    ldr r0,=0x020c4068 @CCGR0
    ldr r1,=0xffffffff @要向CCGR0写入的数据
    str r1,[r0] @将0xffffffff写入到CCGR0中

    ldr r0,=0x020c406c @CCGR1
    str r1,[r0]
    
    ldr r0,=0x020c4070 @CCGR2
    str r1,[r0]

    ldr r0,=0x020c4074 @CCGR3
    str r1,[r0]

    ldr r0,=0x020c4078 @CCGR4
    str r1,[r0]

    ldr r0,=0x020c407c @CCGR5
    str r1,[r0]
    
    ldr r0,=0x020c4080 @CCGR6
    str r1,[r0]

4.2 第二步，定功能（MUX）

第二步就是配置GPIO1_IO3引脚的的复用模式是GPIO1功能，也就是IO口（输入和输出的功能），也就是令：IOMUXC_SW_MUX_CTL_PAD_GPIO1_IO03=0x0101=5,也就是在GPIO1_IO03对应的寄存器地址写入5的内容，具体汇编实现如下：

/*第二步 复用引脚：GPIO1_IO03  PIN的复用为GPIO 
    设置：IOMUXC_SW_MUX_CTL_PAD_GPIO1_IO03=5
    IOMUXC_SW_MUX_CTL_PAD_GPIO1_IO03的地址为：0x020E0068
    */

    ldr r0,=0x020E0068 @IOMUXC_SW_MUX_CTL_PAD_GPIO1_IO03地址
    ldr r1,=0x5 @要向IOMUXC_SW_MUX_CTL_PAD_GPIO1_IO03写入的数据
    str r1,[r0] @将0x5写入到0x020E0068对应寄存器中

4.3 第三步，定电气属性（PAD）

第三步就是配置GPIO1_IO3引脚的电气属性，也就是配置：IOMUXC_SW_PAD_CTL_PAD_GPIO1_IO03：寄存器的电气属性，其中具体可参考数据手册，具体就是如下：

/* 第三步：配置电气属性GPIO1_1O03的电气属性：
 * 也就是寄存器：IOMUXC_SW_PAD_CTL_PAD_GPIO1_IO03
 * 寄存器IOMUXC_SW_PAD_CTL_PAD_GPIO1_IO03地址： 0x020E02F4
 * bit0:        0       低速率
 * bit5:3       110     R0/6
 * bit7:6       10      100MHZ
 * bit11:       0       关闭，开路输出
 * bit12:       1       使能保持
 * bir13:       0       keeper
 * bit15:14     00      100K下拉
 * bit16：      0       关闭hys
 * total:       0x10B0
 */
    ldr r0,=0x020E02F4 @IOMUXC_SW_PAD_CTL_PAD_GPIO1_IO03
    ldr r1,=0x10B0 @要向IOMUXC_SW_PAD_CTL_PAD_GPIO1_IO03写入的数据
    str r1,[r0] @

4.4 第四步，定输出/输入

第四步就是配置GPIO1_IO3的功能，首先对于一个GPIO而言，要想输出0或者1，那么不能凭空输出吧，因此要先对引脚赋值为1或者0，然后让这个引脚进行输出，不然单单一个输出，输出的数据是0还是1呢？所以就是先写数据，然后进行输出，总体思路就是这样，由于我们配置的模式是GPIO(General Purpose Input/Output)的模式，因此在参考手册中找到对应的GPIO的章节，这里注意GPIO和IIC或者其他的模式一样，每一个模式都有对应的寄存器介绍，只需找到对应的寄存器的介绍说明就行：这里截取GPIO_IO3的GPIO模式的对应说明参考手册：要注意我们配置的是GPIO1，但是在GPIOx这里的地址是：0x0209C000
其中DR（data register)寄存器就是设置数据的，而DIR寄存器就是设置输入还是输出的；两个寄存器是挨着的，地址的偏移是4，可以根据参考手册看出来，其中设置：GPIO1_GDIR寄存器bit3为1，也就是：
GPIO1->GDIR |= (1 << 3); 设置为输出,1左移三位,为什么是3，因为GPIO中GDIP寄存器有32位，分别可以代表32个IO端口的设置，例如GPIO1_IO15，则要改的GPIO中的DR寄存器就是16位从0开始

在这里插入图片描述

/*  设置GPIO1的功能 
 *  设置GPIO1_GDIR寄存器，设置GPIO1_GPIO3为输出  
 *  GPIO1_GDIR寄存器的地址是：209_C004
 *  设置：GPIO1_GDIR寄存器bit3为1，也就是：GPIO1_GPIO3为输出
 */
    ldr r0,=0x0209c004
    ldr r1,=0x8
    str r1,[r0]
/*  打开LED，也就是设置GPIO1_IO03为低0 
*   GPIO1_DR的地址为：0x0209c000
*   */
    ldr r0,=0x0209c000
    ldr r1,=0
    str r1,[r0]

loop:
    b loop