CMake实践三：Hello World的共享库建立

这节的任务是建立静态库和动态库，提供HelloFunc函数供其它程序编程使用，HelloFunc向终端输出Hello World字符串。

1.新建文件
具体怎么新建目录这些LZ都不赘述了，可以参考http://blog.youkuaiyun.com/felaim/article/details/71601017这篇博客进行自己工程的构建，建议刚开始不要嫌麻烦，养成良好的代码习惯。

这节的内容主要是共享库的建立，所以主要的代码就是在lib文件夹里。

2.代码细节

hello.c代码内容：

#include "hello.h"

void HelloFunc()
{
    printf("Hello World\n");
}

这里一定要注意printf后main的“；”，如果分号忘写了，还会报错：error:expected ‘；’ before ‘}’ token。

hello.h的代码内容：

#ifndef HELLO_H

#define HELLO_H

#include <stdio.h>

void HelloFunc();

#endif

反正LZ 看到这个.h文件有点懵逼，不知道具体是什么意思，后来经过多次百度之后才知道具体是咋回事。
头文件中的#ifndef/#define/#endif这一串结构相信小伙伴们应该是经常看到的，这是放置头文件被重复引用，在代码量比较小的情况下，这个问题可能还不是很明显，但是在工程量巨大的情况下，会使得代码效率低下，而且局部变量全局变量的混合很容易造成代码混乱，所以上述这个结构就是防止这个问题的。下面LZ具体解释一下上述代码的含义：

#if not define HELLO.h,如果不存在HELLO.h
#ifndef HELLO_H 

#引入HELLO.h
#define HELLO_H

#否则不要引入
#endif

../lib/CMakeLists.txt中的代码：

#设置名称
set (LIBHELLO_SRC hello.c)

#设置lib输出路径
set(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/lib)

#增加library,SHARED代表是动态库
add_library(hello SHARED ${LIBHELLO_SRC})

#增加library,STATIC代表静态库
add_library(hello_static STATIC ${LIBHELLO_SRC})

#设置目标性质，LZ这里在编译过程中会显示NOT FOUND...没有这个属性定义
set_target_properties(hello_static PROPERTIES OUTPUT_NAME "hello")

#清理掉其它使用这个名字的库
set_target_properties(hello PROPERTIES CLEAN_DIRECT_OUTPUT 1)

set_target_properties(hello_static PROPERTIES CLEAN_DIRECT_OUTPUT 1)

#设置动态库的版本号
set_target_properties(hello PROPERTIES VERSION 1.2 SOVERSION 1)

get_target_property(OUTPUT_VALUE hello_static OUYPUT_NAME)

MESSAGE(STATUS "This is the hello_static OUTPUT_NAME:" ${OUTPUT_VALUE})

#通过install进行安装
install(TARGETS hello hello_static
        LIBRARY DESTINATION lib
        ARCHIVE DESTINATION lib)

install(FILES hello.h DESTINATION include/hello)

根目录下CMakeLists.txt的代码内容：

#申明cmake的最低版本，这句还是习惯性加上吧，不然报个warning也难受
cmake_minimum_required(VERSION 2.8)

#定义工程的名字
project(HELLOLIB)

#添加子目录
add_subdirectory(lib)

具体的实现步骤：

静态库与动态库构建：

读者云，太能罗唆了，一个Hello World就折腾了两个大节。OK，从本节开始，我们不再折腾Hello World了，我们来折腾Hello World的共享库。

本节的任务：

１，建立一个静态库和动态库，提供HelloFunc函数供其他程序编程使用，HelloFunc向终端输出Hello World字符串。
２，安装头文件与共享库。
一，准备工作：
在/backup/cmake目录建立t3目录，用于存放本节涉及到的工程

二，建立共享库

cd /backup/cmake/t3
mkdir lib

在t3目录下建立CMakeLists.txt，内容如下：

PROJECT(HELLOLIB)
ADD_SUBDIRECTORY(lib)

在lib目录下建立两个源文件hello.c与hello.h
hello.c内容如下：

#include “hello.h”
void HelloFunc()
{
printf(“Hello World\n”);
}

hello.h内容如下：

#ifndef HELLO_H
#define HELLO_H
#include <stdio.h>
void HelloFunc();
#endif

在lib目录下建立CMakeLists.txt，内容如下：

SET(LIBHELLO_SRC hello.c)
ADD_LIBRARY(hello SHARED ${LIBHELLO_SRC})

三，编译共享库:

仍然采用out-of-source编译的方式，按照习惯，我们建立一个build目录，在build目录中

cmake ..
make

这时，你就可以在lib目录得到一个libhello.so，这就是我们期望的共享库。

如 果你要指定libhello.so生成的位置，可以通过在主工程文件CMakeLists.txt中修改ADD_SUBDIRECTORY(lib)指令来指定一个编译输出位置或者在lib/CMakeLists.txt中添加SET(LIBRARY_OUTPUT_PATH <路径>)来指定一个新的位置。这两者的区别我们上一节已经提到了，所以，这里不再赘述，下面，我们解释一下一个新的指令
ADD_LIBRARY：

ADD_LIBRARY(libname [SHARED|STATIC|MODULE][EXCLUDE_FROM_ALL]source1 source2 ... sourceN)

