Excel下实现贪吃蛇小游戏

Excel实现贪吃蛇 天天写报表工具,感觉Excel越用越烦,看着Sheet里的格子,我突然想到了以前他们说用VBA做游戏的想法。 Excel工作表里的格子,天生就适合用来做俄罗斯方块、贪吃蛇这样的小游戏啊,想到了就做,于是有了以下。 先说一下实现方式。 蛇的运动通过user32.dll的SetTimer实现,蛇的组成即一个一维数组,数组存放自定义类型,包含横纵坐标。 蛇、食物通过填充Excel单元格实现。... 阅读详情

上次我们在Excel下实现了一个华容道式的小游戏,使用了Excel中的小部分属性和功能,不到100行语句就完成了。这次我们要把贪吃蛇搬到Excel中,就不那么容易了。

首先要解决游戏显示的问题。对我们来说,小游戏最好的平台是Excel的工作区,由于大小可调、颜色可填的单元格操作方便,我们完全可以把它们当像素来使用。于是我们的贪吃蛇游戏就有了以单元格为基础的像素形式的显示方式了。

其次是游戏的控制方法。在这里我摸索了好久,其中走了弯路不说,我最后的结论是在Excel中要实现按键事件的方法是引入窗体,然后在窗体中响应Keydown与Keypress事件。这样的话,既可以快速响应还可以根据情况修改对应按键。

 最后是游戏的定时问题。所有的游戏事实上都是在一个时间大循环里面定时接收输入信息更新状态的程序,我们的小游戏都不例外。老实说,我写这个游戏大部分的思考时间就浪费在如何实现游戏定时这里。Excel的VBA中与定时有关的只有onTime函数,没有其他相关函数提供了,onTime函数可以实现某一事件在指定时间发生,但只能以秒为最小单位,对我们要在一秒内更新数十次信息的小游戏不适合,我们只能另找方法。用过VB的人都知道VB控件中有个定时控件,用它来实现游戏定时是最好的,但在Excel中却没有,难道我要把VB中的定时控件移植到VBA中?这也是个很值得研究的课题,但是我想到了另外的方法。VB的程序员都知道要想VB程序发挥大作用一定离不开调用系统的API,于是我查看了系统相关API的帮助,发现系统API中实现相应功能的有settimer与killtimer函数,具体定义和用法大家可以参考相关帮助,但从字面大家都已经可以知道它们就是我们要找的东西了。那么现在的问题就是如何在vba环境下调用系统API。心想微软称vba就是office中的vb,那么在vba中调用系统API应该也与在VB中的一样。一试,呵呵,果然非虚,这微软真不是盖的(后在msdn中发现ms office vba从2000版本开始支持调用系统API,大家可以拓展office应用了)。

就这样游戏输入、输出、逻辑定时的问题都解决了,我们的吃蛇游戏就仅剩下算法逻辑部分了。我们的游戏逻辑是,游戏初始化后,启动定时器。在每次定时循环中,程序分别实现蛇头移动与蛇尾移动。首先是移动蛇头,游戏判断在移动方向上蛇头下一个的位置是否为空格,若是则把这位置的空格填上颜色(蛇头移动),蛇尾移动标志设为真;如果蛇头下一个位置不是空格(即有食物),则把这位置的空格填上颜色(蛇头移动)后把蛇尾移动标志设为假。接着到蛇尾移动部分,若蛇尾移动标志为真则把蛇尾原所在单元格填回白色(蛇尾移动),并更新蛇尾位置;如果蛇尾移动标志为假,则什么都不做(蛇尾不动蛇头动,蛇身长了)。对于整个游戏来说,效率的瓶颈在于像素操作(对单元格频繁填色)。但从以上算法可以看到,在每次循环中程序只需处理蛇头及蛇尾所在单元格;如果贪吃蛇吃到食物,则只需要更新蛇头单元格。每个时间循环里较少的数据处理量实现了游戏较快的响应速度,贪吃蛇游戏在Excel中实现也有了实际意义。

游戏还是以宏的形式实现。大家新建一个宏,输入如下代码。

