ABAP OO ALV模板（Docking 容器）

已于 2025-03-25 17:27:44 修改
阅读量1.3k 收藏 8
点赞数 4
分类专栏： 模板 文章标签： SAP
于 2023-06-01 16:30:55 首次发布
窝窝头~一块钱四个~嘿嘿~
本文链接：https://blog.youkuaiyun.com/qq_44826887/article/details/130964634
版权

前言

来了新入职的开发同事，因为之前双方都来自不同的乙方公司，所以开发习惯上有挺大的差异
我之前的公司是使用的LVC函数进行的报表开发，另一位同事是公司是使用的OO ALV进行开发，借此机会拓展一下知识面，再补补报表开发的基础
感觉Docking容器的应用应该比Custome Control来的多一些，毕竟不需要在屏幕上固定划出一块区域作为ALV展示的自定义容器，用户还能通过拖拽自定义容器的大小
开发步骤如下：

新建屏幕

开发Docking 容器的OO ALV只需要新建一个屏幕即可
在这里插入图片描述
OO ALV中常用的是ALV的tool bar，所以会把应用程序工具栏隐藏掉，勾选【无应用程序工具栏】即可
在这里插入图片描述
在屏幕流逻辑中新建module
在这里插入图片描述

新建GUI 状态 & GUI 标题

新建的GUI状态是空白的，标准工具栏的功能大多数都没有，至少把退出的几个功能先实现出来，否则用户进入ALV之后就无法退出
在这里插入图片描述
新建GUI标题，代码中可以用占位符&填充自定义文本
在这里插入图片描述

代码实现

********************************************************************
* 事务代码：                                                       *
* 程序名称：                                                       *
* 程序目的：                                                       *
* 设 计 人：                                                       *
* 开 发 人：Seele                                                  *
* 设计时间：2025-03-17                                             *
* 程序类型: ABAP/4 程序 ，报表程序                                 *
* 应用类型:                                                        *
* 描    述:                                                        *
*(修改日志)--------------------------------------------------------*
*                                                                  *
* 日志号   修改人  修改时间       修改说明              传输号码   *
*  ----    ----    ------         -----------
*   001    Seele   2025-02-24     创建报表程序                     *
********************************************************************
REPORT zdemo_seele13.

TABLES: mara, makt.

*----------------------------------------------------------------------*
* 结构声明类型/Structure type declaration
*----------------------------------------------------------------------*
*&---主表数据/master table data
TYPES:BEGIN OF ty_output,

        matnr TYPE makt-matnr         , "
        maktx TYPE makt-maktx         , "

        box   TYPE c                  , "
        style TYPE lvc_t_styl         , "
        color TYPE char4              , "

      END OF ty_output.

*&---------------------------------------------------------------------*
*&  CLASS
*&---------------------------------------------------------------------*
CLASS cl_events DEFINITION.
  PUBLIC SECTION.
    METHODS:
      handle_toolbar      FOR EVENT toolbar               OF cl_gui_alv_grid IMPORTING e_object e_interactive,
      handle_command      FOR EVENT user_command          OF cl_gui_alv_grid IMPORTING e_ucomm,
      handle_data_changed FOR EVENT data_changed_finished OF cl_gui_alv_grid IMPORTING et_good_cells e_modified.
ENDCLASS.

CLASS cl_events IMPLEMENTATION.
  METHOD handle_toolbar.
    PERFORM frm_handle_toolbar CHANGING e_object.
  ENDMETHOD.

  METHOD handle_command.
    PERFORM frm_handle_command USING e_ucomm.
  ENDMETHOD.

  METHOD handle_data_changed.
    PERFORM frm_handle_data_changed USING et_good_cells e_modified.
  ENDMETHOD.

ENDCLASS.

*----------------------------------------------------------------------*
* 全局变量定义/Global variable definition
*----------------------------------------------------------------------*
" OO ALV对象容器
DATA: gr_ctn_alv  TYPE REF TO cl_gui_docking_container,
      gr_grid     TYPE REF TO cl_gui_alv_grid,
      gr_events   TYPE REF TO cl_events,
      gt_output   TYPE TABLE OF ty_output,
      gt_delete   TYPE TABLE OF ty_output,
      gt_fieldcat TYPE TABLE OF lvc_s_fcat,
      gv_variant  TYPE disvariant,
      gs_fieldcat TYPE lvc_s_fcat,
      gs_output   TYPE ty_output.

FIELD-SYMBOLS: <fs_output> TYPE ty_output.

