慢慢欣赏arm64内核启动14 primary_entry之__create_page_tables代码第四部分map_memory

原创已于 2025-08-07 06:23:23 修改 · 1k 阅读

13 ·

CC 4.0 BY-SA版权

文章标签：

#linux

于 2024-08-17 16:42:31 首次发布

linux内核专栏收录该内容

270 篇文章

订阅专栏

分析代码

/*
 * Map memory for specified virtual address range. Each level of page table needed supports
 * multiple entries. If a level requires n entries the next page table level is assumed to be
 * formed from n pages.
 *
 *	tbl:	location of page table
 *	rtbl:	address to be used for first level page table entry (typically tbl + PAGE_SIZE)
 *	vstart:	virtual address of start of range
 *	vend:	virtual address of end of range - we map [vstart, vend - 1]
 *	flags:	flags to use to map last level entries
 *	phys:	physical address corresponding to vstart - physical memory is contiguous
 *	pgds:	the number of pgd entries
 *
 * Temporaries:	istart, iend, tmp, count, sv - these need to be different registers
 * Preserves:	vstart, flags
 * Corrupts:	tbl, rtbl, vend, istart, iend, tmp, count, sv
 */
	.macro map_memory, tbl, rtbl, vstart, vend, flags, phys, pgds, istart, iend, tmp, count, sv
	sub \vend, \vend, #1
	add \rtbl, \tbl, #PAGE_SIZE
	mov \sv, \rtbl
	mov \count, #0
	compute_indices \vstart, \vend, #PGDIR_SHIFT, \pgds, \istart, \iend, \count
	populate_entries \tbl, \rtbl, \istart, \iend, #PMD_TYPE_TABLE, #PAGE_SIZE, \tmp
	mov \tbl, \sv
	mov \sv, \rtbl

#if SWAPPER_PGTABLE_LEVELS > 3
	compute_indices \vstart, \vend, #PUD_SHIFT, #PTRS_PER_PUD, \istart, \iend, \count
	populate_entries \tbl, \rtbl, \istart, \iend, #PMD_TYPE_TABLE, #PAGE_SIZE, \tmp
	mov \tbl, \sv
	mov \sv, \rtbl
#endif

#if SWAPPER_PGTABLE_LEVELS > 2
	compute_indices \vstart, \vend, #SWAPPER_TABLE_SHIFT, #PTRS_PER_PMD, \istart, \iend, \count
	populate_entries \tbl, \rtbl, \istart, \iend, #PMD_TYPE_TABLE, #PAGE_SIZE, \tmp
	mov \tbl, \sv
#endif

	compute_indices \vstart, \vend, #SWAPPER_BLOCK_SHIFT, #PTRS_PER_PTE, \istart, \iend, \count
	bic \count, \phys, #SWAPPER_BLOCK_SIZE - 1
	populate_entries \tbl, \count, \istart, \iend, \flags, #SWAPPER_BLOCK_SIZE, \tmp
	.endm

注释

第1行到第17行是注释，详细介绍每个参数的含义

第一个参数

第一个参数 tbl 即 table localtion 的缩写，根据链接地址的定义，我们认为所有的恒等映射的页表地址是连续的。即全局目录（PGD）后面是页上级目录（PUD），后面接着是页中间目录（PMD），最后是页表项（PTE）
所以不必费心传递不同级别页表的地址
入参对应的形参是 x0，在前面的代码中通过如下语句赋值

adrp	x0, idmap_pg_dir

第二个参数

第二个参数 rtbl 是下一级页表的起始地址，根据刚才的描述，下一级页表的起始地址其实是不用传达的，注释也做了说明，由于全局目录只占有1个页面，所以在函数的内部是通过 tbl + PAGE_SIZE 传递的
所以第二个参数本质是一个出参，在这里只是占用一个寄存器 x1而已

第三个参数

第三个参数是 vstart 表示虚拟地址的起始地址，从上一章节调用者的角度看，当映射是恒等映射时，虚拟地址等于物理地址
入参对应 x3，在前面的代码中通过如下语句赋值

adrp	x3, __idmap_text_start		// __pa(__idmap_text_start)

第四个参数

第四个参数是 vend 表示虚拟地址的结束地址，从上一章节调用者的角度看，当映射是恒等映射时，虚拟地址等于物理地址
入参对应 x6，在前面的代码中通过如下语句赋值

adr_l	x6, __idmap_text_end		// __pa(__idmap_text_end)

第五个参数

第五个参数是 flags，表示页表的属性，入参对应 x7，在前面的代码中通过如下语句赋值

mov	x7, SWAPPER_MM_MMUFLAGS

第六个参数

第六个参数 phys，表示物理地址，从上一章节调用者的角度看，当映射是恒等映射时，虚拟地址等于物理地址
入参也对应 x3

第七个参数

第七个参数 pgds 表示该页表的页表项数目，也就是全局目录的页表项数目，上一章节俄罗斯套娃里面讲过，入参对应 x4，其值为 512

第八个参数

第八个参数 istart，注释里没有说明，根据意思以及上下文代码的实现，应该是 index of start 的缩写，就是下一级页表的起始地址在该级页表的索引值，其范围为 [0, 512)，
该参数为出参，对应 x10，需要在函数内部通过计算得到

第九个参数

第九个参数 iend，注释里没有说明，根据意思以及上下文代码的实现，应该是 index of end 的缩写，就是下一级页表的终止地址在该级页表的索引值，由于可能存在多个页表的可能性，
其范围为 [0, 512) + 该级页表最多包含的页表项的数目（例如四级映射每一级的最多的页表项为512） * 下一级页表的个数
该参数为出参，对应 x11，需要在函数内部通过计算得到