' 熟悉VB的程序员知道首先是对调用系统API的声明
Public Declare Function SetTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As Long) As Long  
Public Declare Function KillTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long) As Long

' 定义数据结构
Type pos_
    row As Long
    col As Long
End Type

Public timerset As Long  ' SetTimer函数的返回值,用以标记已存在的Timer,KillTimer以此为参数销毁所标记的Timer
Public gaming As Boolean
Public pulsed As Boolean

Public head_movement As Long  '蛇头新移动方向标志,1、2、3、4代表右上左下
Public tail_movement As Long  '蛇尾移动方向标志,意义同上
Public oldhead_movement As Long '蛇头旧有移动方向标志
Dim tailmove As Boolean   '蛇尾移动标志

Dim origin_size As Long   '贪吃蛇原始大小

Public score As Long
Dim steps As Long
Dim clean As Boolean

Dim sth As pos_

Dim headrow As Long   '蛇头所在行位置
Dim headcol As Long   '蛇头所在列位置
Dim tailrow As Long   '蛇尾所在行位置
Dim tailcol As Long   '蛇尾所在列位置
Dim startpos As pos_   '贪吃蛇起始位置
Dim color As Long

Const left As Long = 5   '游戏区域左边边界
Const right As Long = 30  '游戏区域右边边界
Const top As Long = 3   '游戏区域上边边界
Const bottom As Long = 25  '游戏区域下边边界

Function main()    '主函数
    gaming = False
    If Worksheets.Count < 2 Then
        ActiveWorkbook.Sheets.Add after:=Worksheets(Worksheets.Count)
    ElseIf (MsgBox("Do you want to run it in a new blank worksheet ?", vbOKCancel, "?????") = vbOK) Then
            ActiveWorkbook.Sheets.Add after:=Worksheets(Worksheets.Count)
        Else
            Worksheets(Worksheets.Count).Select
    End If
Load UserForm1   '引入窗体
UserForm1.Show
End Function

Function game_initial()  '游戏初始化函数
    '初始化游戏界面
    color = 5
    If Not gaming Then
        Cells.ColumnWidth = 1
        Cells.RowHeight = 10
        Range(Cells(top, left), Cells(top, right)).Interior.ColorIndex = 1
        Range(Cells(top + 1, left), Cells(bottom - 1, left)).Interior.ColorIndex = 1
        Range(Cells(bottom, left), Cells(bottom, right)).Interior.ColorIndex = 1
        Range(Cells(top + 1, right), Cells(bottom - 1, right)).Interior.ColorIndex = 1
        Range(Cells(top + 1, left + 1), Cells(bottom - 1, right - 1)).Font.ColorIndex = color
    End If

    '贪吃蛇初始化
    origin_size = 5
    tail_movement = 1
    head_movement = 1
    oldhead_movement = head_movement
    startpos.row = (top + bottom) / 2 'initialized as 16
    startpos.col = (left + right) / 2 'initailized as 20
    pulsed = False
    tailmove = True
    headrow = startpos.row
    headcol = startpos.col
    tailrow = startpos.row
    tailcol = startpos.col - origin_size + 1
    clean = True
    steps = 0
    score = 0
    For i = 0 To origin_size - 1
        Cells(startpos.row, startpos.col - i).Interior.ColorIndex = color
    Next i
    gaming = True
'游戏初始化结束
End Function