*&---------------------------------------------------------------------*
*&  Macro 宏定义
*&---------------------------------------------------------------------*
DEFINE mcr_set_catalog.
  gs_fieldcat-fieldname  = &1. " 字段技术名称
  gs_fieldcat-coltext    = &2. " 显示名称
  gs_fieldcat-scrtext_s  = &2. " 显示名称
  gs_fieldcat-scrtext_m  = &2. " 显示名称
  gs_fieldcat-scrtext_l  = &2. " 显示名称
  gs_fieldcat-ref_table  = &3. " 参照表
  gs_fieldcat-ref_field  = &4. " 参照表字段
  gs_fieldcat-qfieldname = &5. " 参考计量单位的字段名称
  gs_fieldcat-key        = &6. " key 值
  gs_fieldcat-edit       = &7. " 可编辑

  APPEND gs_fieldcat TO gt_fieldcat.
  CLEAR  gs_fieldcat.
END-OF-DEFINITION.

*&---------------------------------------------------------------------*
*& Selection Screen/选择屏幕
*&---------------------------------------------------------------------*
*&---选择屏幕块
SELECTION-SCREEN BEGIN OF BLOCK blk01 WITH FRAME TITLE TEXT-101.

*&---范围
SELECT-OPTIONS: s_matnr FOR mara-matnr .

SELECTION-SCREEN END OF BLOCK blk01.

*&---------------------------------------------------------------------*
*& Start-of-selection/开始选择屏幕                                     *
*&---------------------------------------------------------------------*
START-OF-SELECTION.
  PERFORM frm_get_data.

*&---------------------------------------------------------------------*
*& End-of-selection/结束选择屏幕（程序结束处理，输出等）               *
*&---------------------------------------------------------------------*
END-OF-SELECTION.
  PERFORM frm_call_screen.

*&---------------------------------------------------------------------*
*& Form FRM_GET_DATA
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_get_data .

  CLEAR: gt_output.
  SELECT
    makt~matnr,
    makt~maktx
  FROM makt
  WHERE
    makt~matnr IN @s_matnr AND
    spras = @sy-langu
  INTO TABLE @DATA(lt_data).

  LOOP AT lt_data INTO DATA(ls_data).
    gs_output = CORRESPONDING #( ls_data ).

    APPEND gs_output TO gt_output.
  ENDLOOP.

ENDFORM.

*&---------------------------------------------------------------------*
*& Form frm_call_screen
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*&      --> GS_HEAD
*&      --> GS_ITEM
*&---------------------------------------------------------------------*
FORM frm_call_screen .

  CALL SCREEN '9000'.

ENDFORM.

*&---------------------------------------------------------------------*
*& Module STATUS_9000 OUTPUT
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
MODULE status_9000 OUTPUT.

  PERFORM frm_set_status. " 菜单栏
  PERFORM frm_set_fieldcat.
  PERFORM frm_set_alv.    " ALV

ENDMODULE.

*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_9001  INPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE user_command_9000 INPUT.

*&-- 刷新ALV数据
  IF gr_grid IS NOT INITIAL.
    gr_grid->check_changed_data( ).
  ENDIF.
  DATA:lv_result TYPE c.

*&-- 菜单栏事件
  CASE sy-ucomm.
    WHEN 'ZEXIT'.
      LEAVE PROGRAM.
    WHEN 'ZBACK'.
      LEAVE TO SCREEN '0'.
    WHEN OTHERS.
  ENDCASE.

ENDMODULE.

*&---------------------------------------------------------------------*
*& Form FRM_SET_FIELDCAT
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_set_fieldcat .
  mcr_set_catalog: 'MATNR' TEXT-a01 'MARA' 'MATNR' '' '' '' , " 行号
                   'MAKTX' TEXT-a02 'MAKT' 'MAKTX' '' '' 'X'. " 工厂

ENDFORM.

*&---------------------------------------------------------------------*
*& Form frm_set_status
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_set_status .
  DATA: lt_extab TYPE slis_t_extab.

  SET TITLEBAR 'TITLE_9000' WITH TEXT-t01.
  SET PF-STATUS 'STATUS_9000' EXCLUDING lt_extab.

ENDFORM.

*&---------------------------------------------------------------------*
*& Form frm_set_alv
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_set_alv .

  DATA: ls_style TYPE lvc_s_styl.

  IF gr_ctn_alv IS INITIAL.

    " 初始化对象
    gr_ctn_alv = NEW #( side = cl_gui_docking_container=>dock_at_top extension = 9999 ).
    gr_grid    = NEW #( i_parent = gr_ctn_alv ).
    gr_events  = NEW #(  ).

    " 绑定ALV菜单栏事件
    SET HANDLER gr_events->handle_toolbar      FOR gr_grid.
    SET HANDLER gr_events->handle_command      FOR gr_grid.
*    SET HANDLER gr_events->handle_data_changed FOR gr_grid.

    " 绑定回车事件
