CMake使用CPack制作安装程序

已于 2025-01-23 18:10:21 修改
阅读量916 收藏 31
点赞数 16
分类专栏： cmake 文章标签： cmake cpack rpm deb dmg pkg rpath
于 2025-01-23 17:15:50 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.youkuaiyun.com/witton/article/details/145307607
版权

CPack的功能很强大，笔者前面有一博文使用CMake的CPack工具打包项目介绍了一下使用CPack来打包成7z压缩文件，不仅如此，它还可以生成各平台的安装包。

CPack支持以下类型的生成器：

名称文件类型平台及说明
STGZSTGZ(.sh)自解压文件，支持shell脚本的平台
7Z7zip(.7z)跨平台
ZIPZIP(.zip)跨平台
TGZTGZ(.tar.gz)跨平台
TXZTXZ(.tar.xz)跨平台
TBZ2TBZ2(.tar.bz2)跨平台
TZTZ(.tar)跨平台
TZSTTZST(.tar.zst)跨平台
RPMRPM(.rpm)Linux，用于redhat系产品
DEBDEB(.deb)Linux，用于Debian, ubuntu系列产品
DragNDropDMG(.dmg)macOS
productbuildPKG(.pkg)macOS
BundleBundle(.bundle)macOS
NSISBinary(.exe)Windows
INNOSETUPBinary(.exe)Windows
NuGetNuGet(.nupkg)Windows
WIXMSI(.msi)Windows
IFWBinaryLinux, Windows, macOS,使用QtIFW编译器生成
ExternalJSON(.json)与外部打包工具集成
FreeBSDPKG(pkg)BSD，Linux, OSX

本文就介绍一下如何使用CPack来制作各个主流平台的应用程序安装程序。

关于CPack的知识，可以参考https://cmake.org/cmake/help/latest/module/CPack.html

一、Linux

1. RPM

RPM安装包格式适用于red hat出品的系统RHEL以及centos。

安装rpmbuild

要制作RPM包，必须要先安装rpmbuild命令。

在ubuntu下使用下面的命令安装：

sudo apt install rpm

安装后既可以使用rpm命令，也可以使用rpmbuild命令。

如果是CentOS系统，默认是有rpm命令的，需要使用下面的命令单独安装rpmbuild。

 yum install rpm-build

CMakeLists.txt设置

#设置安装规则
install(TARGETS ${PROJECT_NAME} DESTINATION /usr/local/bin)
#设置CPack生成器为RPM
set(CPACK_GENERATOR "RPM")
#设置CPack项目名称
set(CPACK_PROJECT_NAME ${PROJECT_NAME})
#设置CPack项目版本
set(CPACK_PROJECT_VERSION ${PROJECT_VERSION})
#必须包含CPack的cmake文件
include(CPack)

2. DEB

DEB格式适用于Debian以及Ubuntu系统。CMakeLists.txt设置：

#设置安装规则
install(TARGETS ${PROJECT_NAME} DESTINATION /usr/local/bin)
# DEB要求设置`CPACK_PACKAGE_CONTACT`或者`CPACK_DEBIAN_PACKAGE_MAINTAINER`变量
set(CPACK_PACKAGE_CONTACT "witton@163.com")
#设置CPack生成器为RPM
set(CPACK_GENERATOR "DEB")
#设置CPack项目名称
set(CPACK_PROJECT_NAME ${PROJECT_NAME})
#设置CPack项目版本
set(CPACK_PROJECT_VERSION ${PROJECT_VERSION})
#必须包含CPack的cmake文件
include(CPack)

生成好DEB格式后，可以使用apt命令安装：

sudo apt install ./demo-0.1.0-Linux.deb

如果想要生成多种安装包格式，可以在CPACK_GENERATOR变量中填写多个，以分号隔开：

set(CPACK_GENERATOR "DEB;RPM")

二、MacOS

macOS下制作安装包，稍麻烦一点，最主要的问题是动态库的搜索路径问题，在Linux下可以使用ldconfig进行配置，但是MacOS下没有这样的工具，虽然有环境变量DYLD_LIBRARY_PATH 或 DYLD_FALLBACK_LIBRARY_PATH可以设置，但是如果生成程序的时候rpath没有设置为@rpath开头的路径，而是使用的绝对路径，就是灾难。