你不需要写全libhello.so，只需要填写hello即可，cmake系统会自动为你生成libhello.X。类型有三种:

SHARED，动态库

STATIC，静态库

MODULE，在使用dyld的系统有效，如果不支持dyld，则被当作SHARED对待。

在ios系统中，几乎所有的程序都会用到动态库，而动态库加载的时候都需要用dyld(位于/usr/lib/dyld)程序进行链接。

EXCLUDE_FROM_ALL参数的意思是这个库不会被默认构建，除非有其他的组件依赖或者手工构建。

四，添加静态库：

同样使用上面的指令，我们在支持动态库的基础上再为工程添加一个静态库，按照一般的习惯，静态库名字跟动态库名字应该是一致的，只不过后缀是.a罢了。下面我们用这个指令再来添加静态库：

ADD_LIBRARY(hello STATIC ${LIBHELLO_SRC})

然后再在build目录进行外部编译，我们会发现，静态库根本没有被构建，仍然只生成了一个动态库。因为hello作为一个target是不能重名的，所以，静态库构建指令无效。

如果我们把上面的hello修改为

hello_static:ADD_LIBRARY(hello_static STATIC ${LIBHELLO_SRC})

就可以构建一个libhello_static.a的静态库了。这种结果显示不是我们想要的，我们需要的是名字相同的静 态库和动态库，因为target名称是唯一的，所以，我们肯定不能通过ADD_LIBRARY指令来实现了。这时候我们需要用到另外一个指令：
SET_TARGET_PROPERTIES，其基本语法是：
SET_TARGET_PROPERTIES(target1 target2 …PROPERTIES prop1 value1prop2 value2 …)
这条指令可以用来设置输出的名称，对于动态库，还可以用来指定动态库版本和API版本。在本例中，我们需要作的是向lib/CMakeLists.txt中添加一条：

SET_TARGET_PROPERTIES(hello_static PROPERTIES OUTPUT_NAME "hello")

这样，我们就可以同时得到libhello.so/libhello.a两个库了。
与他对应的指令是：

GET_TARGET_PROPERTY(VAR target property)

具体用法如下例，我们向lib/CMakeListst.txt中添加：

GET_TARGET_PROPERTY(OUTPUT_VALUE hello_static OUTPUT_NAME)
MESSAGE(STATUS “This is the hello_static
OUTPUT_NAME:”${OUTPUT_VALUE})

如果没有这个属性定义，则返回NOTFOUND。

让我们来检查一下最终的构建结果，我们发现，libhello.a已经构建完成，位于build/lib目录中，但是libhello.so去消失了。这个 问题的原因是：cmake在构建一个新的target时，会尝试清理掉其他使用这个名字的库，因为，在构建libhello.a时，就会清理掉 libhello.so.为了回避这个问题，比如再次使用SET_TARGET_PROPERTIES定义
CLEAN_DIRECT_OUTPUT属性。向lib/CMakeLists.txt中添加:

SET_TARGET_PROPERTIES(hello PROPERTIES CLEAN_DIRECT_OUTPUT 1)
SET_TARGET_PROPERTIES(hello_static PROPERTIES CLEAN_DIRECT_OUTPUT 1)

这时候，我们再次进行构建，会发现build/lib目录中同时生成了libhello.so和libhello.a

五，动态库版本号
按照规则，动态库是应该包含一个版本号的，我们可以看一下系统的动态库，一般情况是

libhello.so.1.2
libhello.so ->libhello.so.1
libhello.so.1->libhello.so.1.2

为了实现动态库版本号，我们仍然需要使用SET_TARGET_PROPERTIES指令。具体使用方法如下：

SET_TARGET_PROPERTIES(hello PROPERTIES VERSION 1.2 SOVERSION 1)

VERSION指代动态库版本，SOVERSION指代API版本。将上述指令加入lib/CMakeLists.txt中，重新构建看看结果。
在build/lib目录会生成：

libhello.so.1.2
libhello.so.1->libhello.so.1.2
libhello.so ->libhello.so.1

六，安装共享库和头文件

以上面的例子，我们需要将libhello.a, libhello.so.x以及hello.h安装到系统目录，才能真正让其他人开发使用，在本例中我们将hello的共享库安装 到/lib目录，将hello.h安装到/include/hello目录。

利用上一节了解到的INSTALL指令，我们向lib/CMakeLists.txt中添加如下指令：

INSTALL(TARGETS hello hello_static
LIBRARY DESTINATION lib
ARCHIVE DESTINATION lib)
INSTALL(FILES hello.h DESTINATION include/hello)

注意，静态库要使用ARCHIVE关键字通过:

cmake -DCMAKE_INSTALL_PREFIX=/usr ..
make
make install

我们就可以将头文件和共享库安装到系统目录/usr/lib和/usr/include/hello中了。
七，小结：

本小节，我们谈到了：

如何通过ADD_LIBRARY指令构建节

如何通过SET_TARGET_PROPERTIES同时构建同名的动态库和静态库。

如何通过SET_TARGET_PROPERTIES控制动态库版本

最终使用上节谈到的INSTALL指令来安装头文件和动态、静态库。

在下一节，我们需要编写另一个高级一点的Hello World来演示怎么使用我们已经构建的构建的共享库libhello和外部头文件。