【Godot Shader】描边

张学徒

已于 2022-05-02 12:55:56 修改

阅读量1.3k

点赞数

分类专栏： Godot Godot Shader 文章标签： godot cocos2d 游戏引擎 shader

于 2022-05-02 12:55:37 首次发布

本文链接：https://blog.youkuaiyun.com/qq_37280924/article/details/124539546

版权

Godot 同时被 2 个专栏收录

65 篇文章

订阅专栏

Godot Shader

2 篇文章

订阅专栏

Godot 3.4.2

让图片内容描边
在这里插入图片描述

shader_type canvas_item;

uniform vec4 color : hint_color = vec4(1.0);
uniform float width : hint_range(0, 50) = 1.0;
uniform int pattern : hint_range(0, 2) = 0;
uniform bool inside = false;
uniform bool add_margins = true;
uniform bool visible = true;

void vertex(){
	if (visible){
	    if (add_margins){
	        VERTEX += (UV * 2.0 - 1.0) * width;
	    }
	}
}

bool hasContraryNeighbour(vec2 uv, vec2 texture_pixel_size, sampler2D texture){
    for (float i = -ceil(width); i <= ceil(width); i++){
        float x = abs(i) > width ? width * sign(i) : i;
        float offset;

        if (pattern == 0){
            offset = width - abs(x);
        } else if (pattern == 1){
            offset = floor(sqrt(pow(width + 0.5, 2) - x * x));
        } else if (pattern == 2){
            offset = width;
        }

        for (float j = -ceil(offset); j <= ceil(offset); j++){
            float y = abs(j) > offset ? offset * sign(j) : j;
            vec2 xy = uv + texture_pixel_size * vec2(x, y);
            if ((xy != clamp(xy, vec2(0.0), vec2(1.0)) || texture(texture, xy).a == 0.0) == inside){
                return true;
            }
        }

    }
    return false;
}

void fragment(){
	if (visible){
		vec2 uv = UV;
		 if (add_margins) {
	        vec2 texture_pixel_size = vec2(1.0) / (vec2(1.0) / TEXTURE_PIXEL_SIZE + vec2(width * 2.0));
	        uv = (uv - texture_pixel_size * width) * TEXTURE_PIXEL_SIZE / texture_pixel_size;
	        if (uv != clamp(uv, vec2(0.0), vec2(1.0))){
	            COLOR.a = 0.0;
	        } else {
	            COLOR = texture(TEXTURE, uv);
	        }
	    } else {
	        COLOR = texture(TEXTURE, uv);
	    }

	    if ((COLOR.a > 0.0) == inside && hasContraryNeighbour(uv, TEXTURE_PIXEL_SIZE, TEXTURE)){
	        COLOR.rgb = inside ? mix(COLOR.rgb, color.rgb, color.a): color.rgb;
	        COLOR.a += (1.0 - COLOR.a) * color.a;
	    }
	} else {
		COLOR = texture(TEXTURE, UV);
	}
}