【操作系统学习日记】4.控制电脑的第一步：MBR

启动盘的设置

首先，先说明一下启动盘怎么设置。
在ata0后添加：
ata0-master:type=disk,path=”hd60M.img”,mode=flat,cylinders=121,heads=16,spt=63

在这里我们用到了path=hd60m.img,这个文件是由汇编语言编译的，就要用到NASM了
NASM是一个为可移植性与模块化而设计的一个80x86的汇编器。我们的汇编代码就由它来编辑。

nasm下载地址：
http://www.nasm.us/pub/nasm/releasebuilds/?C=M;O=D

MBR跑起来

下面是范例的汇编代码，主要功能就是在屏幕上打印字符串“1 MBR”

;主引导程序 
;------------------------------------------------------------
SECTION MBR vstart=0x7c00         
   mov ax,cs      
   mov ds,ax
   mov es,ax
   mov ss,ax
   mov fs,ax
   mov sp,0x7c00

; 清屏 利用0x06号功能，上卷全部行，则可清屏。
; -----------------------------------------------------------
;INT 0x10   功能号:0x06       功能描述:上卷窗口
;------------------------------------------------------
;输入：
;AH 功能号= 0x06
;AL = 上卷的行数(如果为0,表示全部)
;BH = 上卷行属性
;(CL,CH) = 窗口左上角的(X,Y)位置
;(DL,DH) = 窗口右下角的(X,Y)位置
;无返回值：
   mov     ax, 0x600
   mov     bx, 0x700
   mov     cx, 0           ; 左上角: (0, 0)
   mov     dx, 0x184f      ; 右下角: (80,25),
               ; VGA文本模式中,一行只能容纳80个字符,共25行。
               ; 下标从0开始,所以0x18=24,0x4f=79
   int     0x10            ; int 0x10

;;;;;;;;;    下面这三行代码是获取光标位置    ;;;;;;;;;
;.get_cursor获取当前光标位置,在光标位置处打印字符.
   mov ah, 3        ; 输入: 3号子功能是获取光标位置,需要存入ah寄存器
   mov bh, 0        ; bh寄存器存储的是待获取光标的页号

   int 0x10     ; 输出: ch=光标开始行,cl=光标结束行
            ; dh=光标所在行号,dl=光标所在列号

;;;;;;;;;    获取光标位置结束    ;;;;;;;;;;;;;;;;

;;;;;;;;;     打印字符串    ;;;;;;;;;;;
   ;还是用10h中断,不过这次是调用13号子功能打印字符串
   mov ax, message 
   mov bp, ax       ; es:bp 为串首地址, es此时同cs一致，
            ; 开头时已经为sreg初始化

   ; 光标位置要用到dx寄存器中内容,cx中的光标位置可忽略
   mov cx, 5        ; cx 为串长度,不包括结束符0的字符个数
   mov ax, 0x1301   ; 子功能号13是显示字符及属性,要存入ah寄存器,
            ; al设置写字符方式 ah=01: 显示字符串,光标跟随移动
   mov bx, 0x2      ; bh存储要显示的页号,此处是第0页,
            ; bl中是字符属性, 属性黑底绿字(bl = 02h)
   int 0x10     ; 执行BIOS 0x10 号中断
;;;;;;;;;      打字字符串结束   ;;;;;;;;;;;;;;;

   jmp $       ; 使程序悬停在此

   message db "1 MBR"
   times 510-($-$$) db 0
   db 0x55,0xaa

记得保存为纯文本文档，即用gredit打开的那种，注意不要用libreOffice Writer，要不那漫天的报错会让你难过一整天：(,搜了一天发现是格式错误，心情是异常的崩溃。

编译成功后（如果有错可以自行百度或提问我，说不定我搜过呢）
输入命令ls -lb mbr.bin,可以看到生成的文件数据
-rw-r–r– 1 root root 512 9月 5 21:06 mbr.bin

学过linux的读者肯定很熟悉啦，如果没学的话可以看看《鸟哥的linux私房菜》，我之后会单独写一篇分享我的操作系统学习资料，会给出这些资料的下载地址的，当然无所不能的优快云上也有下载，不过需要积分，还是能省则省啊~

接下来输入命令

dd if=/root/下载/nasm-2.10.07/mbr.bin of=/bochs/hd60M.img bs=512 count=1 conv=notrunc

这句话的目的是将我们的编译后的文件输出为模拟出来的硬盘hd60M.img

然后在bochs目录下输入bin/bochs -f bochsrc.disk
回车
然后点continue，回到终端，输入c，ok，可以看到绿色的文字 1 MBR闪耀啦~

为了平复激动的心情，我觉得还是把成果图放出来：