标记永久化

1.概述
在可持久化线段树中，我们常常要使用区间修改操作。这时候，如果再用下传标记再向上更新的方式来实现就会变得十分麻烦。

那么，有没有一种实现线段树区间修改的方式可以不用下传标记或向上更新呢？有，那就是标记永久化。
2.原理
标记永久化的原理简单来说就是修改时一路更改被影响到的点，询问时则一路累加路上的标记，从而省去下传标记的操作。
3.代码实现
3.0 说明
这里以区间修改区间求和的线段树为例。
线段树中编号为p的结点的值和标记分别为val[p]和mark[p]。
3.1 建树
标记永久化线段树的建树和标记不永久化线段树的建树没有什么区别，这里就不在赘述，直接上代码吧。

procedure build(p,l,r:longint);
var
        mid:longint;
begin
        if (l=r) then
        begin
                read(val[p]);
                exit;
        end;
        mid:=(l+r)>>1;
        build(p<<1,l,mid);
        build(p<<1+1,mid+1,r);
        val[p]:=val[p<<1]+val[p<<1+1];
end;

3.2 区间修改
0.设要将区间[x,y]中的数都加上v。
1.一路走下去同时更新路上受此次修改影响的节点的值，即inc(val[p],(y-x+1)*v)。
2.当目前结点所代表的区间与待修改区间完全重合时，更新标记，返回，即inc(mark[p],v);

procedure odd(p,l,r,x,y:longint;v:int64);
var
        mid:longint;
begin
        inc(val[p],(y-x+1)*v);
        if (l=x) and (r=y) then
        begin
                inc(mark[p],v);
                exit;
        end;
        mid:=(l+r)>>1;
        if (y<=mid) then odd(p<<1,l,mid,x,y,v)
        else if (x>mid) then odd((p<<1) or 1,mid+1,r,x,y,v)
        else
        begin
                odd(p<<1,l,mid,x,mid,v);
                odd((p<<1) or 1,mid+1,r,mid+1,y,v);
        end;
end;

有人可能会问：标记更新后直接返回的话下面的结点不就没更新了吗？
慢慢来嘛，往下看就明白了。

3.3 区间查询
0.设求区间[x…y]中数的总和
1.一路走下去同时累加路上的标记，因为在修改操作中标记并没有下传，所以要这样子，即inc(ad,mark[p])。
2.当目前结点所代表的区间与待修改区间完全重合时，返回当前结点的值与累加下来的标记乘上询问区间长度的和，即exit(val[p]+(y-x+1)*ad)。

function ask(p,l,r,x,y:longint;ad:int64):int64;
var
        mid:longint;
begin
        if (l=x) and (r=y) then exit(val[p]+(y-x+1)*ad);
        mid:=(l+r)>>1;
        if (y<=mid) then exit(ask((p<<1),l,mid,x,y,ad+mark[p]));
        if (x>mid) then exit(ask((p<<1) or 1,mid+1,r,x,y,ad+mark[p]));
        exit(ask(p<<1,l,mid,x,mid,ad+mark[p])+ask(p<<1 or 1,mid+1,r,mid+1,y,ad+mark[p]));
end;

4.练习题
luogu P3372

var
        val,mark:array[0..400005] of int64;
        n,m,i,opt,k,x,y:longint;
procedure build(p,l,r:longint);
var
        mid:longint;
begin
        if (l=r) then
        begin
                read(val[p]);
                exit;
        end;
        mid:=(l+r)>>1;
        build(p<<1,l,mid);
        build(p<<1+1,mid+1,r);
        val[p]:=val[p<<1]+val[p<<1+1];
end;

procedure odd(p,l,r,x,y:longint;v:int64);
var
        mid:longint;
begin
        inc(val[p],(y-x+1)*v);
        if (l=x) and (r=y) then
        begin
                inc(mark[p],v);
                exit;
        end;
        mid:=(l+r)>>1;
        if (y<=mid) then odd(p<<1,l,mid,x,y,v)
        else if (x>mid) then odd((p<<1) or 1,mid+1,r,x,y,v)
        else
        begin
                odd(p<<1,l,mid,x,mid,v);
                odd((p<<1) or 1,mid+1,r,mid+1,y,v);
        end;
end;

function ask(p,l,r,x,y:longint;ad:int64):int64;
var
        mid:longint;
begin
        if (l=x) and (r=y) then exit(val[p]+(y-x+1)*ad);
        mid:=(l+r)>>1;
        if (y<=mid) then exit(ask((p<<1),l,mid,x,y,ad+mark[p]));
        if (x>mid) then exit(ask((p<<1) or 1,mid+1,r,x,y,ad+mark[p]));
        exit(ask(p<<1,l,mid,x,mid,ad+mark[p])+ask(p<<1 or 1,mid+1,r,mid+1,y,ad+mark[p]));
end;

begin
        readln(n,m);
        build(1,1,n);
        for i:=1 to m do
        begin
                read(opt,x,y);
                if (opt=1) then
                begin
                        read(k);
                        odd(1,1,n,x,y,k);
                end
                else
                        writeln(ask(1,1,n,x,y,0));
        end;
end.

5.标记永久化线段树和标记不永久化线段树的差异

标记永久化线段树用时：

标记不永久化线段树用时：
明显快了很多。
并且码量也少了很多。