所以在生成程序时，最好是设置程序的动态库路径为@rpath开头的路径。有关MacOS程序的@rpath、@loader_path、@executable_path可以在网络上搜索相关资料。

这里我们以一个实例来讲，更好理解。下面为t项目结构：

在这里插入图片描述

有一个lib库，提供了一个函数foo，供main.cc调用，lib.h与priv.h分别为lib库的公开头文件与私有头文件。

lib/lib.cc：

#include <iostream>
using namespace std;

void foo() {
    cout << "foo" << endl;
}

lib/lib.h：

#ifndef __LIB__H__
#define __LIB__H__

#include "priv/priv.h"

void foo();

#endif //__LIB__H__

lib/priv/priv.h：

#pragma once

#ifndef __LIB__H__
#error 私有头文件不能直接包含，需要include `lib.h`
#endif

// 这是私有头文件

为了展示动态库和静态的安装，这里把lib库，既编译成动态库，也编译成静态库：

lib/CMakeLists.txt：

cmake_minimum_required(VERSION 3.25.0)
project(tlib VERSION 0.1.0)

add_library(${PROJECT_NAME} SHARED lib.cc)
add_library(${PROJECT_NAME}s lib.cc)

#设置库的公开头文件，注意，这里一定要加上${CMAKE_CURRENT_SOURCE_DIR}，不然安装时会找不到文件
set_target_properties(${PROJECT_NAME} PROPERTIES PUBLIC_HEADER ${CMAKE_CURRENT_SOURCE_DIR}/lib.h)
#设置库的私有头文件
set_target_properties(${PROJECT_NAME} PROPERTIES PRIVATE_HEADER ${CMAKE_CURRENT_SOURCE_DIR}/priv/priv.h)

main.cc：

#include <stdio.h>
#include <stdlib.h>
#include "lib.h"

int main(int argc, char *argv[])
{
    foo();
    return 0;
}

CMakeLists.txt：

cmake_minimum_required(VERSION 3.25.0)
project(t VERSION 0.1.0)

add_subdirectory(lib)
aux_source_directory(. SRC)

add_executable(${PROJECT_NAME} ${SRC})
target_include_directories(${PROJECT_NAME} PUBLIC lib)
target_link_libraries(${PROJECT_NAME} tlib)

#设置安装规则
install(TARGETS ${PROJECT_NAME} tlib tlibs
	ARCHIVE DESTINATION ${PROJECT_NAME}/lib #静态库，macOS中标记为“FRAMEWORK”除外
	LIBRARY DESTINATION ${PROJECT_NAME}/lib #动态库，macOS中标记为“FRAMEWORK”除外
	RUNTIME DESTINATION ${PROJECT_NAME}/bin #可执行文件，macOS中标记为“MACOSX_BUNDLE”除外
	FRAMEWORK DESTINATION ${PROJECT_NAME}/framework # 在 macOS上，标有“FRAMEWORK”属性的静态库和共享库都被视为“FRAMEWORK”目标。
	PUBLIC_HEADER DESTINATION ${PROJECT_NAME}/include # 与库关联的任何公开头文件
	PRIVATE_HEADER DESTINATION ${PROJECT_NAME}/include/priv # 与库关联的任何私有头文件
)

我们期望最终制作的安装包，安装后的结构：

在这里插入图片描述

1. dmg

为了制作dmg格式的安装包，CMakeLists.txt文件中添加

# 需要设置`${PROJECT_NAME}`目标的属性`INSTALL_RPATH`为`@loader_path/../lib`，
# 即安装后的运行时路径为`@loader_path/../lib`，@loader_path是重点，
# 是相对于可执行文件的路径，否则会出现找不到`libtlib.dylib`库。
# 可以设置多个路径，在后面直接添加即可，比如再添加`/usr/local/lib`
set_property(
	TARGET ${PROJECT_NAME}
	PROPERTY
	INSTALL_RPATH
	"@loader_path/../lib"
	"/usr/local/lib"
)
# 设置CPACK的生成器类型为`DragNDrop`
set(CPACK_GENERATOR DragNDrop)
#设置CPack的项目名
set(CPACK_PROJECT_NAME ${PROJECT_NAME})
#设置CPack的项目版本号
set(CPACK_PROJECT_VERSION ${PROJECT_VERSION})
#必须包含CPack
include(CPack)

