用Excel编写小游戏

游戏要给予人的是欢娱快乐而非困扰闹心，要满足玩乐之心，有时一片树叶已经足够。对于我们这些游戏开发爱好者来说，asm、c、c++、directx、opengl、flash等并非是我们必需的知识和工具，有时一些意想不到的实现更能体现游戏简单的真意。

办公软件Excel大家熟悉不过，其功能我不多说。但大家可有想过在Excel中也可实现个把小游戏？这个不是指97版Excel中的复活节彩旦游戏，而是实实在在的利用Excel资源编写、在Excel下运行的小游戏。经过几代的升级，ms office下的vba（visual basic for application）语言的功能有了很大的提高，在Excel中实现个把平面游戏理论上是可能的。当然这里面也要因应Excel工作区的特点。在Excel中编写应用一般都是通过vba编写宏，这些小游戏也是。至于如何开始编写宏、如何插入窗体及一些选择行列单元格、改变单元格颜色、清除单元格内容等的语句，这里假设大家都知道了，不明白的参考帮助吧。老实说，我对visual basic for application也不大熟悉，做起来整个过程也要不停地看帮助。下面结合代码与大家介绍一下。

先说个简单的。大家玩过那个外国华容道吧，就是有n*n个格，有一格是空的，其他格是次序混乱的拼图或数字，游戏的目的就是利用这唯一的这个空格移动各块拼图把混乱的拼图（数字）恢复（顺序）。这里我们小游戏的目的是要把1至15这15个次序混乱的数字恢复从1到15的顺序排列，就像瑞星网站上那个（不知现在还在不在）。

打开Excel后打开代码编写器（Alt + F11），将如下代码写入其中一个工作表（Sheet）的通用代码部分中。程序首先是初始化。定义数据结构，选择4*4的空格，调整表格大小，改变单元格颜色（标示出游戏区域），然后是让1到15非重复随机分布到前15格空格中：

Type pos
    row As Integer
    col As Integer
End Type

'blank为空格的位置，初值为最后一格
Public blank As pos

'init_pos为游戏区域的左上角，控制游戏区域的位置，这里为(5,5)单元格
Public init_pos As pos

'border为游戏区域边界
Public border As pos

'N为游戏区域的大小，控制游戏的规模(N*N)，这里N=4
Public N As Integer

'running用于判断游戏是否进行中，如果要中途退出或玩家需要重玩用此变量控制
Public running As Boolean

'此下是本游戏宏的总入口，由工作区中button启动，如果愿意也可以让游戏宏在打开该表时自动运行
Sub Begin()
If running Then
    Cells(border.row, border.col).ClearContents '将唯一的空格初始化在右下角
    running = False
End If
initialize  '调用全局初始化函数
End Sub

'全局初始化函数
Function initialize()
If Not running Then

Dim i As Integer
Dim ii As Integer
Dim temp As Integer
Dim a(14) As Integer

running = True
N = 4
init_pos.col = 5
init_pos.row = 5
border.row = init_pos.row + N - 1
border.col = init_pos.col + N - 1
blank.col = border.col
blank.row = border.row

'游戏区域（颜色）初始化，省略了单元格大小的调整，大家可以应该加入相应语句让游戏外观整齐
Range(Cells(init_pos.row, init_pos.col), Cells(border.row, border.col)).Interior.ColorIndex = 5

'随机数数组初始化，这里是编号0到编号14共15个数
For i = 0 To (N*N-2)
    a(i) = i + 1
Next i

'不重复随机分布各数
For i = N*N-2 To 0 Step -1
    Randomize
    ii = Int(Rnd * i)
    temp = a(i)
    a(i) = a(ii)
    Cells(init_pos.row + i / N, init_pos.col + (i Mod N)) = a(i)
    a(ii) = temp
Next i
End If
End Function

很明显，Excel的单元格是游戏的主角。初始化后游戏开始，逻辑很简单：玩家每单击一个单元格（产生Worksheet中的SelectionChange事件），游戏就判断这个格是否在游戏区域中，若是就判断上下左右4个方向是否有空格，如果有空格就把原单元格中的数传到空格中，原单元格清空（空格与原单元格交换），然后判断游戏是否结束（1到15顺序排序了？），若还没有，什么都不做，等下一次单击事件发生。

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If running Then
'所单击单元格是否就是空格
If (Target.row <> blank.row Or Target.Column <> blank.col) Then
'所单击单元格是否在游戏区域
    If ((Target.row >= init_pos.row And Target.row <= border.row) And (Target.Column >= init_pos.col And Target.Column <= border.col)) Then
'所单击单元格上下左右是否有空格
    If ((Abs(blank.col - Target.Column) <= 1 And blank.row = Target.row) Or (Abs(blank.row - Target.row) <= 1 And blank.col = Target.Column)) Then
'单元格与空格交换
Cells(blank.row, blank.col) = Cells(Target.row, Target.Column)
        Cells(Target.row, Target.Column).ClearContents
        blank.col = Target.Column
        blank.row = Target.row
    End If
    End If
End If

'判断游戏是否结束?
Dim i As Integer
i = 0
Do While (i < N*N And Cells(init_pos.row + i / N, init_pos.col + i Mod N) = i + 1)
i = i + 1
Loop
If i = N*N-1 Then
MsgBox ("你成功了!")
running = False
End If
End If
End Sub

最后在Excel工作区中放个button，用来调用游戏宏启动游戏。双击button，输入代码
Private Sub button_Click()
    Call Begin
End Sub

保存后单击button，游戏开始了！

这个游戏还可以再加上记时、限时、计算移动步数等功能，并记录在表中某个位置作为游戏纪录。游戏没有防作弊功能，人们能够随便修改单元格中的数值，而这可以通过Worksheet_Change事件加以限制（不过这样的游戏都要作弊我无话可说）。