flash实现点击QQ图标显示QQ对话框

最新推荐文章于 2021-05-26 02:15:36 发布

转载最新推荐文章于 2021-05-26 02:15:36 发布 · 733 阅读

文章标签：

#flash

AS3 专栏收录该内容

7 篇文章

订阅专栏

本文介绍了一个Flash项目中遇到的问题：在独立运行SWF文件时无法从wpa.qq.com加载图片。原因是默认的安全沙箱保护机制不允许跨域加载资源。文章提供了具体的代码示例并解释了解决方案。

package
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.globalization.StringTools;
    import flash.net.URLRequest;
    import flash.net.navigateToURL;
    import flash.display.Bitmap;
    import flash.display.Loader;
    import flash.ui.Mouse;
    import flash.ui.MouseCursor;
 
 
    public class Main extends Sprite
    {            
        private var qq:String = "278919507";
        private var loader:Loader = new Loader();
        private var bit:Bitmap ;
        private var box:Sprite;
         
        public function Main():void
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }
 
        private function init(e:Event = null):void
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);       
            box = new Sprite();
            upData();
        }
         
        public function upData():void
        {     
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onCom); 
            var sUrl:String = "http://wpa.qq.com/pa?p=2:" + qq + ":41?" + Math.random();
            trace(sUrl);           
            loader.load(new URLRequest(sUrl));
        }          
 
        private function onCom(e:Event) :void
        {           
            bit = Bitmap(loader.content);  
            bit.height = 22;
            bit.width = 74;    
            box.addChild(bit);         
            addChild(box);         
            box.x = box.y = 10;
             
            //点击图标，以及切换鼠标
            box.addEventListener(MouseEvent.CLICK, onClick);
            box.addEventListener(MouseEvent.MOUSE_OVER, onMouseOver);
            box.addEventListener(MouseEvent.MOUSE_OUT, onMouseOut);
             
        }    
         
        private function onClick(e:MouseEvent):void
        {
            var sUrl:String = "http://wpa.qq.com/msgrd?v=3&uin=" + qq + "&site=qq&menu=yes";
            navigateToURL(new URLRequest(sUrl),"_blank");
            trace("test");
        }
         
        private function onMouseOver(e:MouseEvent):void
        {
            Mouse.cursor=MouseCursor.BUTTON;
        }
         
        private function onMouseOut(e:MouseEvent):void
        {
            Mouse.cursor=MouseCursor.ARROW;
        }
 
         
    }
 
}

在flash cs5环境下一切正常，但是单独运行swf时会失败：并不能加载图片。原因是wpa.qq.com下没有策略文件，默认的安全沙箱保护机制并不允许跨域加载图片。