执行CPack打包命令后，会生成t-0.1.0-Darwin.dmg安装包，在MacOS系统中双击加载后好即可拖曳安装了，与其它DMG安装包一样。
在这里插入图片描述

拖曳安装好后，执行：

在这里插入图片描述

使用otool -L ./t命令来查看依赖：

在这里插入图片描述

使用otool -l ./t命令来查看rpath：

在这里插入图片描述

完整的CMakeLists.txt：

cmake_minimum_required(VERSION 3.25.0)
project(t VERSION 0.1.0)

add_subdirectory(lib)

aux_source_directory(. SRC)

add_executable(${PROJECT_NAME} ${SRC})
target_include_directories(${PROJECT_NAME} PUBLIC lib)
target_link_libraries(${PROJECT_NAME} tlib)

#设置安装规则
install(TARGETS ${PROJECT_NAME} tlib tlibs
	ARCHIVE DESTINATION ${PROJECT_NAME}/lib #静态库，macOS中标记为“FRAMEWORK”除外
	LIBRARY DESTINATION ${PROJECT_NAME}/lib #动态库，macOS中标记为“FRAMEWORK”除外
	RUNTIME DESTINATION ${PROJECT_NAME}/bin #可执行文件，macOS中标记为“MACOSX_BUNDLE”除外
	FRAMEWORK DESTINATION ${PROJECT_NAME}/framework # 在 macOS上，标有“FRAMEWORK”属性的静态库和共享库都被视为“FRAMEWORK”目标。
	PUBLIC_HEADER DESTINATION ${PROJECT_NAME}/include # 与库关联的任何公开头文件
	PRIVATE_HEADER DESTINATION ${PROJECT_NAME}/include/priv # 与库关联的任何私有头文件
)
# 需要设置`${PROJECT_NAME}`目标的属性`INSTALL_RPATH`为`@loader_path/../lib`，
# 即安装后的运行时路径为`@loader_path/../lib`，@loader_path是重点，
# 是相对于可执行文件的路径，否则会出现找不到`libtlib.dylib`库。
# 可以设置多个路径，在后面直接添加即可，比如再添加`/usr/local/lib`
set_property(
	TARGET ${PROJECT_NAME}
	PROPERTY
	INSTALL_RPATH
	"@loader_path/../lib"
	"/usr/local/lib"
)

# 设置CPACK的生成器类型为`DragNDrop`
set(CPACK_GENERATOR DragNDrop)
#设置CPack的项目名
set(CPACK_PROJECT_NAME ${PROJECT_NAME})
#设置CPack的项目版本号
set(CPACK_PROJECT_VERSION ${PROJECT_VERSION})
#必须包含CPack
include(CPack)

2. pkg

CPack生成器productbuild可以生成macOS下的pkg安装包。
将前面的CPACK_GENERATOR 改为productbuild，再使用cpack_add_component(${PROJECT_NAME} REQUIRED)添加进组件即可生成一个简单的安装包，如果没有使用cpack_add_component(${PROJECT_NAME} REQUIRED)添加组件，只会生成一个空包。

完整的CMakeLists.txt：

cmake_minimum_required(VERSION 3.25.0)
project(t VERSION 0.1.0)

add_subdirectory(lib)

aux_source_directory(. SRC)

add_executable(${PROJECT_NAME} ${SRC})
target_include_directories(${PROJECT_NAME} PUBLIC lib)
target_link_libraries(${PROJECT_NAME} tlib)

