StrToInt / IntToStr Asm For Delphi

最新推荐文章于 2021-09-03 11:21:15 发布

weixin_34249367

最新推荐文章于 2021-09-03 11:21:15 发布

阅读量143

点赞数

CC 4.0 BY-SA版权

原文链接：http://www.cnblogs.com/bsoom/archive/2009/11/26/1611589.html

本文介绍了一种使用汇编语言实现整数到字符串（IntToStr）及字符串到整数（StrToInt）的转换方法。通过具体的汇编指令，文章详细展示了如何处理正负数，并实现了数值的有效转换。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

Code
function IntToStr(Value: Integer): ShortString;
// Value  = eax
// Result = edx
asm
  push ebx
  push esi
  push edi

  mov edi,edx
  xor ecx,ecx
  mov ebx,10
  xor edx,edx

  cmp eax,0 // check for negative
  setl dl
  mov esi,edx
  jnl @reads
  neg eax

  @reads:
    mov  edx,0   // edx = eax mod 10
    div  ebx     // eax = eax div 10
    add  edx,48  // '0' = #48
    push edx
    inc  ecx
    cmp  eax,0
  jne @reads

  dec esi
  jnz @positive
  push 45 // '-' = #45
  inc ecx

  @positive:
  mov [edi],cl // set length byte
  inc edi

  @writes:
    pop eax
    mov [edi],al
    inc edi
    dec ecx
  jnz @writes

  pop edi
  pop esi
  pop ebx
end;

Code

function StrToInt(Value: ShortString): Integer;
// Value   = eax
// Result  = eax
asm
  push ebx
  push esi

  mov esi,eax
  xor eax,eax
  movzx ecx,Byte([esi]) // read length byte
  cmp ecx,0
  je @exit

  movzx ebx,Byte([esi+1])
  xor edx,edx // edx = 0
  cmp ebx,45  // check for negative '-' = #45
  jne @loop

  dec edx // edx = -1
  inc esi // skip '-'
  dec ecx

  @loop:
    inc   esi
    movzx ebx,Byte([esi])
    imul  eax,10
    sub   ebx,48 // '0' = #48
    add   eax,ebx
    dec   ecx
  jnz @loop

  mov ecx,eax
  and ecx,edx
  shl ecx,1
  sub eax,ecx

  @exit:
  pop esi
  pop ebx
end;

转载于:https://www.cnblogs.com/bsoom/archive/2009/11/26/1611589.html