Sub snake_move()
   If gaming Then
    Dim nextcol As Long
    Dim nextrow As Long
    If clean Then
        steps = steps + 1
  '贪吃蛇食物生成,这里食物的生成过程很简单,蛇每前进6步就生成一块食物
        If steps >= 6 Then
            steps = 0
            Randomize
            sth.row = Int((bottom - top) * Rnd) + top + 1
            Randomize
            sth.col = Int((right - left) * Rnd) + left + 1
               
            Do While sth.row >= bottom
                sth.row = sth.row - (bottom - top) + 1
            Loop
            Do While sth.col >= right
                sth.col = sth.col - (right - left) + 1
            Loop
            Cells(sth.row, sth.col) = "*"
            clean = False
            End If
    End If
    ''''''蛇头移动部分
    tailmove = True
    If oldhead_movement <> head_movement Then
        If Abs(oldhead_movement - head_movement) <> 2 Then
            oldhead_movement = head_movement
            Cells(headrow, headcol) = head_movement '当方向改变时在蛇头当前单元格记下前进方向,待蛇尾运行至此时可以按正确方向前进。本来应该用个数组记录,但我懒得再琢磨了。
        End If
    End If
        Select Case oldhead_movement
        Case 1 'right
            nextrow = headrow
            nextcol = headcol + 1
        Case 2 'up
            nextcol = headcol
            nextrow = headrow - 1
        Case 3 'left
            nextrow = headrow
            nextcol = headcol - 1
        Case 4 'down
            nextcol = headcol
            nextrow = headrow + 1
    End Select
    '看是否超出游戏区域了。
If nextcol = left Then
        nextcol = right - 1
    ElseIf nextcol = right Then
        nextcol = left + 1
    End If
    If nextrow = top Then
        nextrow = bottom - 1
    ElseIf nextrow = bottom Then
        nextrow = top + 1
    End If
   
    If Cells(nextrow, nextcol).Interior.ColorIndex = color Then  '蛇头碰到蛇身了,游戏结束
        Call game_over: Exit Sub
    End If
    If Cells(nextrow, nextcol) = "*" Then
        Call score_
        Cells(nextrow, nextcol).ClearContents
    End If
   
    Cells(nextrow, nextcol).Interior.ColorIndex = color
   
    headrow = nextrow
    headcol = nextcol
    ''''''蛇尾移动部分
    If tailmove Then
          
           Select Case tail_movement
            Case 1 'right
                nextrow = tailrow
                nextcol = tailcol + 1
            Case 2 'up
                nextrow = tailrow - 1
                nextcol = tailcol
            Case 3 'left
                nextrow = tailrow
                nextcol = tailcol - 1
            Case 4 'down
                nextcol = tailcol
                nextrow = tailrow + 1
            End Select
       
        If nextcol = left Then
            nextcol = right - 1
        ElseIf nextcol = right Then
            nextcol = left + 1
        End If
        If nextrow = top Then
            nextrow = bottom - 1
        ElseIf nextrow = bottom Then
            nextrow = top + 1
        End If
        If Cells(nextrow, nextcol) <> 0 Then
            If (Asc(Cells(nextrow, nextcol)) <> 42) Then
                tail_movement = Cells(nextrow, nextcol)
                Cells(nextrow, nextcol).ClearContents
            End If
        End If
        Cells(tailrow, tailcol).Interior.ColorIndex = 0
        tailrow = nextrow
        tailcol = nextcol
    End If
   End If
End Sub

Function game_over()
   
    If timerset <> 0 Then
        timerset = KillTimer(0, timerset)
        pulsed = False
    End If
    If MsgBox("Game over...temporarily. Try again?", vbOKCancel, "?????") = vbOK Then
        Range(Cells(top + 1, left + 1), Cells(bottom - 1, right - 1)).Interior.ColorIndex = 0
        Range(Cells(top + 1, left + 1), Cells(bottom - 1, right - 1)).ClearContents
        Call game_initial
    Else
        Cells.ClearContents
        Cells.Interior.ColorIndex = 0
        gaming = False
        SendKeys "%{F4}"  '这句很关键,当引入窗体后要在程序中退出窗体就要用Alt+F4
    End If
End Function

Function score_()
        clean = True
        score = score + 50
        tailmove = False
        UserForm1.Label2.Caption = "Now you have the score of " + Str(score)
End Function

上边是主程序(宏)部分,以下是窗体代码部分。在工程中引入用户窗体,名为UserForm1,拖入两个label控件名为Label1、2,再在窗体属性窗口调整好窗体在Excel中出现的位置。完成后在窗体代码窗口键入如下代码:

Private Sub UserForm_Initialize()  '窗体初始化事件
    Call game_initial
        If gaming Then
            UserForm1.Label1.Caption = "NO PLAY , NO GAME"
            UserForm1.Label2.Caption = "Arrow keys to move.                 P key to pause the game             E key to end the game"
        Else
            UserForm1.Label1.Caption = "Something happened !"
        End If
       
End Sub

Private Sub UserForm_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)  '响应窗体KeyDown事件
    If gaming Then
        If Not pulsed Then
            pulsed = True
            timerset = SetTimer(0, 0, 150, AddressOf snake_move) '启动定时器,这里时间间隔为150毫秒,大家可以加入一些代码用来实现越来越快的游戏速度
            UserForm1.Label2.Caption = "Arrow keys to move.                 P key to pause the game             E key to end the game"
        End If
        Select Case KeyCode
            Case vbKeyUp
                head_movement = 2
            Case vbKeyDown
                head_movement = 4
            Case vbKeyLeft
                head_movement = 3
            Case vbKeyRight
                head_movement = 1
            Case vbKeyP   '这里是通过销毁定时器实现游戏暂停
                If timerset <> 0 Then
                    timerset = KillTimer(0, timerset)
                    pulsed = False
                End If
                UserForm1.Label2.Caption = "Game paused. Any key to resume. "
            Case vbKeyE
                Call game_over
        End Select
    End If
End Sub

Private Sub UserForm_Terminate() '窗体销毁事件,这里是通过主程序发出Alt+F4按键事件引发
    If timerset <> 0 Then
        timerset = KillTimer(0, timerset)
        pulsed = False
    End If
    MsgBox ("You have finished the game with the score of " + Str(score))
End Sub

不过还没完,我们要找个地方启动整个程序。在工作表sheet1中找个地方拖入一个按钮用作总开关,名为CommandButton1,双击进入代码编写状态,键入

Private Sub CommandButton1_Click()
    Call main
End Sub
   

一切完成后保存。单击CommandButton1,游戏询问是否在一个新工作表中开始游戏,选择是,野猪拉屎了。

VBA贪吃蛇小游戏 文章目录前言项目引入项目介绍推荐理由场景展示代码总结 前言 最近接触到VBA,记录下学习的内容,以便以后查看! 项目引入 贪吃蛇小游戏 项目介绍 基于excel 实现贪吃蛇小游戏,为枯燥的工作挖掘一点点的happy时光! 推荐理由 推进等级☆☆ 可以通过编写小游戏,提升VBA编程能力,(我是菜鸟,随便学习点对我来说都是提升,大佬请忽视,狗头保命。) 场景展示 提示:这里可以介绍项目的使用场景并进行展示,记得删除示例哦。 代码 ‘’’ ’sheet中的代码 Private Sub CommandButton 阅读详情

相关推荐

H5小游戏开发从入门到深入:280款源码学习路径与技术拆解

H5小游戏开发涉及Canvas渲染、游戏循环、碰撞检测、对象池、状态机等核心技术。游戏循环通过requestAnimationFrame驱动,配合deltaTime保证不同刷新率下的速度一致性;碰撞检测常用AABB算法判断矩形重叠;对象池通过复用对象减少垃圾回收,提升移动端性能。这些技术不仅用于游戏,也广泛应用于互动营销、可视化等场景。本文基于280多款源码的实战分析,系统梳理从打砖块到塔防的渐进学习路径,涵盖精灵动画、音效管理、关卡数据设计等关键实现,帮助开发者建立完整的技术地图。

weixin_33892359的博客 350

用Excel制作贪吃蛇

此文章最先发布于我的博客 废话不多说,先放成果。在GitHub上查看源代码 。 开始编写 阅读此教程,你需要了解 什么是VBA,对VBA初步了解 如何在Excel中编辑VBA,并启用它 否则请另行百度。 ##最重要的两个函数 Range和Cells是整个游戏程序中的核心,它们都能返回一个 表示一个单元格、一行、一列、一个包含单个或若干连续单元格区域的选定单元格范围,或者一个三维区域。(摘自https://docs.microsoft.com/zh-cn/office/vba/api/excel

m0_70043868的博客 5591

批量执行多个SQL脚本并自动导出到Excel文件,Python源码分享