#设置安装规则
install(TARGETS ${PROJECT_NAME} tlib tlibs
	ARCHIVE DESTINATION ${PROJECT_NAME}/lib #静态库，macOS中标记为“FRAMEWORK”除外
	LIBRARY DESTINATION ${PROJECT_NAME}/lib #动态库，macOS中标记为“FRAMEWORK”除外
	RUNTIME DESTINATION ${PROJECT_NAME}/bin #可执行文件，macOS中标记为“MACOSX_BUNDLE”除外
	FRAMEWORK DESTINATION ${PROJECT_NAME}/framework # 在 macOS上，标有“FRAMEWORK”属性的静态库和共享库都被视为“FRAMEWORK”目标。
	PUBLIC_HEADER DESTINATION ${PROJECT_NAME}/include # 与库关联的任何公开头文件
	PRIVATE_HEADER DESTINATION ${PROJECT_NAME}/include/priv # 与库关联的任何私有头文件
)
# 需要设置`${PROJECT_NAME}`目标的属性`INSTALL_RPATH`为`@loader_path/../lib`，
# 即安装后的运行时路径为`@loader_path/../lib`，@loader_path是重点，
# 是相对于可执行文件的路径，否则会出现找不到`libtlib.dylib`库。
# 可以设置多个路径，在后面直接添加即可，比如再添加`/usr/local/lib`
set_property(
	TARGET ${PROJECT_NAME}
	PROPERTY
	INSTALL_RPATH
	"@loader_path/../lib"
	"/usr/local/lib"
)

# 设置CPACK的生成器类型为`productbuild`
set(CPACK_GENERATOR productbuild)
#设置CPack的项目名
set(CPACK_PROJECT_NAME ${PROJECT_NAME})
#设置CPack的项目版本号
set(CPACK_PROJECT_VERSION ${PROJECT_VERSION})
#必须包含CPack
include(CPack)
#这里必须使用cpack_add_component命令添加组件，否则只会生成一个空包
cpack_add_component(${PROJECT_NAME} REQUIRED)

安装情况如下所示：

在这里插入图片描述

在这里插入图片描述

在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述

默认情况下，介绍，请先阅读，许可三个页面的内容是CPack的模板内容，是三个txt文本文件，需要自定义一下，可以使用html文件。在项目根目录添加一个res目录，把所有自定义的CPack安装模板放在里面，现在目录树：

在这里插入图片描述

welcome.html：

<html>
	<head>
		<meta charset="utf-8">
	</head>
	<body>
		<h1>欢迎使用macOS软件t</h1>
	</body>
</html>

readme.html：

<html>
	<head>
		<meta charset="utf-8">
	</head>
	<body>
		<h1>读一下我吧！</h1>
	</body>
</html>

license.html：

<html>
	<head>
		<meta charset="utf-8">
	</head>
	<body>
		<h1>版权所有(C)，Witton Bell</h1>
	</body>
</html>

CMakeLists.txt设置：

set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/res/welcome.html")
set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/res/license.html")
set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/res/readMe.html")

# 设置CPACK的生成器类型为`productbuild`
set(CPACK_GENERATOR productbuild)
#设置CPack的项目名
set(CPACK_PROJECT_NAME ${PROJECT_NAME})
#设置CPack的项目版本号
set(CPACK_PROJECT_VERSION ${PROJECT_VERSION})
#必须包含CPack
include(CPack)
cpack_add_component(${PROJECT_NAME} REQUIRED)

现在生成的安装包，运行如下所示：

在这里插入图片描述

在这里插入图片描述

在这里插入图片描述

三、Windows

Window下介绍一下NSIS/NSIS64，它是一个开源的安装包制作工具。
使用nsis软件来制作安装包，需要先下载nsis并安装。
设置CPack的生成器为NSIS或者NSIS64，该安装程序的许可证是UTF16编码格式的文本。

CMakeLists.txt设置：

set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/res/license.txt")

# 设置CPACK的生成器类型为`NSIS64`
set(CPACK_GENERATOR NSIS64)
#设置CPack的项目名
set(CPACK_PROJECT_NAME ${PROJECT_NAME})
#设置CPack的项目版本号
set(CPACK_PROJECT_VERSION ${PROJECT_VERSION})
#必须包含CPack
include(CPack)

它有一些特殊的变量，可以自定义安装界面的一些显示，具体参见：https://cmake-doc.readthedocs.io/zh-cn/latest/cpack_gen/nsis.html

