9.工作日处理函数（标准节假日）

最新推荐文章于 2024-05-21 14:23:18 发布

huang714

最新推荐文章于 2024-05-21 14:23:18 发布

阅读量565

点赞数

CC 4.0 BY-SA版权

分类专栏： SQL Server 语句实现初学者学习SQL SERVER 文章标签： SQL语句-作日处理函数（标准节假日）

本文链接：https://blog.youkuaiyun.com/huang714/article/details/87911010

SQL Server 语句实现同时被 2 个专栏收录

295 篇文章

订阅专栏

初学者学习SQL SERVER

288 篇文章

订阅专栏

本文介绍了一种在SQL中计算两个日期间的工作日数量的方法，并提供了一个函数用于在指定日期基础上增加工作日得到新的日期。这些函数对于业务系统中涉及工作日计算的场景非常实用。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[f_WorkDay]') and xtype in (N'FN', N'IF', N'TF'))
drop function [dbo].[f_WorkDay]
GO

--计算两个日期相差的工作天数
CREATE FUNCTION f_WorkDay(
@dt_begin datetime,  --计算的开始日期
@dt_end  datetime    --计算的结束日期
)RETURNS int
AS
BEGIN
	DECLARE @workday int,@i int,@bz bit,@dt datetime
	IF @dt_begin>@dt_end
		SELECT @bz=1,@dt=@dt_begin,@dt_begin=@dt_end,@dt_end=@dt
	ELSE
		SET @bz=0
	SELECT @i=DATEDIFF(Day,@dt_begin,@dt_end)+1,
		@workday=@i/7*5,
		@dt_begin=DATEADD(Day,@i/7*7,@dt_begin)
	WHILE @dt_begin<=@dt_end
	BEGIN
		SELECT @workday=CASE 
			WHEN (@@DATEFIRST+DATEPART(Weekday,@dt_begin)-1)%7 BETWEEN 1 AND 5
			THEN @workday+1 ELSE @workday END,
			@dt_begin=@dt_begin+1
	END
	RETURN(CASE WHEN @bz=1 THEN -@workday ELSE @workday END)
END
GO



/*=================================================================*/

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[f_WorkDayADD]') and xtype in (N'FN', N'IF', N'TF'))
drop function [dbo].[f_WorkDayADD]
GO

--在指定日期上,增加指定工作天数后的日期
CREATE FUNCTION f_WorkDayADD(
@date    datetime,  --基础日期
@workday int       --要增加的工作日数
)RETURNS datetime
AS
BEGIN
	DECLARE @bz int
	--增加整周的天数
	SELECT @bz=CASE WHEN @workday<0 THEN -1 ELSE 1 END
		,@date=DATEADD(Week,@workday/5,@date)
		,@workday=@workday%5
	--增加不是整周的工作天数
	WHILE @workday<>0 
		SELECT @date=DATEADD(Day,@bz,@date),
			@workday=CASE WHEN (@@DATEFIRST+DATEPART(Weekday,@date)-1)%7 BETWEEN 1 AND 5
				THEN @workday-@bz ELSE @workday END
	--避免处理后的日期停留在非工作日上
	WHILE (@@DATEFIRST+DATEPART(Weekday,@date)-1)%7 in(0,6) 
		SET @date=DATEADD(Day,@bz,@date)
	RETURN(@date)
END