【BZOJ1004】【HNOI2008】Cards

最新推荐文章于 2019-09-20 21:04:54 发布

原创最新推荐文章于 2019-09-20 21:04:54 发布 · 325 阅读

0 ·

CC 4.0 BY-SA版权

BZOJ 同时被 2 个专栏收录

20 篇文章

订阅专栏

Burnside定理/Pólya计数公式

1 篇文章

订阅专栏

本文探讨了给定数量的牌使用三种颜色染色，并在不同洗牌法下计算不同染色方案的问题。通过应用Burnside定理和Pólya计数公式，我们解决了在特定洗牌法约束下的染色方案计数问题，并最终计算出答案除以质数P的余数。

【Description】

　　小春现在很清闲,面对书桌上的N张牌,他决定给每张染色,目前小春只有3种颜色:红色,蓝色,绿色.他询问Sun有多少种染色方案,Sun很快就给出了答案.进一步,小春要求染出Sr张红色,Sb张蓝色,Sg张绝色.他又询问有多少种方案,Sun想了一下,又给出了正确答案. 最后小春发明了M种不同的洗牌法,这里他又问Sun有多少种不同的染色方案.两种染色方法相同当且仅当其中一种可以通过任意的洗牌法(即可以使用多种洗牌法,而每种方法可以使用多次)洗成另一种.Sun发现这个问题有点难度,决定交给你,答案可能很大,只要求出答案除以P的余数(P为质数).

【Input】

　　第一行输入 5 个整数：Sr,Sb,Sg,m,p(m<=60,m+1

【Output】

　　不同染法除以P的余数

【Sample Input】

1 1 1 2 7
2 3 1
3 1 2

【Sample Output】

【Hint】

　　有2 种本质上不同的染色法RGB 和RBG，使用洗牌法231 一次可得GBR 和BGR，使用洗牌法312 一次可得BRG 和GRB。
　　100%数据满足 Max{Sr,Sb,Sg}<=20。

【Solution】

　　运用Burnside定理和Pólya计数公式（注意在题目给的条件之外加上一个恒等置换使其满足置换群的条件）：
　　

N (G, C) = 1 | G | \sum f \in G | C (f) |, | C (f) | = k # (f)

$\begin{equation*} N(G,C)= \frac{1}{|G|}\sum_{f\in G}|C(f)|\quad ,\quad |C(f)|=k^{\#(f)} \end{equation*}$
　　用背包求解

f[i][j][k] $f[i][j][k]$ 表示用了i个红色，j个蓝色，k个绿色的方案数。
　　最后用乘法逆元计算答案。
　　
　　代码如下：

/**************************************************************
    Problem: 1004
    User: llgyc
    Language: Pascal
    Result: Accepted
    Time:984 ms
    Memory:4924 kb
****************************************************************/

const maxn = 105;
var sr,sb,sg,m,n,p,ans:longint;
    sz:array[0..maxn] of longint;
    used:array[0..maxn] of boolean;
    g:array[0..maxn,0..maxn] of longint;
    f:array[0..maxn,0..maxn,0..maxn] of longint;
procedure init();
  var i,j:longint;
  begin
    readln(sr,sb,sg,m,p); n:=sr+sb+sg;
    for i:=1 to m do begin for j:=1 to n do read(g[i,j]); readln; end;
    inc(m); for i:=1 to n do g[m,i]:=i;
  end;
function dp(x:longint):longint;
  var t,i,j,k,size,next:longint;
  begin
    fillchar(used,sizeof(used),false);
    fillchar(sz,sizeof(sz),0);
    fillchar(f,sizeof(f),0);
    size:=0;
    for i:=1 to n do begin
      if used[i] then continue;
      inc(size); sz[size]:=1;
      used[i]:=true; next:=i;
      while (not used[g[x][next]]) do begin
        used[g[x][next]]:=true;
        inc(sz[size]);
        next:=g[x][next];
      end;
    end;
    f[0,0,0]:=1;
    for t:=1 to size do
      for i:=sr downto 0 do
        for j:=sb downto 0 do
          for k:=sg downto 0 do begin
            if i>=sz[t] then f[i,j,k]:=(f[i,j,k]+f[i-sz[t],j,k]) mod p;
            if j>=sz[t] then f[i,j,k]:=(f[i,j,k]+f[i,j-sz[t],k]) mod p;
            if k>=sz[t] then f[i,j,k]:=(f[i,j,k]+f[i,j,k-sz[t]]) mod p;
          end;
    exit(f[sr,sb,sg]);
  end;
procedure exgcd(a,b:longint; var x,y:longint);
  var t:longint;
  begin
    if b=0 then begin x:=1; y:=0; exit; end;
    exgcd(b,a mod b,x,y);
    t:=x; x:=y; y:=t-a div b*y;
  end;
procedure main();
  var i,x,y:longint;
  begin
    for i:=1 to m do
      ans:=(ans+dp(i)) mod p;
    exgcd(m,p,x,y);
    while (x<=0) do x:=x+p;
    writeln((ans*x) mod p);
  end;
begin
  init();
  main();
end.