通过汇编看调用协定

导读：
　　调用函数的时候，有各种不同的调用约定。它们规定了参数的传送方式、参数是否可变，由谁来处理堆栈等。常用的调用约定有两种：C语言调用约定和Pascal语言调用约定。
　　可以在工程设置中设定自定义函数的调用规则，也可以在函数声明和定义的时候在函数名前加关键词或API宏定义(如_cdecl、__stdcall、__fastcall、WINAPI、APIENTRY等)明确表示函数的调用协定。
　　下面将分别说明各种调用协定的用法和意义，并附以相应的汇编代码分析。
　　1、C语言调用约定
　　采用C语言编程的时候，默认使用C/C++语言调用约定。也可以手工指定，这需要在函数声明时加上__cdecl关键字。采用本约定时，参数从右到左入栈，个数可变。由于函数体不能预先知道传进来的参数个数，因此采用本约定时必须由调用函数者负责堆栈清理。由于参数可变，此约定比较灵活，但是性能比较低。生成的代码中函数名有一个_(下划线)做前缀。
　　举例：
　　int __cdecl Add(int a, int b)
　　{
　　return (a + b);
　　}
　　
　　函数调用：
　　Add(1, 2);
　　push 2
　　push 1
　　call @Add 其实还有编译器用于定位函数的表达式这里把它省略了
　　add esp,8 清栈
　　函数体：
　　push ebp
　　mov ebp,esp
　　sub esp,40h 函数使用的栈默认为40H(16*4),增加一个变量加4bytesWIN32下栈的粒度为4bytes。
　　push ebx
　　push esi
　　push edi
　　lea edi,[ebp-40h] 初始化用于该函数的栈空间为0XCCCCCCCC
　　mov ecx,10h
　　mov eax,0CCCCCCCCh
　　rep stos dword ptr [edi]
　　return (a + b);
　　mov eax,dword ptr [ebp+8]
　　add eax,dword ptr [ebp+0Ch]
　　pop edi
　　pop esi
　　pop ebx
　　mov esp,ebp 如果在此函数中对ESP进行操作，则会有add esp, 40h cmp esp,ebp call chkesp, 检查弹出的ESP指针是否和EBP相同，若不同则调用chkesp抛出异常
　　pop ebp
　　ret
　　下图指出了该函数的栈的使用情况:
　　
　　
　　
　　2、Pascal语言调用约定
　　大部分的Windows API都采用Pascal语言调用约定。采用C语言编程的时候，如果要采用这种调用约定，需要在函数声明的时候加上__stdcall关键字。windows.h头文件中也定义了一个WINAPI的宏，起同样的作用。采用本约定时，参数从右到左入栈，个数固定。因此，函数体本身就能知道传进来的参数个数，可以用一条ret n指令直接清理堆栈。牺牲灵活性换来的，是性能的提高。生成的代码中函数名一个_(下划线)做前缀、一个@和参数总字节数(十进制)作后缀(参数的个数乘以4)。WINAPI CALLBACK APIENTRY PASCAL 都是__stdcall的宏定义，而__pascal是一个废弃的关键词。
　　举例：
　　int __stdcall Add(int a, int b)
　　{
　　return (a + b);
　　}
　　
　　函数的调用：
　　push 2
　　push 1
　　call _Add@8 ;这里使用了连接时使用的函数名
　　
　　函数体：
　　;和__cdecl一样，最后一行如下：
　　ret 8 清栈
　　3、This调用约定
　　用于C++中的非静态类成员函数，它只能被编译器使用，没有相应的关键字。在Intel IA32架构下，此调用约定跟PASCAL语言调用约定相同，只是另外通过ECX寄存器传送一个额外的参数—this指针。在函数中清理栈，不能在C中使用，没有C的换名规则，所以说类的非静态成员函数不能作为回调函数。
　　举例：
　　struct CSum
　　{
　　int Add(int a, int b)
　　{
　　return (a + b);
　　}
　　};
　　函数调用：
　　CSum sum;
　　sum.Add(1, 2);
　　push 2
　　push 1
　　lea ecx,[ebp-4] ecx存放了this指针
　　call ?Add@CSum@@QAEHHH@Z 当重复定义一个类成员函数时，可以在输出框中得到该名字
　　
　　函数体：
　　push ebp
　　mov ebp,esp
　　sub esp,44h 多用了一个4bytes的空间用于存放this指针
　　push ebx
　　push esi
　　push edi
　　push ecx
　　lea edi,[ebp-44h]
　　mov ecx,11h
　　mov eax,0CCCCCCCCh
　　rep stos dword ptr [edi]
　　pop ecx
　　mov dword ptr [ebp-4],ecx
　　
　　return (a + b);
　　mov eax,dword ptr [ebp+8]
　　add eax,dword ptr [ebp+0Ch]
　　pop edi
　　pop esi
　　pop ebx
　　mov esp,ebp
　　pop ebp
　　ret 8 清栈
　　4、快速调用约定
　　这种调用约定用于对性能要求非常高的场合，关键字是__fastcall。它要求将参数放在寄存器中，以提高速度。在Intel IA32架构下，此调用约定将函数最左边两个大小小于4个字节（DWORD的大小）的参数放在ECX和EDX寄存器，其余规定同Pascal调用约定。生成的代码中函数名有一个@做前缀和一个@加上参数
　　总字节数(十进制)作后缀。
　　举例：
　　int __fastcall Add(int a, int b, int c)
　　{
　　return (a + b + c);
　　}
　　函数的调用：
　　Add(1, 2, 3);
　　push 3
　　mov edx, 2
　　mov ecx, 1
　　call @Add@8 这里使用了连接时使用的函数名
　　函数体：
　　push ebp
　　mov ebp,esp
　　sub esp,48h 多使用了两个变量在[ebp-4]、[ebp-8]
　　push ebx
　　push esi
　　push edi
　　push ecx
　　lea edi,[ebp-48h]
　　mov ecx,12h
　　mov eax,0CCCCCCCCh
　　rep stos dword ptr [edi]
　　pop ecx
　　mov dword ptr [ebp-8],edx 还是将edx,ecx的内容放在
　　mov dword ptr [ebp-4],ecx ;栈中似乎并没有提高速度
　　return (a + b + c);
　　mov eax,dword ptr [ebp-4]
　　add eax,dword ptr [ebp-8]
　　add eax,dword ptr [ebp+8]
　　pop edi
　　pop esi
　　pop ebx
　　mov esp,ebp
　　pop ebp
　　ret 4 清栈
　　5、裸调用约定
　　当嵌入式汇编程序员需要手工控制调用约定的时候，使用这 种方法。它没有相应的关键字，但是有一个__declspec(naked)用来指定这种调用约定。它不能用于函数声明，只能用于函数定义，也就是说，它只能让编译器不要生成函数体中的堆栈管理代码，但是调用函数者依然需要前面的某种调用约定来生成调用函数的代码。此协定本人没用过，希望有高手补充。
　　本文参考：
　　http://www.codeproject.com/cpp/calling_conventions_demystified.asp
　　以及优快云上众多网友的回答。

本文转自
http://www.moon-soft.com/doc/12118.htm