*    gr_grid->register_edit_event( i_event_id = cl_gui_alv_grid=>mc_evt_enter ).
*    gr_grid->register_edit_event( i_event_id = cl_gui_alv_grid=>mc_evt_modified ).
*    gr_grid->set_ready_for_input( i_ready_for_input = 1 ).

    " 调用ALV
    gv_variant = sy-repid.
    gr_grid->set_table_for_first_display(
      EXPORTING
        i_save          = 'A'
        i_default       = 'X'
        is_variant      = gv_variant
        is_layout       = VALUE lvc_s_layo( zebra = 'X'
                                            cwidth_opt = 'X'
                                            sel_mode   = 'A'
                                            box_fname  = 'BOX'
                                            stylefname = 'STYLE'
                                            info_fname = 'COLOR' )
      CHANGING
        it_outtab       = gt_output[]
        it_fieldcatalog = gt_fieldcat[] ).

  ENDIF.

ENDFORM.

*&---------------------------------------------------------------------*
*& Form frm_handle_toolbar
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_handle_toolbar CHANGING pr_object TYPE REF TO cl_alv_event_toolbar_set.
  DATA: lr_func TYPE RANGE OF stb_button-function.

  " OO ALV自带的标准按钮，不需要
  lr_func[] = VALUE #( ( sign = 'I' option = 'EQ' low = '&DETAIL' )
                       ( sign = 'I' option = 'EQ' low = '&&SEP2' )
                       ( sign = 'I' option = 'EQ' low = '&CHECK' )
                       ( sign = 'I' option = 'EQ' low = '&REFRESH' )
                       ( sign = 'I' option = 'EQ' low = '&LOCAL&CUT' )
                       ( sign = 'I' option = 'EQ' low = '&LOCAL&COPY' )
                       ( sign = 'I' option = 'EQ' low = '&LOCAL&PASTE' )
                       ( sign = 'I' option = 'EQ' low = '&LOCAL&UNDO' )
                       ( sign = 'I' option = 'EQ' low = '&LOCAL&APPEND' )
                       ( sign = 'I' option = 'EQ' low = '&LOCAL&INSERT_ROW' )
                       ( sign = 'I' option = 'EQ' low = '&LOCAL&DELETE_ROW' )
                       ( sign = 'I' option = 'EQ' low = '&LOCAL&COPY_ROW' )
                       ( sign = 'I' option = 'EQ' low = '&&SEP19' ) ).

  " 新增插入删除按钮
  pr_object->mt_toolbar = VALUE #( BASE pr_object->mt_toolbar
                                   ( function = 'INSERT'  icon = icon_insert_row )
                                   ( function = 'CHANGE'  icon = icon_change      text = TEXT-t05 )
                                   ( function = 'DELETE'  icon = icon_delete_row  text = TEXT-t06 ) ).

  DELETE pr_object->mt_toolbar WHERE function IN lr_func[].

ENDFORM.

*&---------------------------------------------------------------------*
*& Form frm_handle_command
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_handle_command USING pv_ucomm TYPE sy-ucomm.

  DATA: lt_alv   TYPE TABLE OF ty_output,
        ls_alv   TYPE ty_output,
        lv_index TYPE i.

  gr_grid->get_selected_rows(
    IMPORTING
      et_row_no = DATA(lt_row_no) ).

  gr_grid->check_changed_data( ).

  CASE pv_ucomm.

    WHEN 'DELETE'.

      LOOP AT lt_row_no INTO DATA(ls_row_no).
        READ TABLE gt_output ASSIGNING <fs_output> INDEX ls_row_no-row_id.
        IF sy-subrc = 0.

        ENDIF.
      ENDLOOP.

    WHEN OTHERS.
      RETURN.
  ENDCASE.

  gr_grid->refresh_table_display( is_stable = VALUE lvc_s_stbl( row = 'X' col = 'X' ) ).

  gr_grid->set_selected_rows(
    EXPORTING
      it_row_no = lt_row_no ).

ENDFORM.

*&---------------------------------------------------------------------*
*& Form frm_handle_data_changed
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*&      --> ER_DATA_CHANGED
*&---------------------------------------------------------------------*
FORM frm_handle_data_changed  USING pt_data   TYPE lvc_t_modi
                                    pv_modify TYPE c.

  IF pv_modify IS INITIAL.
    RETURN.
  ENDIF.

*  DATA: lt_modify TYPE lvc_t_modi.
*  lt_modify = pt_data.
*  DELETE lt_modify WHERE fieldname <> 'NETPR' AND fieldname <> 'MENGE'.
*  SORT lt_modify BY row_id.
*  DELETE ADJACENT DUPLICATES FROM lt_modify COMPARING row_id.
*  LOOP AT lt_modify INTO DATA(ls_modify).
*    READ TABLE gt_output ASSIGNING FIELD-SYMBOL(<fs_output>) INDEX ls_modify-row_id.
*    IF sy-subrc = 0.
*      <fs_output>-amout = <fs_output>-menge * <fs_output>-netpr.
*    ENDIF.
*  ENDLOOP.

  gr_grid->refresh_table_display( is_stable = VALUE lvc_s_stbl( row = 'X' col = 'X' ) ).

