序列合并

题目描述

有两个长度都是N的序列A和B，在A和B中各取一个数相加可以得到N^2个和，求这N^2个和中最小的N个。

输入输出格式

输入格式：

第一行一个正整数N；

第二行N个整数Ai,满足Ai<=Ai+1且Ai<=10^9;

第三行N个整数Bi, 满足Bi<=Bi+1且Bi<=10^9.

【数据规模】

对于50%的数据中，满足1<=N<=1000；

对于100%的数据中，满足1<=N<=100000。

输出格式：

输出仅一行，包含N个整数，从小到大输出这N个最小的和，相邻数字之间用空格隔开。

输入输出样例

输入样例#1：

3
2 6 6
1 4 8

输出样例#1：

3 6 7

---

思路

数据太大，所以想到拿堆做。
由于题中说a与b都是有序的，所以不用排序。
维护小根堆即可。

---

程序

var 
  a,b:array [1..100000] of longint;
  d:array [1..100000,0..1] of longint;
  n,i:longint;
procedure swap(var x,y:longint);
begin
  x:=x+y; y:=x-y; x:=x-y;
end;
function min(x,y:longint):longint;
begin
  if y>n then exit(x);
  if d[x,1]<d[y,1] then exit(x);
  exit(y);
end;
procedure down(x:longint);
var k,i:longint;
begin
  i:=x;
  while 2*i<=n do
  begin
    k:=min(2*i,2*i+1);
    if d[k,1]<d[i,1] then
    begin
      swap(d[k,0],d[i,0]);
      swap(d[k,1],d[i,1]);
      i:=k;
    end
    else exit;
  end;
end;
begin
  read(n);
  for i:=1 to n do
    read(a[i]);
  for i:=1 to n do
    read(b[i]);
  for i:=1 to n do
  begin
    d[i,0]:=1;
    d[i,1]:=a[i]+b[1];
  end;
  for i:=n div 2 downto 1 do
    down(i);
  for i:=1 to n do
  begin
    write(d[1,1],' ');
    inc(d[1,0]);
    d[1,1]:=d[1,1]-b[d[1,0]-1]+b[d[1,0]];
    down(1);
  end;
end.