二分图：CodeVs 2776 最大匹配_最下权最大二部图匹配 python-优快云博客

本文介绍了一个关于二分匹配的实际问题：广州二中苏元实验学校的社团代表选举问题。通过匈牙利算法实现最大匹配数的求解，详细解释了如何利用DFS深度优先搜索寻找增广路径。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

Codevs 2776 : 寻找代表元

题目描述 Description

广州二中苏元实验学校一共有n个社团，分别用1到n编号。
广州二中苏元实验学校一共有m个人，分别用1到m编号。每个人可以参加一个或多个社团，也可以不参加任何社团。
每个社团都需要选一个代表。谦哥希望更多的人能够成为代表。

输入描述 Input Description
第一行输入两个数n和m。
以下n行每行若干个数，这些数都是不超过m的正整数。其中第i行的数表示社团i的全部成员。每行用一个0结束。

输出描述 Output Description
输出最多的能够成为代表的人数。

样例输入 Sample Input
4 4
1 2 0
1 2 0
1 2 0
1 2 3 4 0

样例输出 Sample Output
3

数据范围及提示 Data Size & Hint
各个测试点1s

数据范围
n,m<=200

首先向广东OI致敬，贵省真是厉害 ★,°:.☆(￣▽￣)/$:.°★

一看题，这实际上就是个二分匹配问题，只需每个社团都对应一个不同
的人即可（剩下的那些人参加什么社团无所谓）。

所以题目求的就是最大匹配数，用匈牙利算法，这样题目就解决了。

program divide;
var 
    nl,nr,i,ans,k:longint;

    a:array[0..1000,0..1000] of boolean;

    got:array[0..1000] of boolean;

    match:array[0..1000] of longint;

function dfs(k:longint):boolean;
var 
   i:longint;
begin 

   for i:=1 to nr do 

        if (a[k,i]) and (not got[i]) then begin // 是否有边 / 未访问过

           got[i]:=true; //打访问标记

           if (match[i]=0) or (dfs(match[i])) then begin //未匹配 或 找到增广路 

               match[i]:=k;

               exit(true);

           end;

    end;

    exit(false);

end;

begin 

    //读入数据

    read(nl,nr);  //nl 为社团数，nr为社员数

    fillchar(a,sizeof(a),false);

    for i:=1 to nl do 

        repeat 

            read(k);

            if k>0 then a[i,k]:=true;

        until k=0;

    fillchar(match,sizeof(match),0); //节点匹配的对象

    ans:=0;

    for i:=1 to nl do begin //dfs找增广路

        fillchar(got,sizeof(got),false);

        if dfs(i) then inc(ans);

    end;

    writeln(ans);

end.