ENDFORM.

效果图

在这里插入图片描述
参考文档：大佬夜猫君的博客

SAP ABAP ALV 的一些总结：Docking container 和 Dialogbox container
2007 年 ~ 2025 年，深耕 SAP 技术 18 年
09-24 880
自定义容器可以使用 CL_GUI_CUSTOM_CONTAINER 类创建，但它需要一个可以放置它的父容器，或者需要在自定义屏幕中创建自定义控制区域。 将自定义容器与其他容器混合，这种方式在实际 ABAP 开发中也很常见。 许多 ABAP 开发人员在包含自定义容器区域的屏幕的 PBO 事件期间创建自定义容器，但这不是必须的。也可以在调用屏幕之前创建它。
ABAP——OOALV应用测试（以SD为例）
qq_48863931的博客
07-14 339
设置字段命名fieldcat设置布局字段layout设置用于区分抬头，行项目，主数据的布局字段variant设置隐藏alv菜单控件设置PAI事件字段设置grid容器用到的字段写PBO事件写PAI事件（包括子例程：屏幕分割，创建alv grid容器，显示数据，alv刷新）本篇主要是实现了屏幕拆分，还有其他功能有待挖掘。执行时，程序没有语法错误却被dump掉了，首先使用了事务码ST22，查看被dump掉的原因，最后在返回程序，打断点进行调试，找到程序的错因。
ABAP OOALV模板（Custom 容器）
谁的博客来着？
05-18 1386
OO ALV实现示例
ALV OO 模板
01-04
ALV OO 模板
SAP-ABAP-OOALV一般使用模板
Qunending的博客
03-30 2186
首先创建程序，复制源码，然后添加屏幕9000，给9000屏幕添加控件取名ALV，给9000屏幕添加GUI状态和GUI标题，将9000的POB,PAI注释放开 *&---------------------------------------------------------------------* *& Report ZSD_R0028 *&--------------------------------------------------------------------
SAP ABAP 之OOALV (保姆级教程)
最新发布
Li958172829的博客
06-25 5769
SAP ABAP 之OOALV
ABAP OOALV报表开发
06-30
ABAP OOALV报表开发，定义变量，选择屏幕定义，创建类，调用函数
SAP ABAP OO ALV 模板 示例
qq_40463305的博客
05-30 577
一屏展示多个ALV示例代码。示例调用简单展示ALV。程序 YTEST03。
ALV OO: 最简单的ALV OO实例-Docking容器
rztyzxzy的博客
07-29 9056
最简单的ALV OO实例，Docking容器实现，ALV宽度可以由用户自动调整……
OO ALV(一屏幕显示多个ALV， 双击事件)例子
埃克斯歪ForABAP的专栏
08-07 3707
*&---------------------------------------------------------------------**& Report ZVR_V051*&*&---------------------------------------------------------------------**& 机电根据生产订单查询下级组件库存报表*& Create by 谭小
sap abap oo实现ALV
09-05
利用OO实现ALV ， OO是SAP比较新的东西了，应用可能会越来越广
ABAP OOALV
05-29
SAP ABAP OOALV自学记录，适合刚接触ABAP的同学进行自学。
ABAP OO去掉ALV中的标准工具栏
06-29
在ABAP开发中，应用OO的方法，有时候会需要去掉ALV中的标准工具栏，里面有具体步骤和实例。
ABAP - SALV教程14 状态栏添加按钮
HeathlX的博客
03-04 1710
【代码】ABAP - SALV教程15 状态栏添加按钮。
【ABAP】OO ALV 概述
热门推荐
少年休闲海
07-19 1万+
•OO ALV，是指通过面向对象（Object-Oriented）的方式实现的ALV输出 •基本使用原理： –通过界面调用，在界面的Customer Control控件中，输出ALV •CLASS ALV优势 –使用面向对象的编程方式 –使用容器，可以在一个界面中指定位置进行ALV的输出 •执行步骤 –ALV实现相关变量定义 –创建本地类的声明及实现（EVENT HANDLE...
ABAP OO ALV 示例模板
qq_40463305的博客
07-03 295
【代码】ABAP OO ALV 示例模板。
ABAP的ALV的模板
qq_42954713的博客
09-03 663
代码： *&---------------------------------------------------------------------* *&REPORTZTRR0180 *&---------------------------------------------------------------------* *&--------------------------------------------------------------------..
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值