67.防止重复的案例

--自己做编号,防止冲突的处理

--处理示例1(用主键/唯一键)

--得到最新编号的函数
create function f_newid()
returns char(7)	--编号位数固定,用char的检索效率高于varchar
as
begin
	declare @re char(7)
	select @re=max(BHID) from 表 
	return(
		case when @re is null then 'BH00001'
			else 'BH'+right('0000'+cast(cast(right(@re,5) as int)+1 as varchar),5) 
		end)
end
go

--测试的表,表名与函数中的表名对应
create table 表(
BHID char(7) default dbo.f_newid()	--设置默认值,自动生成编号
	primary key,  --设置成主键,防止编号冲突
--	constraint UNIQUE_BHID_表 unique,	--如果用唯一约束,则删除上面的主键约束语句,改用此句
txt1 varchar(10),
txt2 varchar(10),
num  float)
go

/*--插入数据时,就可以不理会编号字段,直接用这样的语句
	多用户同时插入时,如果编号重复,就会有错误发生
	此时,前台程序拦截错误,如果是违反约束的错误
	只需要重新执行插入的语句即可,此时的编号会自动再重新生成
	而重新执行插入语句也很方便,因为根本就不需要改语句
--*/
insert 表(txt1,txt2,num) values('aa','bb',1)

go
--删除测试
drop table 表
drop function f_newid




--处理示例2(用表级锁)

--得到最新编号的函数
create function f_newid()
returns char(7)	--编号位数固定,用char的检索效率高于varchar
as
begin
	declare @re char(7)
	select @re=max(BHID) from 表(tablockx) --加表级锁
	return(
		case when @re is null then 'BH00001'
			else 'BH'+right('0000'+cast(cast(right(@re,5) as int)+1 as varchar),5) 
		end)
end
go

--测试的表,表名与函数中的表名对应
create table 表(
BHID char(7) default dbo.f_newid()	--设置默认值,自动生成编号
txt1 varchar(10),
txt2 varchar(10),
num  float)
go

--用事务/配合函数中的锁,就可以实现在插入时锁定表
begin tran
insert 表(txt1,txt2,num) values('aa','bb',1)
commit tran

go
--删除测试
drop table 表
drop function f_newid



/*--关于两种方法:

设置主键或唯一键的处理效率是最高的,因为在处理数据的同时,其他用户还可以浏览数据,

如果不用主键或唯一键,就要用表级锁,而用表级锁,在锁定时,其他用户是不能做任何操作的,这样在多用户环境下,进程肯定容易堵塞,造成千军万马过独木桥的情况.
--*/