洛谷 并查集 修复公路

题目背景

A地区在地震过后，连接所有村庄的公路都造成了损坏而无法通车。政府派人修复这些公路。

题目描述

给出A地区的村庄数N，和公路数M，公路是双向的。并告诉你每条公路的连着哪两个村庄，并告诉你什么时候能修完这条公路。问最早什么时候任意两个村庄能够通车，即最早什么时候任意两条村庄都存在至少一条修复完成的道路（可以由多条公路连成一条道路）

输入输出格式

输入格式：

第1行两个正整数N，M

下面M行，每行3个正整数x, y, t，告诉你这条公路连着x,y两个村庄，在时间t时能修复完成这条公路。

输出格式：

如果全部公路修复完毕仍然存在两个村庄无法通车，则输出-1，否则输出最早什么时候任意两个村庄能够通车。

输入输出样例

输入样例#1：

4 4
1 2 6
1 3 4
1 4 5
4 2 3

输出样例#1：

5

说明

N<=1000，M<=100000

x<=N，y<=N，t<=100000

题解：并查集裸题（不知为何用C++调不过）

const
  maxn=1000;
  maxm=100000;
var
  fa:array[1..maxn]of longint;
  n,m,i:longint;
  edge:array[0..maxm,1..3]of longint;

procedure init;
var
  i:longint;
begin
  readln(n,m);
  for i:=1 to m do
    readln(edge[i,1],edge[i,2],edge[i,3]);
  for i:=1 to n do
    fa[i]:=i;
end;

procedure qsort(l,r:longint);
var
  i,j,key:longint;
begin
  if l>r then exit;
  i:=l;j:=r;
  key:=edge[(i+j)shr 1,3];
  repeat
    while edge[i,3]<key do inc(i);
    while edge[j,3]>key do dec(j);
    if i<=j then
    begin
      edge[0]:=edge[i];edge[i]:=edge[j];edge[j]:=edge[0];
      inc(i);dec(j);
    end;
  until i>j;
  qsort(l,j);
  qsort(i,r);
end;

function find(x:longint):longint;
begin
  if fa[x]=x then exit(x);
  fa[x]:=find(fa[x]);
  find:=fa[x];
end;

procedure union(x,y:longint);
var
  u,v:longint;
begin
  u:=find(x);v:=find(y);
  if u<>v then fa[u]:=v;
end;

function judge:boolean;
var
  i,y:longint;
begin
  y:=find(1);
  for i:=2 to n do
    if find(i)<>y then exit(false);
  exit(true);
end;

begin
  init;
  qsort(1,m);
  for i:=1 to m do
  begin
    union(edge[i,1],edge[i,2]);
    if judge then
    begin
      writeln(edge[i,3]);
      halt;
    end;
  end;
  writeln(-1);
end.