TA之路——Shader学习09（遮罩纹理）

最新推荐文章于 2025-04-07 19:33:22 发布

翻译最新推荐文章于 2025-04-07 19:33:22 发布 · 267 阅读

文章标签：

本文介绍如何利用遮罩纹理来控制模型表面的光照和材质混合，通过具体实例展示了遮罩在调节反光强度和混合多种纹理时的应用，从而实现更细腻的视觉效果。

遮罩允许我们可以保护某些区域，使他们免于某些修改。例如：我们希望模型表面某些区域的反光强一些，某些区域弱一些，为了得到更加细腻的效果，我们就可以使用遮罩纹理控制光照。另一种常见的应用是用于制作丢性材质时需要混合多张图片，例如表现草地的纹理，表现石子4的纹理，表现裸露土地的纹理等等，遮罩纹理可以控制如何混合这些纹理。

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Test/7-4"{
	Properties{
		_Color("Color",Color)=(1,1,1,1)
		_MainTex("MainTex",2D)="white"{}
		_BumpMap("BumpMap",2D)="bump"{}
		_BumpScale("BumpScale",float)=1
		_SpecularMask("SpecularMask",2D)="white"{}
		_SpecularScale("SpecularScale",float)=1 //控制遮罩影响度
		_Specular("Specular",Color)=(1,1,1,1)
		_Gloss("Gloss",Range(8,256))=20
	}

	SubShader{
		Pass{
			Tags{"LightMode"="ForwardBase"}
			CGPROGRAM
			#include "Lighting.cginc"
			#pragma vertex vert
			#pragma fragment frag

			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			sampler2D _BumpMap;
			float _BumpScale;
			sampler2D _SpecularMask;
			float _SpecularScale;
			fixed4 _Specular;
			float _Gloss;

			struct a2v{
				float4 vertex:POSITION;
				float3 normal:NORMAL;
				float4 tangent:TANGENT;
				float4 texcoord:TEXCOORD0;
			};
			struct v2f{
				float4 pos:SV_POSITION;
				float2 uv:TEXCOORD0;
				float3 lightDir:TEXCOORD1;
				float3 viewDir:TEXCOORD2;
			};

			v2f vert(a2v v){
				v2f o;
				o.pos=UnityObjectToClipPos(v.vertex);
				o.uv.xy=v.texcoord.xy*_MainTex_ST.xy+_MainTex_ST.zw;
				//把光照和视角方向从模型空间变幻到切线空间中，以便在片元着色器中和法线进行计算
				TANGENT_SPACE_ROTATION;
				o.lightDir=mul(rotation,ObjSpaceLightDir(v.vertex)).xyz;
				o.viewDir=mul(rotation,ObjSpaceViewDir(v.vertex)).xyz;
				return o;
			}
			//使用遮罩纹理的地方是片元着色器，使用它控制模型表面的高光反射强度
			fixed4 frag(v2f i):SV_Target{
				fixed3 tangentLightDir=normalize(i.lightDir);
				fixed3 tangentViewDir=normalize(i.viewDir);

				fixed3 tangentNormal=UnpackNormal(tex2D(_BumpMap,i.uv));
				tangentNormal.xy*=_BumpScale;
				tangentNormal.z=sqrt(1.0-saturate(dot(tangentNormal.xy,tangentNormal.xy)));

				fixed3 albedo=tex2D(_MainTex,i.uv).rgb*_Color.rgb;
				fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;
				fixed3 diffuse=_LightColor0.rgb*albedo*max(0,dot(tangentNormal,tangentLightDir));
				fixed3 halfDir=normalize(tangentLightDir+tangentViewDir);
				fixed3 specularMask=tex2D(_SpecularMask,i.uv).r*_SpecularScale;
				fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(0,dot(tangentNormal,halfDir)),_Gloss)*specularMask;
				return fixed4(ambient+diffuse+specular,1);
			}
			ENDCG
		}
	}
}