批量执行多个SQL文件,导出到Excel,记录数据行数和执行时间

mosquito_lover1的专栏 1402

EXCEL实现简易的贪吃蛇小程序

在EXCEL里,看到不一样的C/C++编程,很多时候用表格来辅助理解编程真的还不错~ EXCEL中的简易贪吃蛇~

AouSdu 9834

Excel下实现贪吃蛇小游戏.txt

Excel下实现贪吃蛇小游戏 上次我们在Excel下实现了一个华容道式的小游戏,使用了Excel中的小部分属性和功能,不到100行语句就完成了。这次我们要把贪吃蛇搬到Excel中,就不那么容易了。 首先要解决游戏显示的问题。对我们来说,小游戏最好的平台是Excel的工作区,由于大小可调、颜色可填的单元格操作方便,我们完全可以把它们当像素来使用。于是我们的贪吃蛇游戏就有了以单元格为基础的像素形式的显示方式了。 其次是游戏的控制方法。在这里我摸索了好久,其中走了弯路不说,我最后的结论是在Excel中要实现按键事件的方法是引入窗体,然后在窗体中响应Keydown与Keypress事件。这样的话,既可以快速响应还可以根据情况修改对应按键。 最后是游戏的定时问题。所有的游戏事实上都是在一个时间大循环里面定时接收输入信息更新状态的程序,我们的小游戏都不例外。老实说,我写这个游戏大部分的思考时间就浪费在如何实现游戏定时这里。Excel的VBA中与定时有关的只有onTime函数,没有其他相关函数提供了,onTime函数可以实现某一事件在指定时间发生,但只能以秒为最小单位,对我们要在一秒内更新数十次信息的小游戏不适合,我们只能另找方法。用过VB的人都知道VB控件中有个定时控件,用它来实现游戏定时是最好的,但在Excel中却没有,难道我要把VB中的定时控件移植到VBA中?这也是个很值得研究的课题,但是我想到了另外的方法。VB的程序员都知道要想VB程序发挥大作用一定离不开调用系统的API,于是我查看了系统相关API的帮助,发现系统API中实现相应功能的有settimer与killtimer函数,具体定义和用法大家可以参考相关帮助,但从字面大家都已经可以知道它们就是我们要找的东西了。那么现在的问题就是如何在vba环境下调用系统API。心想微软称vba就是office中的vb,那么在vba中调用系统API应该也与在VB中的一样。一试,呵呵,果然非虚,这微软真不是盖的(后在msdn中发现ms office vba从2000版本开始支持调用系统API,大家可以拓展office应用了)。

贪吃蛇 Excel VBA

用VBA写的一个贪吃蛇小程序,希望大家能够喜欢,同时也帮帮我测测BUG。谢谢。

Excel VBA小游戏,上班摸鱼必备

Excel 小游戏 介绍 这是我刚学vba的时候做的游戏,这里部分游戏是我自己写的,部分游戏来源网络 下载地址:https://gitee.com/LuoRober/excel_games 游戏目录 1 五子棋 2 三国杀 3 俄罗斯方块-界面版 4 俄罗斯方块-窗体版 5 俄罗斯方块 6 卡牌video poker 7 图灵游戏 8 坦克 9 娱票儿票房分析3 10 扫雷 11 数独3 12 斗地主 13 游戏sliding tile puzzl

1万+

excel版贪食蛇

用excel工作表单元格为游戏界面结合VBA代码编写的贪食蛇游戏.

DeepSeek Harness实测:6个玩法,写完代码自动跑自动改

先说个扎心的事实:现在能写代码的 AI 一抓一大把,但你让它把代码跑起来、亲眼看看效果,它立马安静得跟群里已读不回的那几位一样。DeepSeek Harness 不太一样。它写完代码会自己跑、自己看、自己改——写、跑、看、改,一条龙闭环,全程不用你伸手。这就好比请了个只会写菜谱的厨子,你问他菜呢,他说"菜谱在这,你自己开火"。这篇不整虚的,六个玩法都是我亲手试过的,从省半天活的实用派,到纯属找乐子的好玩派。每个都说清楚:以前要多久、现在要多久、什么活扔给它最合适。

