Unity流光shader，无需图片

最新推荐文章于 2024-08-10 18:05:50 发布

原创最新推荐文章于 2024-08-10 18:05:50 发布 · 3.4k 阅读

25 ·

CC 4.0 BY-SA版权

文章标签：

#unity

Unity3D 同时被 2 个专栏收录

31 篇文章

订阅专栏

Shader

6 篇文章

订阅专栏

本文介绍了一种不依赖预设纹理的流光Shader实现方法，通过计算而非图片，灵活调整光带的宽度、亮度、方向和角度。利用sin函数结合_Time属性，实现动态光效，通过smoothstep和lerp函数优化显示效果。

本片博客实现流光shader的方式无需黑色带有白道的图片，单纯通过计算实现，可以调节光带宽度、亮度、方向、角度，灵活性比较大。
下面图是实现效果
在这里插入图片描述
下面是代码的实现：

Shader "Unlit/liuguang"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
		
		// 速度 默认左->右
		_Speed ("Speed", range(-2, 2)) = 1.04
		
		// 宽度
		_Width ("Width", range(1, 10)) = 5.83

		// 角度
		_Angle ("Angle", range(-1, 1)) = 0.33

		// 亮度
		_Light ("Light", range(0, 1)) = 0.51
	}
	SubShader
	{
		Tags { "RenderType"="Opaque" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			
			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float2 uv : TEXCOORD0;
				float4 vertex : SV_POSITION;
			};

			sampler2D _MainTex;
			
			v2f vert (appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = v.uv;
				return o;
			}
			
			float _Speed; 
			float _Width; 
			float _Angle; 
			float _Light; 
			fixed4 frag (v2f i) : SV_Target
			{
				fixed4 col = tex2D(_MainTex, i.uv);
				float x = i.uv.x + i.uv.y * _Angle;
				float v = sin(x - _Time.w * _Speed);
				v = smoothstep(1 - _Width / 1000, 1.0, v);
				float3 target = float3(v, v, v) + col.rgb;
				col.rgb = lerp(col.rgb, target, _Light);
				return col;
			}
			ENDCG
		}
	}
}

流光是一条光带，所以无需进行进行顶点计算，正在片元着色器按照规则叠加像素值就可以。使用sin函数和_Time可以得到-1到1的波浪，与原像素叠加，可以得到下面的效果：
在这里插入图片描述
观察上图会发现有以下几个部分：

出现了阴暗：
因为sin函数取值到了小于0的部分，跟原像素叠加就变成了暗的或者黑色，取值越小，越暗
全白或全黑：
在sin函数取值范围[-1, 0]和[0, 1]的区间内，都进行了像素值叠加，所以看起来整张图片明暗都变了。
为解决上面两个问题，需要对sin函数的的取值进行取舍，使用smoothstep函数进行范围先定，去除了[-1, 0]的部分，以及不符合自定义的取值部分。再使用lerp函数插值处理，使得看起来更平滑。