物流运输

题目描述

Description
物流公司要把一批货物从码头A运到码头B。由于货物量比较大，需要n天才能运完。货物运输过程中一般要转停好几个码头。物流公司通常会设计一条固定的运输路线，以便对整个运输过程实施严格的管理和跟踪。由于各种因素的存在，有的时候某个码头会无法装卸货物。这时候就必须修改运输路线，让货物能够按时到达目的地。但是修改路线是—件十分麻烦的事情，会带来额外的成本。因此物流公司希望能够订一个n天的运输计划，使得总成本尽可能地小。
输入输出格式 Input/output
输入格式：
第一行是四个整数n(l≤n≤100)、m(l≤m≤20)、K和e。n表示货物运输所需天数，m表示码头总数，K表示每次修改运输路线所需成本。接下来e行每行是一条航线描述，包括了三个整数，依次表示航线连接的两个码头编号以及航线长度(>0)。其中码头A编号为1，码头B编号为m。单位长度的运输费用为1。航线是双向的。再接下来一行是一个整数d，后面的d行每行是三个整数P(1< P< m)，a，b(1≤a≤b≤n)。表示编号为P的码头从第a天到第b天无法装卸货物（含头尾）。同一个码头有可能在多个时间段内不可用。但任何时间都存在至少一条从码头A到码头B的运输路线。
输出格式：
包括了一个整数表示最小的总成本。总成本=n天运输路线长度之和+K*改变运输路线的次数。
输入输出样例 Sample input/output
样例测试点#1 输入样例：
5 5 10 8
1 2 1
1 3 3
1 4 2
2 3 2
2 4 4
3 4 1
3 5 2
4 5 2
4
2 2 3
3 1 1
3 3 3
4 4 5
输出样例：
32
说明 description
【样例输入说明】

上图依次表示第1至第5天的情况，阴影表示不可用的码头。
【样例输出说明】
前三天走1-4-5，后两天走1-3-5，这样总成本为(2+2)*3+(3+2)*2+10=32。

分析

单源最短路+dp。
dp方程：f[i]=min{ans(1,i) * i,f[j]+ans(j+1,i) * (i-j)+k} (1=< j<=i-1) f[i]表示前i天的最小运费，
ans(x,y)表示从第x天到第y天从起点到终点的最短路，可以用bellman ford,dijkstra,SPFA……方程很好理解。
第一种情况：1到i天都走一条路。
第二种情况：j+1到i天走一条路（这条路记为路径1）。这个时候，不管前j天走的路径2和路径1是否相同，都把它看成路径改变了，所以加上k。这样做是对的，因为如果相同还加了k就一定没有第一种情况的解或者是j更靠前的那个解优。具体来说这个更靠前的j，就是真正的改变路径的分界限。所以刚开始可能会考虑如何记录状态来判断是否加上k,那样就做不出来了。这道题的价值其实就在k的处理上。

上述DP方程可以变为：
因为ans(1,i) * i相当于，把第一天和第0天比较改变了一次路径，即
f[i]=min{f[j-1]+ans(j,i) * (i-j+1)+k} - k (1=< j<=i)
因为一开始min：=maxlongint，第一天比较的时候会多加一个k，所以在最后应该再减去一个k。

代码

var ans:array[1..100,1..100]of longint;
    f:array[0..100]of longint;
    use,v:array[1..100]of boolean;
    can:array[1..20,1..100]of boolean;
    dist:array[1..20]of longint;
    map:array[1..20,1..20]of longint;
    min,a,b,c,n,m,k,e,i,d,j:longint;

procedure dijkstra;
var i,j,min,minj:longint;
begin
  for i:=1 to m do begin dist[i]:=maxint;v[i]:=false;end;
  dist[1]:=0;
  for i:=1 to m-1 do
    begin
      min:=maxint;
      for j:=1 to m do
        if (not v[j])and(not use[j])and(min>dist[j]) then
          begin
            min:=dist[j];
            minj:=j;
          end;
     if minj=m then exit;
      v[minj]:=true;
      for j:=1 to m do
        if (not v[j])and(map[minj,j]>0)then
          if (dist[j]>dist[minj]+map[minj,j]) then
            dist[j]:=dist[minj]+map[minj,j];
    end;
end;

procedure get_ans;
var i,j,p,k:longint;
begin
  for i:=1 to n do
    for j:=1 to n do
     begin
       fillchar(use,sizeof(use),false);
       for k:=i to j do
         for p:=1 to m do
          if can[p,k] then use[p]:=true;
       dijkstra;
       ans[i,j]:=dist[m];
     end;
end;

begin

  readln(n,m,k,e);
  for i:=1 to e do
    begin
      readln(a,b,c);
      map[a,b]:=c;
      map[b,a]:=c;
    end;
  readln(d);
  for i:=1 to d do
    begin
      readln(c,a,b);
      for j:=a to b do can[c,j]:=true;
    end;

  get_ans;

  f[0]:=0;
  for i:=1 to n do
    begin
      min:=maxlongint;
      for j:=1 to i do
         begin
        if min>f[j-1]+ans[j,i]*(i-j+1)+k
         then min:=f[j-1]+ans[j,i]*(i-j+1)+k;
        end;
      f[i]:=min;
    end;

  write(f[n]-k);
end.


评测结果：Accepted 
得分：　　100
提交时间：2015-10-17 17:50 耗时：137ms
内存：3182kb 点击进入记录列表。

 编译信息 Compiling
编译成功
 评测结果 Result
测试点 #1：通过该测试点。 得分10，耗时0ms，内存3149kB。
测试点 #2：通过该测试点。 得分10，耗时0ms，内存3149kB。
测试点 #3：通过该测试点。 得分10，耗时0ms，内存3129kB。
测试点 #4：通过该测试点。 得分10，耗时0ms，内存3158kB。
测试点 #5：通过该测试点。 得分10，耗时15ms，内存3162kB。
测试点 #6：通过该测试点。 得分10，耗时15ms，内存3149kB。
测试点 #7：通过该测试点。 得分10，耗时15ms，内存3174kB。
测试点 #8：通过该测试点。 得分10，耗时15ms，内存3174kB。
测试点 #9：通过该测试点。 得分10，耗时31ms，内存3166kB。
测试点 #10：通过该测试点。 得分10，耗时46ms，内存3182kB。