在这里插入图片描述

NSIS软件可以做很多定制，感兴趣的读者可以继续深究！

四、自解压安装包

自解压安装包是使用的shell脚本作为安装程序的，它的CMakeLists.txt设置：

#设置许可证文本的文件，而不是内容
set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/res/license.txt")
# 设置CPACK的生成器类型
set(CPACK_GENERATOR "STGZ")
#设置CPack的项目名
set(CPACK_PROJECT_NAME ${PROJECT_NAME})
#设置CPack的项目版本号
set(CPACK_PROJECT_VERSION ${PROJECT_VERSION})
set(CPACK_PACKAGE_VENDOR "Witton Bell")
#必须包含CPack
include(CPack)

实际上它是根据CMake安装目录下share/cmake/Modules/Internal/CPack/CPack.STGZ_Header.sh.in的模板文件来生成的。

它主要可以定制以下变量：

  • CPACK_PACKAGE_NAME：包名
  • CPACK_PACKAGE_VERSION：包版本
  • CPACK_PACKAGE_VENDOR：包所有者
  • CPACK_RESOURCE_FILE_LICENSE_CONTENT：直接设置许可证内容

在这里插入图片描述

如果想要定制更多内容，可以修改CPack.STGZ_Header.sh.in模板文件的内容。

如果对你有帮助，欢迎点赞收藏！

