Jenkins 核心概念-Pipeline基础语法

阿常呓语

于 2025-03-17 07:30:00 发布

阅读量545

点赞数 21

分类专栏： Jenkins CICD 文章标签： jenkins 运维

本文链接：https://blog.youkuaiyun.com/u010339879/article/details/146302216

版权

Jenkins CICD 专栏收录该内容

5 篇文章

订阅专栏

文章目录

- Jenkins 核心概念
- - Pipeline组成部分
  - 参考文档

Jenkins 核心概念

今天我们来学习 Jenkins Pipeline 的基本语法。为我们以后编写 Pipeline 脚本提供一些基础的经验。

Pipeline组成部分

Jenkins Pipeline（或简称为 “Pipeline”）是一套插件，将持续交付的实现和实施集成到 Jenkins 中。

持续交付 Pipeline 自动化的表达了这样一种流程：将基于版本控制管理的软件持续的交付到您的用户和消费者手中。

Jenkins Pipeline 提供了一套可扩展的工具，用于将“简单到复杂”的交付流程实现为“持续交付即代码”。Jenkins Pipeline 的定义通常被写入到一个文本文件（称为 Jenkinsfile ）中，该文件可以被放入项目的源代码控制库中。

pipeline {
    agent any

    environment {
        // 定义全局环境变量
        DOCKER_REGISTRY = '172.19.89.106:12300'
        IMAGE_NAME = 'saas-cloud-job-service'
        SHORT_NAME = 'cloud-job'
        GIT_URL = 'http://xxxxxxxxxxxxxx/xxxxxxxxx/xxxxxxxxxx/xxxxxxx.git'
        CREDENTIALS_ID = '080912b9-902a-49f1-89e1-4684586ab238'
    }

    parameters {
        choice(name: 'BRANCH', choices: ['cicd','dev', 'test', 'master'], description: 'Select the branch to build')
        choice(name: 'ENV', choices: ['test', 'prod'], description: 'Select the environment to deploy')
    }
    stages {
        stage('Pull code') {
            steps {
                script {
                    // 使用参数化的分支名称进行 checkout
                    def branchName = params.BRANCH
                    checkout scmGit(
                        branches: [[name: "*/${branchName}"]],
                        extensions: [],
                        userRemoteConfigs: [[credentialsId: CREDENTIALS_ID, url: GIT_URL]]
                    )
                }
            }
        }

        stage('Build project') {
            steps {
                script {
                    def branchName = params.BRANCH
                    env.branchName = branchName  // 设置环境变量

                    // 获取 Git SHA 和当前日期
                    def gitSha = sh(returnStdout: true, script: 'git rev-parse --short HEAD').trim()
                    def currentDate = sh(returnStdout: true, script: 'date +%Y%m%d').trim()

                    // 构建 Docker 镜像标签
                    env.IMAGE_TAG = "${DOCKER_REGISTRY}/${IMAGE_NAME}/${SHORT_NAME}:${branchName}-${currentDate}-${gitSha}"

                    // 打印信息
                    // echo "Building Docker image with tag: ${env.IMAGE_TAG}"

                    // 构建 Docker 镜像
                    sh """
                        echo " ============================= 开始构建docker image ============================= "
                        docker build -f Dockerfile . -t ${env.IMAGE_TAG}
                        echo " ============================= docker image 构建完成  ============================= "
                        echo "[TAG]: ${env.IMAGE_TAG}"
                    """
                }
            }
        }

        stage('Push Docker image') {
            steps {
                script {
                    // 登录并推送 Docker 镜像
                    dockerLoginAndPush(env.IMAGE_TAG)
                }
            }
        }

        stage('Deploy project') {
            steps {
                echo 'Publishing project'
                // 这里可以添加部署的具体步骤
            }
        }
    }

    post {
        always {
            echo 'This pipeline will always run, begin cleaning workspace.'
            cleanWs() 
        }
        success {
            echo 'The pipeline succeeded.'
        }
        failure {
            echo 'The pipeline failed.'
        }
        changed {
            echo 'The pipeline status has changed.'
        }
    }
}


def dockerLoginAndPush(String imageTag) {
    /**
    使用 withDockerRegistry 插件来简化 Docker 登录和推送
    */ 
    withDockerRegistry([credentialsId: 'docker-harbor-registry-credentials', url: "http://${env.DOCKER_REGISTRY}"]) {
        try {
            // 推送 Docker 镜像
            sh "docker push ${imageTag}"
            echo "Pushed Docker Image [TAG]: ${imageTag}"
        } catch (err) {
            error "Failed to push Docker image: ${err}"
        }
    }

}