DOS命令行删除N天以前的文件

最新推荐文章于 2022-10-06 12:40:16 发布

wangqi0079

最新推荐文章于 2022-10-06 12:40:16 发布

阅读量3.4k

点赞数

分类专栏： Dos命令服务器管理文章标签： dos date 扩展 dst cmd 算法

服务器管理同时被 2 个专栏收录

23 篇文章

订阅专栏

Dos命令

3 篇文章

订阅专栏

本文介绍了一组用于批量删除指定日期前文件的脚本，包括DelOldFile.cmd、DateDel2_for_2k3.bat、DateDel2_for_win2k.bat等，适用于Windows XP、2003、2000等系统，支持多种删除方式和路径指定，同时提供了日期转换函数，简化了文件管理任务。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

DOS命令行删除N天以前的文件

DelOldFile.cmd

:: DelOldFile.cmd - 删除指定日期前的所有文件
:: Climbing - 2005-8-26 - CMD@WinXP
@echo off
if "%1"=="" goto _usage
set dst=./.
if not "%2"=="" if exist %2/. (set dst=%2/.) else (goto _err1)
for /r %dst% %%f in (*.*) do if %%~tf LSS %1 del /f /q %%f && echo 删除 %%f
goto _quit

:_usage
echo DelOldFile.cmd   －　删除指定目录指定日期以前的所有文件
echo Version 1.0 Copyleft by Climbing
echo 语法： DelOldFile ^<日期^> [目标目录]
echo         ^<日期^> 　　必须指定的参数，日期格式为：%date%，该日期前的文件都会被删除（不含该日期）
echo         [目标目录]　可选参数，指定要删除文件的目录，默认为当前目录
goto _quit

:_err1
echo 错误：指定的%2目录不存在！

:_quit
set dst=
:End

DateDel2_for_2k3.bat

:: DateDel2.bat - 删除指定路径下指定日数以前修改的文件
:: Will Sort - 2005-9-2 - CMD@WinXP
:: 注意事项：参数%1指定日数，昨天为1，前天为2，依次类推
:: 参数%1指定文件路径，省略时将处理当前路径
:: 核心算法：Ritchie Lawrence, updated 2002-08-13. Version 1.1
::
@echo off & setlocal ENABLEEXTENSIONS
call :Date2Day %date:~0,10% sdays
set /a sdays-=%1
call :Day2Date %sdays% difdate
echo 将删除 %cd% 下 %difdate% 前的修改的以下文件：
for /r %2 %%f in (*.*) do if "%%~tf" LEQ "%difdate%" del /f /q %%f && echo 删除 %%f
goto :EOF

:Date2Day
setlocal ENABLEEXTENSIONS
for /f "tokens=1-3 delims=/-, " %%a in ('echo/%1') do (
set yy=%%a & set mm=%%b & set dd=%%c
)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %2=%j%&goto :EOF

:Day2Date
setlocal ENABLEEXTENSIONS
set /a i=%1,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%-%mm%-%dd%&goto :EOF

DateDel2_for_win2k.bat

:: DateDel2.bat - 删除指定路径下指定日数以前修改的文件
:: Will Sort - 2005-9-2 - CMD@WinXP
:: 注意事项：参数%1指定日数，昨天为1，前天为2，依次类推
:: 参数%1指定文件路径，省略时将处理当前路径
:: 核心算法：Ritchie Lawrence, updated 2002-08-13. Version 1.1
::
@echo off & setlocal ENABLEEXTENSIONS
call :Date2Day %date:~4,10% sdays
set /a sdays-=%1
call :Day2Date %sdays% difdate
echo 将删除 %cd% 下 %difdate% 前的修改的以下文件：
for /r %2 %%f in (*.*) do if "%%~tf" LEQ "%difdate:~2,14%" del /f /q %%f && echo 删除 %%f
goto :EOF

使用方法
::DelOldFile.cmd
::删除固定日期前的文件
::Win2003语法
DelOldFile.cmd 2008-01-05 d:/conf
::Win2000语法
DelOldFile.cmd 08-01-05 d:/conf
::将变量扩展到文件的日期/时间
for /r d:/conf %i in (test.txt) do set tt=%~ti
::Win2003结果
tt=2008-01-10 00:33
::Win2000结果
tt=08-01-10 00:33

::DateDel2.bat
::统一语法
::删除指定路径下指定日数以前修改的文件
::set /a将日期与相对天数进行相互换算，以求得差值日期
::删除昨天前修改的文件（包含昨天）
DateDel2.bat 1 d:/conf
::注意根据不同系统修改相应的date扩展变量
DelOldFile.cmd 2008-01-05 d:/conf
::Win2003 date扩展变量
echo %date:~0,10%
2009-01-06
::Win2000 date扩展变量
echo %date:~4,10%
2009-01-06
::Win2000 下需要扩展这个difdate变量以适应FOR命令的文件日期时间扩展变量
%difdate:~2,14%
09-01-06

http://blog.youkuaiyun.com/alanyang_2008/article/details/4022693

附录：

对上述文件进行了调整，在2008R2上测试通过,增加了删除批处理当前所在目录[支持空格]和防止误删除等功能

logfilesDel.bat

:: logfilesDel.bat - 删除批处理当前所在目录或指定路径下[注意:路径不支持空格]的LogFiles目录中指定日数以前修改的文件
:: Will Sort - 2005-9-2 - CMD@WinXP
:: 注意事项：参数%1指定日数，昨天为1，前天为2，依次类推，默认值为360天
::           参数%2指定文件路径，省略时将处理批处理当前所在目录下的LogFiles
:: 核心算法：Ritchie Lawrence, updated 2002-08-13. Version 1.1
::
@echo off & setlocal ENABLEEXTENSIONS 

if not "%2"=="" goto :Delfile
:: 进入到批处理当前所在目录下的LogFiles目录
cd /d %~dp0
cd .\LogFiles
:: 防止命令误执行，将非LogFiles目录下的文件删除
rename  logfilesDel.bat logfilesDel_error.bat 

:Delfile

call :Date2Day %date:~0,10% sdays
set /a sdays-=%1

:: 判断是否设置指定日期，如果没有设置那么设置缺省值为360
if "%1"=="" (set /a sdays-=360)

call :Day2Date %sdays% difdate
if "%2"=="" (echo 将删除 %cd% 下 %difdate% 前的修改的以下文件：)
if not "%2"=="" (echo 将删除 "%2" 下 %difdate% 前的修改的以下文件：)
for /r %2 %%f in (*.*) do if "%%~tf" LEQ "%difdate%" del /f /q "%%f" && echo 删除 %%f
goto :EOF

:Date2Day
setlocal ENABLEEXTENSIONS 
for /f "tokens=1-3 delims=/-, " %%a in ('echo/%1') do ( 
  set yy=%%a & set mm=%%b & set dd=%%c 
)
set /a dd=100%dd%%%100,mm=100%mm%%%100 
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2 
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %2=%j%&goto :EOF


:Day2Date
setlocal ENABLEEXTENSIONS 
set /a i=%1,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a 
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5 
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10 
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%) 
endlocal&set %2=%yy%-%mm%-%dd%&goto :EOF