55.使用编号表生成流水号的案例

最新推荐文章于 2024-02-29 17:59:48 发布

huang714

最新推荐文章于 2024-02-29 17:59:48 发布

阅读量197

点赞数

分类专栏： SQL Server 语句实现初学者学习SQL SERVER 文章标签： SQL 语句-使用编号表生成流水号的案例

本文链接：https://blog.youkuaiyun.com/huang714/article/details/88012162

版权

SQL Server 语句实现同时被 2 个专栏收录

295 篇文章

订阅专栏

初学者学习SQL SERVER

288 篇文章

订阅专栏

本文介绍了一个使用SQL Server实现的自动编号生成系统。该系统通过存储过程在数据库中生成唯一编号，适用于多种业务场景，如采购订单、进仓单等。每次调用存储过程将返回一个新的编号，确保了编号的唯一性和连续性。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

--编号表
CREATE TABLE tb_NO(
Name char(2) PRIMARY KEY,               --编号种类的名称
Head nvarchar(10) NOT NULL DEFAULT '',  --编号的前缀
CurrentNo int NOT NULL DEFAULT 0,       --当前编号
BHLen int NOT NULL DEFAULT 6,           --编号数字部分长度
DESCRIPTION NVARCHAR(50))               --编号种类说明

INSERT tb_NO SELECT 'CG','CG',0,4,N'采购订单'
UNION  ALL   SELECT 'CJ','CJ',0,4,N'采购进货'
UNION  ALL   SELECT 'JC','JC',0,4,N'进仓单'
UNION  ALL   SELECT 'ZC','ZC',0,4,N'转仓单'
UNION  ALL   SELECT 'CC','CC',0,4,N'出仓单'
GO

--获取新编号的存储过程
CREATE PROC p_NextBH
@Name char(2),           --编号种类
@BH nvarchar(20) OUTPUT --新编号
AS
BEGIN TRAN
	UPDATE tb_NO WITH(ROWLOCK) SET 
		@BH=Head+RIGHT(POWER(10,BHLen)+CurrentNo+1,BHLen),
		CurrentNo=CurrentNo+1
	WHERE Name=@Name
COMMIT TRAN
GO

--获取 CJ 的新编号
DECLARE @bh char(6)
EXEC p_NextBH 'CJ',@bh OUT
SELECT @bh
--结果: CJ0001

EXEC p_NextBH 'CJ',@bh OUT
SELECT @bh
--结果: CJ0002
GO

--获取 CC 的新编号
DECLARE @bh char(6)
EXEC p_NextBH 'CC',@bh OUT
SELECT @bh
--结果: CC0001

EXEC p_NextBH 'CC',@bh OUT
SELECT @bh
--结果: CC0002