H1727548的博客 794

VBA开发的贪吃蛇小游戏

VBA开发的贪吃蛇小游戏,使用VBA开发,调用Win API函数实现循环

贪吃蛇、五子棋、扫雷C程序代码 三合一

贪吃蛇、五子棋、扫雷C程序代码 三合一 适合初学者和做课程设计的同学使用,三个程序打包下载。

python可以处理excel文件吗,python能处理excel文件吗

贪吃蛇的游戏规则应该不需要我多做介绍了吧T_T。写个贪吃蛇游戏其实还是很简单的。

2401_84503846的博客 891

VBAexcel贪吃蛇小游戏

VBAexcel贪吃蛇小游戏 共有6个版本 刚学VBA 花了一天时间 愿与大家共享

Python复刻游戏《贪吃蛇大作战》

入门教程、案例源码、学习资料、读者群请访问:python666.cn大家好,欢迎来到 Crossin的编程教室 !曾经有一款小游戏刷屏微信朋友圈,叫做《贪吃蛇大作战》。一个简单到不行的游戏,也不知道怎么就火了,还上了iOS免费榜排名第一。我用Python做了一个复刻版,效果是这样的:演示视频demo 花了大约一整天时间,实现了基本效果(没做加速,没怎么优化,会有一点bug)。代码已上传 GitH...

Crossin的编程教室 401

R语言clusterProfiler实战:GO与KEGG富集分析从入门到精通

本文提供了一份详尽的R语言clusterProfiler实战指南,从环境配置、数据导入、基因ID转换到GO与KEGG富集分析及可视化,手把手教你解读生物学意义。文章重点介绍了如何利用clusterProfiler这一强大工具,将差异基因列表转化为清晰的生物学通路与功能故事,并分享了结果解读、可视化以及处理非模式生物等进阶技巧与避坑指南。

weixin_29044713的博客 162

汇川EASY系列之以太网通讯(MODBUS_TCP做从站)

汇川easy系列PLC做MODBUS_TCP从站,,ModbusTCP服务器默认开启,无需设置通信协议(即不需要配置),端口号为“502”。ModbusTCP从站最多支持31个ModbusTCP客户端(ModbusTCP主站)同时连接。

这是一个长期关注工控行业技术的博客,实现0-1的突破,期待您的关注和留言 8895

手机编写python用什么软件,手机编写python的编辑器

并且,这广告里面经常呈现给我们的就是,用Python来协助Excel办公,那就是一种高大上的生活~作为一个日常需要使用Excel的人来说,这个软件运用得好是能够日常提高工作效率的,但是Excel和Python的结合能够也能够高效办公吗?手机最强Python编程神器,在手机上运行Python不再是梦!这款软件最强大的地方在于,输入代码非常更多方便,不仅 集成了Python3解释器,既可以命令行运行Python,还可以编辑源文件后运行有了这几个手机APP让学习编程的人没有了懒惰的借口,也让许多码农。

2301_81900494的博客 1697

嵌入式接口通识知识之PCIe接口

PCIe x1接口是最常见的一种,插槽的长度是最短的,仅有25mm。PCIe x4接口有四个数据通道,提供比x1接口更高的带宽,插槽的长度为39mm,分为前后两组,一组22根针脚用于供电,剩下的42根针脚是数据针脚。插槽全长89mm,有164根针脚,分为前后两组,较短的插槽有22根针脚,主要用于供电,较长的插槽142根,主要用于数据传输,具有16通道所带来的高带宽。PCIe x8接口有八个数据通道,插槽全长56mm,有98跟针脚,分为前后两组,较短的22根针脚用于供电,剩下的76根针脚是数据针脚。

2301_76587520的博客 1306

手机上可以安装python吗,手机上可以下载python吗

