汇编语言 实验十五 安装新的int9中断例程

实验十五 功能

安装一个新的int 9 中断例程，功能：在DOS下，按下“A”键后，除非不再松开，如果松开，就显示满屏幕的“A”，其他的键照常处理。

代码

assume cs:code

stack segment
	db 128 dup (0)
stack ends

code segment
	start:
		mov ax,stack
		mov ss,ax
		mov sp,128
		
		push cs
		pop ds
		
		mov ax,0
		mov es,ax
		
		mov si,offset int9
		mov di,204h
		mov cx,offset int9end-offset int9
		cld
		rep movsb
		
		push es:[9*4]
		pop es:[200h]
		push es:[9*4+2]
		pop es:[202h]
		
		cli
		mov word ptr es:[9*4],204h
		mov word ptr es:[9*4+2],0
		sti
		
		
		mov ax,4c00h
		int 21h
		
	int9:
		push ax
		push bx
		push cx
		push es
		
		in al,60h
		
		pushf
		call dword ptr cs:[200h]
		
		cmp al,9eh
		jne int9ret
		mov cx,4000
		mov ax,0b800h
		mov es,ax
		mov bx,0
		mov dx,3
	s:	mov byte ptr es:[bx],'A'
		mov es:[bx+1],dl
		add bx,2
		loop s
		
	int9ret:
		pop es
		pop cx
		pop bx
		pop ax
		iret
	int9end:
		nop
code ends
end start

截图

说明

首先要安装新的中断处理程序到0：0204h，然后改变入口地址。新的int 9中断例程中仍要调用原来的int 9中断，pushf call dword ptr cs:[200h]，使用这两条指令直接调用int 9中断。
按下一个键时产生的扫描码称为通码，松开一个键产生的扫描码称为断码。
断码=通码+80h。

指令系统总结

我们对8086CPU的指令系统进行一下总结。
1.数据传送指令
比如，mov、push、pop、pushf、popf、xchg等都是数据传送指令，这些指令实现寄存器和内存、寄存器和寄存器之间的单个数据传送。
2.算术运算指令
比如，add、sub、adc、sbb、inc、dec、cmp、idiv、aaa等都是算术运算指令，这些指令实现寄存器和内存中的数据的算术运算。他们的执行结果影响标志寄存器的sf、zf、of、pf、cf、af位。
3.逻辑指令
比如，and、or、not、xor、test、shl、shr、sal、sar、rol、ror、rcl、rcr等都是逻辑指令。除了not指令外，他们的执行结果都影响标志寄存器的相关标志位。
4.转移指令
可以修改IP，或同时修改CS和IP的指令系统统称为转移指令。转移指令分为以下几类。
（1）无条件转移指令，比如，jmp；
（2）条件转移指令，比如，jcxz、je、jb、ja、jna、jnb等；
（3）循环指令，比如，loop；
（4）过程，比如，call、ret、retf；
（5）中断，比如，int、iret。
5.处理机控制指令
这些指令对标志寄存器或其他处理机状态进行设置，比如，cld、std、cli、sti、nop、clc、cmc、stc、hlt、wait、esc、lock等都是处理机控制指令。
6.串处理指令
这些指令对内存中的批量数据进行处理，比如，movsb、movsw、cmps、scas、lods、stos等。若要使用这些指令方便地进行批量数据的处理，则需要和rep、repe、repne等前缀指令配合使用。