svn开机自启动的批处理文件

网上找的一个文件。

原文：http://blog.163.com/air-blue55/blog/static/9708657020105612454398/

 

==svn开机自启动=====================

创建autoRunSVN.bat文件，内容是：

 

Cpp代码

sc create MySVNServer binpath= "\"C:\Program Files\Subversion\svnserve\svnserve\" --service -r H:\homerepos" displayname= "SVNService" depend= Tcpip start= auto  

pause 

sc create MySVNServer binpath= "\"J:\java\Subversion\bin\svnserve.exe" --service -r \"G:\svn repository\"" displayname= "SVNService" depend= Tcpip start= auto

pause

 注意之处：

（1）sc是windows自带的服务配置程序，MySVNServer 是服务的名称，似乎没什么用。

 

（2）参数binPath表示svnserve可执行文件的安装路径，由于路径中的"Program Files"带有空格，因此整个路径需要用双引号引起来。而双引号本身是个特殊字符，需要进行转义，因此在路径前后的两个双引号都需要写成\" 。

（3）--service参数表示以windows服务的形式运行，--r指明svn repository的位置，service参数与r参数都作为binPath的一部分，因此与svnserve.exe的路径一起被包含在一对双引号当中，而这对双引号不需要进行转义。

 

（4）displayname表示在windows服务列表中显示的名字， depend =Tcpip 表示svnserve服务的运行需要tcpip服务，start=auto表示开机后自动运行。安装服务后，svnserve要等下次开机时才会自动运行。 （5）binPath的等号前面无空格，等号后面有空格 displayname depend start也都一样

service前面是--，不是- ，而r前面是-

（6）若要卸载svn服务，则执行 sc delete svnserve 即可。 

 

（7）从“sc”到“auto”是在同一个命令sc，必须写在同一行。

 

      创建成功后，可以在运行中键入service.msc察看系统服务，找到SVNService项，查看这项服务的属性，可以使用Windows提供的界面操作SVNService服务了。

P.S. 经本人实验，以上的SVN开机自启动方法一直无法实现，由于不会写批处理语句，也不知道是哪里错，但网上很多地方都是用这种方法去实现  开机自启动。最后，只能重新找了一种新方法，虽然无法开机自启动，但可以较方便实现多个服务进程和管理多个文件夹，请各位自行选择。

创建SVNService.bat文件，内容如下（尊重作者版权，请勿删除作者信息）：

@ECHO OFF
::======================================================================
::作者     : Zealic
::版本     : 1.05
::功能     : 通过简便快捷的方式安装 Subversion.
::最后更新 : 2007-12-28
::======================================================================
::初始化环境
::======================================================================

ECHO *** 安装 Subversion 服务 ***

::======================================================================
::======================================================================
::创建服务
::======================================================================
ECHO +++ 创建资源库服务 +++
ECHO 创建系统服务，这需要输入一些信息...

:INPUT_SVC_NAME
SET /P svc_name=请输入服务名     :
::服务名不能为空值
if "%svc_name%" == "" (
  ECHO 服务名不能为空，请重新输入。
  GOTO INPUT_SVC_NAME
)
::查询服务是否存在，通过查找输出是否存在错误，"1060:"是发生错误是时输出的错误代码。
SC QUERY "%svc_name%" | find "1060:" >> NUL
IF %errorlevel% == 1 (
  ECHO 服务 "%svc_name%" 已经存在！请重新输入服务名。
  GOTO INPUT_SVC_NAME
)
ECHO.

::输入资源库信息
:INPUT_REPOS
SET /P    repos=请输入资源库路径 :
ECHO.

::创建服务
ECHO 您使用以下信息创建 Subversion 服务 :
ECHO 服务名称   : "%svc_name%"
ECHO 资源库路径 : "%repos%"
ECHO 正在创建服务...
SC create %svc_name% binPath= "\"E:\Subversion\bin\svnserve.exe\" --service -r \"%repos%\"" depend= Tcpip start= auto| find "1060:" >> NUL
ECHO.
IF %errorlevel% == 0 GOTO SC_ERROR
ECHO --- 创建服务成功! ---
ECHO.
ECHO.

::======================================================================
::生成操作批处理文件
::======================================================================
ECHO +++ 生成服务操作批处理 +++
ECHO 服务操作批处理文件可以帮助您快速操作服务。
SET bat_delete=DELETE_%svc_name%.BAT
SET bat_start=START_%svc_name%.BAT
SET bat_stop=STOP_%svc_name%.BAT
ECHO 生成删除服务批处理 "%bat_delete%" ...
::bat_delete
ECHO @ECHO OFF> %bat_delete%
ECHO NET STOP %svc_name%>> %bat_delete%
ECHO SC delete %svc_name%>> %bat_delete%
ECHO DEL %bat_start%>> %bat_delete%
ECHO DEL %bat_stop%>> %bat_delete%
ECHO DEL %bat_delete%>> %bat_delete%
ECHO PAUSE>> %bat_delete%
::bat_start
ECHO 生成运行服务批处理 "%bat_start%" ...
ECHO @ECHO OFF> %bat_start%
ECHO NET START %svc_name%>> %bat_start%
ECHO PAUSE>> %bat_start%
::bat_stop
ECHO 生成停止服务批处理 "%bat_stop%" ...
ECHO @ECHO OFF> %bat_stop%
ECHO NET STOP %svc_name%>> %bat_stop%
ECHO PAUSE>> %bat_stop%
ECHO.
ECHO --- 生成服务操作批处理成功! ---
ECHO.
ECHO.

::======================================================================
::Finish
::======================================================================
ECHO ### 所有操作成功! ###
GOTO END

::======================================================================
::错误段
::======================================================================
:ENV_ERROR
ECHO --- 设置环境变量失败! ---
GOTO END

:SC_ERROR
ECHO --- 创建服务失败! ---
GOTO END

:SC_INV_PORT
ECHO 无效的端口号，请重新输入。
GOTO INPUT_SVC_PORT

:END
PAUSE

其中SC create %svc_name% binPath= "\"E:\Subversion\bin\svnserve.exe\" --service -r \"%repos%\"" depend= Tcpip start= auto| find "1060:" >> NUL需要将binpath改为svnserve.exe所在路径，之后就可以运行服务了。

转载于:https://www.cnblogs.com/czxu/archive/2011/06/02/2070074.html