Windows批处理自动检测、安装Python

最新推荐文章于 2024-11-19 18:04:14 发布

mighty13

最新推荐文章于 2024-11-19 18:04:14 发布

阅读量1.8w

点赞数 3

CC 4.0 BY-SA版权

分类专栏： Python基础 windows运维文章标签： python 批处理注册表安装启动器

本文链接：https://blog.youkuaiyun.com/mighty13/article/details/110686530

Python基础同时被 2 个专栏收录

55 篇文章

订阅专栏

windows运维

25 篇文章

订阅专栏

本文介绍了一种通过批处理脚本实现Python静默安装的方法，并详细阐述了如何利用注册表检测Python安装情况以及如何验证Python及其包管理器pip是否正常工作。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

原理及问题：

使用注册表检测Python是否安装，检测注册表项hklm\software\Python\pythoncore是否存在指定版本信息。经试验发现该注册表项对于较早的安装包无效。
使用py -3.7 --version检测Python解释器是否正常运行，较早的安装包或者未安装python启动器将检测失败。
采用静默模式安装Python，针对所有用户安装，将Python信息加入环境变量path中。
安装文件必须与批处理文件处于同一目录。

@ECHO OFF

rem  检测注册表中是否有Python3.7信息。
echo ----------------------------------
echo 检测注册表……
reg query "hklm\software\Python\pythoncore\3.7" >nul 2>nul
if %errorlevel%==0 (echo 注册表检测到指定版本Python & GOTO check_python) else (echo 注册表未检测到指定版本Python!开始安装Python3.7…… & goto install_python)

:uninstall_python
echo 正在卸载Python！请稍候……
python-3.7.6-amd64.exe /quiet /uninstall
echo 卸载Python完成！

:check_python
rem 检测运行指定版本Python是否成功。
echo ----------------------------------
echo 检测指定版本Python运行状况……
py -3.7 --version  >nul 2>nul
if %errorlevel%==0 (echo Python运行正常！ & goto check_pip) else (echo Python运行异常！)
pause

:check_pip
rem 检测运行pip是否成功。
echo ----------------------------------
echo 检测pip运行状况……
@for /f "tokens=1" %%i in ('pip --version ^| findstr /C:"pip"')  do ^
set PIPVER=%%i
@if "%PIPVER%" == "pip" (@echo Pip运行正常！) else echo (Pip运行异常！)
pause
goto:eof

:install_python
rem 采用静默模式安装Python。
echo ----------------------------------
echo 开始安装Python，请稍候……
python-3.7.6-amd64.exe /quiet InstallAllUsers=1 PrependPath=1
if %errorlevel%==0 (echo Python3.7安装成功！& goto check_python) else echo (Python安装失败！)