Arduino NodeMCU IIC复用案列之双OLED

一、准备

1、知识储备

IIC是一种总线协议，四根线，一根VCC，一根GND，一根时钟线SCL，一根数据线，支持一主多从，这是比串口通信优越的地方，在一主多从情景下，主设备需要指定从设备的地址发送数据包，这就像在局域网下路由器通过ip向局域网内设备发送数据一样。但是现在存在如下问题：NodeMCU的IIC接口只有一个，而高级模块大多是IIC通信。因此在大多应用场景下需要IIC接口复用，本文就是探索这个问题。网上对于解决IIC一主多从的方案很多，有根据IIC地址区分设备，有控制设备的电源，还有使用多个软IIC接口。本文思路是使用一个软IIC接口，根据IIC地址区分。

2、硬件准备

两个四阵脚的0.96寸OLED和一个NodeMCU，这里OLED驱动芯片为SSD1306，值得注意的这类模块的固化IIC地址是0x3C或0x3D，我们可以通过移动电阻实现地址转换，但是模块上标注的是0x7A和0x7B地址，实际指定的时候并不是这个地址，下图是我处理后的两个显示屏，注意电阻的改变：

二、编程

1、扫描IIC地址

我采取扫描IIC的方式去查看它们的可以使用地址，效果如下图，得到3C和3D地址。

代码如下，注意SCL和SDA的引脚：

#include <Wire.h>

void setup() {
  Wire.begin(/*SDA*/D2,/*SCL*/D1);
  Serial.begin(115200);
}

void loop() {
  byte error, address;
  int nDevices;
  Serial.println("Scanning I2C Devices....");
  nDevices = 0;
  for (address = 1; address < 127; address++ ) {
    // 发送1次从机地址
    Wire.beginTransmission(address);
    // 等待从机响应
    error = Wire.endTransmission();
    if (error == 0) {
      Serial.print("I2C device found at address 0x");
      if (address < 16) {
        Serial.print("0");
      }
      Serial.print(address, HEX);
      Serial.println(" !");
      nDevices++;
    }
    else if (error == 4) {
      Serial.print("Unknow error at address 0x");
      if (address < 16) {
        Serial.print("0");
      }
      Serial.println(address, HEX);
    }
  }
  if (nDevices == 0) {
    Serial.println("No I2C devices found\n");
  }
  else {
    Serial.println("done\n");
  }
  delay(5000);
}

2、控制OLED

功能是实现1秒切换显示图形，效果如下图：


代码如下：

#include <Wire.h>
#include <Adafruit_SSD1306.h>
#define OLED_RESET  -1 // Reset pin # (or -1 if sharing Arduino reset pin)
Adafruit_SSD1306 display1(/*SCREEN_WIDTH*/128, /*SCREEN_HEIGHT*/64, &Wire, OLED_RESET);
Adafruit_SSD1306 display2(/*SCREEN_WIDTH*/128, /*SCREEN_HEIGHT*/64, &Wire, OLED_RESET);

//显示一个心形
static const uint8_t PROGMEM Heart_16x16[] = {
  0x00,0x00,0x18,0x18,0x3C,0x3C,0x7E,0x7E,0xFF,0xFF,0xFF,0xFF,0xFF,0xFF,0xFF,0xFF,
  0xFF,0xFF,0x7F,0xFE,0x3F,0xFC,0x1F,0xF8,0x0F,0xF0,0x07,0xE0,0x03,0xC0,0x00,0x00//未命名文件0
};

void setup() {
  Serial.begin(115200);
  Wire.begin(/*SDA*/D2,/*SCL*/D1);
  // SSD1306_SWITCHCAPVCC = generate display voltage from 3.3V internally
  if(!display1.begin(SSD1306_SWITCHCAPVCC, 0x3c,false,true)) { // Address 0x3C for 128x64
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }
  if(!display2.begin(SSD1306_SWITCHCAPVCC, 0x3d,false,true)) { // Address 0x3D for 128x64
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }
  delay(2000); // Pause for 2 seconds
  display1.clearDisplay();
  display2.clearDisplay();
}

void loop(){
  display1.drawBitmap(16,16,Heart_16x16,16,16,WHITE);
  display1.display();
  delay(1000); // Pause for 2 seconds
  display1.clearDisplay();
  display1.display();
  display2.drawBitmap(16,16,Heart_16x16,16,16,WHITE);
  display2.display();
  delay(1000); // Pause for 2 seconds
  display2.clearDisplay();
  display2.display();
}

三、总结

首先感谢 单片机菜鸟哥的文章—— 深入学习 OLED Adafruit_SSD1306库（8266+arduino）和 民不举官不究的文章——ESP8266 Arduino-获取IIC外设地址。
IIC通信的使用依靠的是Wire.h这个库，本文并没有过多的涉及其方法的使用，直接使用了SSD1306封装的对象，而且同构的设备过于简单并没有体现出地址切换的过程，下次探寻异构的设备如何进行总线通信。
如有问题欢迎大家指出。