CMake入门教程【高级篇】CPack打包项目Linux的deb和windows的msi
小鱼酱的博客
01-10 745
CMake中CPack打包项目Linux的deb和windows的msi
学习SLAM：SLAM进阶（四）CMake应用篇---打包、部署和安装 CMake 项目
qq_41694024的博客
06-27 3827
通过本章学习，读者可以学会如何完整、部分安装库文件、可执行文件、目录。
打包大师：CMake中CPack的使用指南
07-26
CMake是一个跨平台的自动化构建系统，它使用配置文件（通常称为CMakeLists.txt）来生成标准的构建环境。CMake能够生成多种编译器和IDE的构建文件，例如Unix的Makefile、Windows的Visual Studio解决方案和Xcode项目文件。CMake支持多种编程语言，但最初是为C++设计的。 CMake的主要特点包括： 1. **跨平台**：可以在多种操作系统上使用，包括Windows、Linux、macOS等。 2. **可定制**：通过编写CMakeLists.txt文件，用户可以定义自己的构建规则和配置选项。 3. **生成多种构建系统**：可以生成适合不同编译器和IDE的构建文件。 4. **依赖管理**：可以自动处理库依赖和项目依赖。 5. **模块化**：CMake提供了许多内置模块，方便进行复杂的构建配置。 CMake广泛用于开源项目和商业项目中，是许多大型项目和库的标准构建工具之一。
CMake/CPack学习小计
一期一会
02-17 1627
从hello world开始 最基础的使用和语法 hello world工程的CMakeLists文件 cmake核心概念 三大核心概念间的关系 target generator command cmake语法 variable 普通变量 cache变量 ENV变量 条件、循环语句 if foreach while 函数 宏 install cpack使用 使用cm...
CMake之CPack
喜欢打篮球的普通人
07-07 3448
在上面的CMakeLists.txt中，最重要的是INSTALL这个指令，上面的INSTALL指令所表达的意思是，需要将LinkLibraryDemo, PrinterInt, PrinterChar 这3个文件打包，其中可执行文件放在/tmp/cmake_demo，这个目录中，静态库和动态库文件则放在默认目录中。如果你不赋值CPACK_DEBIAN_PACKAGE_DEPENDS这个变量，则在debian/control文件中，没有Depends这一行，虽然在你自己的机器上不影响打包构建。
cpack
bacanpi5506的博客
12-11 475
一. 简介 CPack是CMake 2.4.2之后的一个内置工具，主要作用就是生成制定类型的安装包．它可以脱离cmake单独运行． 二. 基本设置 (mandatory) 设置包类型set(CPACK_GENERATOR "DEB") NOTE:参数可以是你所知道的任意压缩包类型,rpm,tar.gz等等,请参见官方wiki 设置软件包版本set(CPACK...
CMake 学习【七】—— 生成一个安装器
xiaodouhao123456的博客
11-05 394
如果我们想要把自己的工程释放给别人使用，想在多个不同的平台同时提供二进制和源码包。我们将使用CPack来创建特定平台的安装器。 那么我们将按照下面的方法进行构建： 1. 在顶层的CMakeLists.txt的末尾添加一些代码 include(InstallRequiredSystemLibraries) set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/License.txt") set(CPACK_PACKAGE_VERSION_MA
CMake中的CPack
m0_61629312的博客
12-05 313
CPack 提供了一种简单的方法来生成各种不同类型的软件包，如二进制安装程序、压缩文件（如 ZIP 或 TAR）、操作系统特定的软件包（如 RPM、DEB、NSIS 等）。CPack 可以与 CMakeLists.txt 文件一起使用，通过在 CMake 构建过程中添加一些特定的指令和变量，来定义软件包的属性和配置。使用 CPack 可以简化软件打包和分发的过程，使得可以更轻松地将您的软件交付给用户或其他开发人员。根据需求，可以选择适合项目的软件包生成器，并根据平台的要求进行相应的配置。
使用CMake+Visual Studio构建Qt程序（二）
TinyHou的博客
05-25 1797
在上一篇文章中，我们成功生成并执行了自己的HelloWorld，接下来将进一步完善其构建方法，使其更加方便更加自动化。同时也会介绍安装打包以及增加程序功能的方法。 设置CMakeLists中的变量来更改VS项目的默认设置 上篇文章结尾我们得到了一个有控制台窗口的HelloWorld程序。我们可以通过修改Visual Studio中的设置来隐藏控制台窗口。 也可以在CMakeLists.txt中添加如下内容达到相同效果： set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_.
如何使用cmake打包C++项目
小舟的博客
09-13 544
请注意，这只是一个基本的示例，对于更复杂的项目，可能需要更多的CMake配置，例如处理依赖关系、添加测试等。这将根据你配置的CPack生成器创建相应的安装包（如。等），其中包含了你的库文件和头文件。创建一个构建目录（例如。
cmake制作deb包
Aggressive_snail的专栏
02-05 3967
以前写的程序都是自己布局DEBIAN结构，这次的项目是用cmake管理的，也是第一次接触，想想这东西应该能自动打包了吧，毕竟cmake高大上啊！ 找了一下，还真行，cpack就是cmake提供的一个打包工具。 下面是CMakeLists.txt关于打包部分的设置： #准备的版本设置 set(_VERSION_MAJOR 1) set(_VERSION_MINOR 0) set(
CPack-开源
05-29
CPack 是一个用 C 编写的简单的快速库，用于归档文件。 它可用于支持 SFX 的游戏引擎或存档器。 该包只能包含 64（查看 CPack.h #define stringsize 以更改密钥长度）字节密钥长度，因此它不支持目录。 支持检查包的版本。 mmap-ing 的跨平台实现。 在 CPack.h 中定义禁用内存映射注释。 要更改压缩和散列算法，请查看 CPack.c 中的宏。未来更改：加密所有密钥。
CPack 入门指南
danshiming的博客
07-18 1429
因为是 CMake 的内置工具，所以使用的方式也是通过在 CMakeLists.txt 配置参数，就能达到我们的需求。使用起来很方便，容易上手。上述配置是将所有需要打包的文件打包成一个安装包，但一个项目往往会有多个不同服务，在实施部署时需安装到不同的机子上，这个时候如果把所有服务一起打包，会导致部署时包太大。然后修改 src/CMakeLists.txt，看下图红框内容，将 program A 二进制文件配置为 AComponent，将 program B 二进制文件配置为 BComponent。
cmake：命令行工具cpack
OceanStar的博客
06-30 2049
概要 cpack [<options>] 描述 cpack可执行文件是CMake打包程序。它以各种格式生成安装程序和源程序包。 对于每个安装程序或包格式，cpack都有一个特定的后端，称为“生成器”。生成器负责生成所需的输入并调用特定的包创建工具。不要将这些安装程序或包生成器与cmake命令的makefile生成器混淆。 cpack generators手册中指定了所有支持的生成器。 cpack–help命令打印目标平台支持的生成器列表。 可以通过CPACK_GENERATOR变量或命令行
【学习笔记】Mastering CMake （十四）—— 使用 CPack 打包
最新发布
cxsydzn的博客
10-27 1430
为了避免转义问题，可以指定项目特定的 CPack 配置文件。此文件将在 CPackConfig.cmake 或 CPackSourceConfig.cmake 被加载后由 CPack 加载，并且将被设置为正在运行的 CPack 生成器。该文件中设置的变量只需要一级 CMake 转义。这个文件可以配置，也可以不配置，它包含常规的 CMake 代码。在上面的例子中，你可以将 CPACK_FOOBAR 移动到文件 MyCPackOptions.cmake.in 中，并将该文件配置到项目的构建树中。@ONLY)
使用CMake的CPack工具打包项目
witton的专栏
04-18 1508
在实际的开发中，可能会有各种各样的配置文件需要在打包的时候一起发布出去，这里在根目录下创建一个bin目录（将所有项目生成的文件全部指定生成到此目录下的各个项目目录中），下面再创建一个demo目录（根据项目来取名），在demo目录中创建一个config.ini文件。可以在build_CPack_Packages\win64\7Z\demo-0.1.0-win64查看打包的情况，这里有额外的include与lib，并不是想要的，是因为使用的GTest为自行编译的库，如果不想让它们出现在包中，可以。
cmake CPack 打包指定目录
zfjBIT的专栏
07-08 1528
CPack说明文档：https://runebook.dev/zh-CN/docs/cmake/module/cpackCPack 是 CMake 2.4.2 之后的一个内置工具，用于创建软件的二进制包和源代码包。
cmake使用教程（五）-cpack生成安装包
weixin_33807284的博客
02-01 1850
【cmake系列使用教程】 cmake使用教程（一）-起步 cmake使用教程（二）-添加库 cmake使用教程（三）-安装、测试、系统自检 cmake使用教程（四）-文件生成器 cmake使用教程（五）-cpack生成安装包 cmake使用教程（六）-蛋疼的语法 cmake使用教程（七）-流程和循环 cmake使用教程（八）-macro和function 这个系列的文章翻译自官方cmake教程：...
CMake/CPack变量之CPACK_SET_DESTDIR
wanglei9876开发人生
01-29 1274
Boolean toggle to make CPack use DESTDIR mechanism when packaging.DESTDIR means DESTination DIRectory. It is commonly used by makefile users in order to install software at non-default location. It is
cmake使用cpack打包
06-02
使用CMake和CPack可以很方便地为你的C++项目创建安装程序或打包文件，以下是一个基本的示例： 1. 在项目的根目录下，创建一个CMakeLists.txt文件，并编写以下内容： ``` cmake_minimum_required(VERSION 3.1) project(MyProject) # 添加可执行文件 add_executable(MyExecutable main.cpp) # 添加安装目标 install(TARGETS MyExecutable DESTINATION bin) # 添加CPack模块 include(CPack) ``` 在这里，我们首先指定了项目的名称和最低要求的CMake版本，然后添加了一个可执行文件(MyExecutable)，并将其安装到bin目录下。最后，我们包含了CPack模块，以便用于生成打包文件。 2. 在终端中，进入项目的根目录，并运行以下命令： ``` mkdir build cd build cmake .. make ``` 这将创建一个build目录，并在其中生成Makefile文件。然后运行make命令来编译和构建项目。 3. 运行以下命令生成打包文件： ``` cpack ``` 这将使用CPack生成一个默认的打包文件，根据CMakeLists.txt文件中的指令，将MyExecutable可执行文件安装到bin目录下。 你可以通过指定不同的CPack参数来创建不同类型的打包文件，例如： ``` cpack -G ZIP # 生成Zip压缩文件 cpack -G DEB # 生成Debian软件包 cpack -G RPM # 生成RedHat软件包 ``` 希望这个简单的示例可以帮助你开始使用CMake和CPack来打包你的C++项目。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值