产生数

2002年分区联赛普级组之三 产生数
Time Limit:1000MS Memory Limit:65536K
Total Submit:177 Accepted:77

Description
给出一个整数 n（n<10^30) 和 k 个变换规则（k<=15）。
　　规则：
　　　一位数可变换成另一个一位数：
　　　规则的右部不能为零。
　　例如：n=234。有规则（k＝2）：
　　　　2－> 5
　　　　3－> 6
　　上面的整数 234 经过变换后可能产生出的整数为（包括原数）:
　　　234
　　　534
　　　264
　　　564
　　共 4 种不同的产生数
问题：
　　给出一个整数 n 和 k 个规则。
求出：
　　经过任意次的变换（0次或多次），能产生出多少个不同整数。
　　仅要求输出个数。

Input
n k
x1 y1
x2 y2
… …
xn yn

Output
一个整数（满足条件的个数）：

Sample Input
234 2
2 5
3 6

Sample Output
4

---

如果数字i能变成数字j，那么i到j必须存在路径，否则i是不可能变成j的，这样一来，Fi的求解就显得非常简单了，求一个顶点v包括本身能到达的顶点数的方法相当多，可以用BFS,DFS,Dijkstra,Floyd，这里介绍一种类似Floyd的有向图的传递闭包算法，该算法实现简单 ，在解决这类问题时比Floyd效率更高，所谓有向图的传递闭包就是指可达性矩阵A=[a[i, j]],其中
a[i, j] = True 从i到j存在通路
a[i, j] = False 从i到j不存在通路

所以有向图传递闭包算法只需将floyd算法中的算术运算符操作‘+’用相应的逻辑运算符‘and’和’or’代替就可以了，其算法如下：
for h:=0 to 9 do
for i:=0 to 9 do
for j:=0 to 9 do
f[i,j]:=f[i,j]or(f[i,h] and f[h,j]);
最后值得注意的是当n很大时输出可能会超过Comp类型的范围，所以要使用高精度乘法，由于高精度算法是信息学竞赛中的基础，这里就不在详述。

---

var
  a:array[1..31]of 0..9;
  b:array[0..9]of longint;
  s:array[1..100]of 0..100;
  f:array[0..9,0..9]of boolean;
  n,k,i,j,h,m,t:integer;
  x:char;
procedure main(a:byte);
var i:integer;
begin
  for i:=1 to m do
    s[i]:=s[i]*a;
  for i:=1 to m+1 do
  begin
    s[i+1]:=s[i+1]+s[i] div 10;
    s[i]:=s[i] mod 10;
  end;
  if s[m+1]>0 then inc(m);
  if s[m+1]>0 then inc(m);
end;
begin
  read(x);
  while x<>' ' do
  begin
    inc(n);
    a[n]:=ord(x)-48;
    read(x);
  end;
  readln(k);
  for h:=1 to k do
  begin
    read(i);
    readln(j);
    f[i,j]:=true;
  end;
  for h:=0 to 9 do
    for i:=0 to 9 do
     for j:=0 to 9 do
       f[i,j]:=f[i,j]or(f[i,h] and f[h,j]);
  for i:=0 to 9 do
    f[i,i]:=true;
  for i:=0 to 9 do
    for j:=0 to 9 do
      inc(b[i],ord(f[i,j]));
  s[1]:=1; m:=1;
  for i:=1 to n do
    main(b[a[i]]);
  for i:=m downto 1 do
    write(s[i]);
end.