并且,这广告里面经常呈现给我们的就是,用Python来协助Excel办公,那就是一种高大上的生活~作为一个日常需要使用Excel的人来说,这个软件运用得好是能够日常提高工作效率的,但是Excel和Python的结合能够也能够高效办公吗?手机最强Python编程神器,在手机上运行Python不再是梦!这款软件最强大的地方在于,输入代码非常更多方便,不仅 集成了Python3解释器,既可以命令行运行Python,还可以编辑源文件后运行有了这几个手机APP让学习编程的人没有了懒惰的借口,也让许多码农。

2401_82891570的博客 869

PyTorch实战:从零构建CNN图像分类模型

卷积神经网络(CNN)作为计算机视觉的核心架构,通过局部连接和权值共享机制高效处理图像数据。其核心组件包括卷积层、池化层和全连接层,其中PyTorch的动态计算图特性为CNN实现提供了灵活的开发环境。在工程实践中,使用CIFAR-10这类标准数据集可以快速验证模型性能,而数据增强和批归一化等技术能有效提升模型泛化能力。通过PyTorch实现CNN不仅能够掌握图像分类的基本原理,还能为后续迁移学习和复杂视觉任务打下基础,特别是在结合Adam优化器和学习率调度策略后,模型收敛速度和准确率都能得到显著提升。

weixin_42405592的博客 318

4.UE数字人工程运行逻辑及程序逻辑

UE数字人工程运行逻辑及程序逻辑

6090

从零开始,用一句话开发你的专属Excel表格工具!

最新接入DeepSeek-V3模型,点击下载最新版本InsCode AI IDE 从零开始,用一句话开发你的专属Excel表格工具! 在数字化的时代,数据处理已经成为每个人工作中不可或缺的一部分。无论是财务报表、销售统计还是项目管理,Excel表格都扮演着至关重要的角色。然而,对于许多人来说,开发一个高效的Excel表格工具却并非易事——复杂的公式、繁琐的代码编写以及对编程知识的高要求,常常让人望...

BlackStone33的博客 943

新系统申请软件著作权详细操作说明

今年八月底版权中心系统升级,新系统相对好用一些,至少不用再拿IE访问了,但是多了一项实名认证。下面介绍新系统的操作流程。 目录注册、登录和实名认证注册登录实名认证软件登记申请申请表填写鉴别材料身份证明文件权利归属证明文件其他材料提交材料变更登记 注册、登录和实名认证 首先访问版权中心系统:https://register.ccopyright.com.cn/login.html,如果老系统有账号直接登录即可,没有的话需要注册。 注册 点击注册按钮进入注册。 根据实际情况选择个人或单位,每个个人或单位只能在

Programming Talk 1万+

手机学python需要什么软件,手机上学python的软件

并且,这广告里面经常呈现给我们的就是,用Python来协助Excel办公,那就是一种高大上的生活~作为一个日常需要使用Excel的人来说,这个软件运用得好是能够日常提高工作效率的,但是Excel和Python的结合能够也能够高效办公吗?手机最强Python编程神器,在手机上运行Python不再是梦!这款软件最强大的地方在于,输入代码非常更多方便,不仅 集成了Python3解释器,既可以命令行运行Python,还可以编辑源文件后运行有了这几个手机APP让学习编程的人没有了懒惰的借口,也让许多码农。

S1112_的博客 421

【模型】OpenClaw 接入阿里云永久免费模型方案

Qwen2.5-7B-Instruct 模型为例。

海兰 4473

在Simulink中构建感应电机的时滞补偿控制模型,并通过仿真验证不同补偿策略的有效性

核心优势Smith预估器可有效补偿已知时滞,提升系统稳定性。动态PID调整适用于时变时滞的初步补偿。扩展方向自适应时滞估计:结合Luenberger观测器实时估计时滞。鲁棒控制:引入H∞控制或滑模控制抑制参数不确定性。网络化时滞补偿:结合知识库[2]的网络延迟模型,实现端到端补偿。

amy_mhd的博客 190
上一篇: 用Excel编写小游戏
下一篇: Excel版贪吃蛇sp1
sidekicker
博客等级 码龄23年 12粉丝 5原创
评论 1
成就一亿技术人!
拼手气红包6.0元
还能输入1000个字符
 
 条评论被折叠 查看
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付:10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值