关于ActionScript3中的fl.transitions.Tween类应用时的注意事项

fl.transitions.Tween 是Flash 自带的缓动类。

我们有各种各样的声明方法。以下这种是最常见的。

var tween:Tween = new Tween(myMc, "x", Regular.easeIn,10, 100, 1, true);

当我们要对这个MC的横坐标，纵坐标，透明度同时进行缓动操作时我们经常是这样做的。

1.

var tweenX:Tween = new Tween(myMc, "x", Regular.easeIn,10, 100, 1, true);

var tweenY:Tween = new Tween(myMc, "y", Regular.easeIn,10, 200, 1, true);

var tweenAlpha:Tween = new Tween(myMc, "alpha", Regular.easeIn,0.1, 1, 1, true);

但是还有些人是这么干的。

2.

new Tween(myMc, "x", Regular.easeIn,10, 100, 1, true);

new Tween(myMc, "y", Regular.easeIn,10, 200, 1, true);

new Tween(myMc, "alpha", Regular.easeIn,0.1, 1, 1, true);

这个人在想，反正就执行一次用不着声明变量。

※其实第二种写法是非常危险的。这种写法会导致缓动在中途停止。当然这种停止未必发生，是有一定概率的，而且这个概率相当高。

下面看一个例子。

看到了吧，声明了２０００个实例，结果最终输出１１０７个终止信号。

那其它８９３个哪里去了？　而且运行效果上看，虽然已经经过足够长时间，但还是存在一些浅色斑点。

如果２０００个缓动全部结束，应该全是深色斑点。

事实上好多缓动对象被GC回收了。

影响GC回收的因素有很多，说白了就是，用不上了就回收。

在第５１行的代码里的最后一个参数是true说明这个Tween对象内部里监听EnterFrame事件时使用的是弱引用。

如果是false则使用强引用。那用强引用就可以解决问题了吗？

看上去完成的数量明显提升，而且，貌似浅色的点基本上看不到了。

但还是有８个tween没有完成。

那８个还是被GC回收了。

所以使用tween时一定要在缓动执行期间保持对其的引用。才能避免被GC

最简单的办法就是放在一个数组里。

放入数组中后２０００次的缓动完美完成。

而且即便使用弱引用，也可以完美完成。

当然要注意当所有缓动完成之后别忘了释放那个数组。不然有可能会导致内存泄露。

附上测试用的源代码：

package 
{
	import flash.display.*;
	import flash.events.TimerEvent;
	import flash.utils.Timer;
	import fl.transitions.*;
	import fl.motion.easing.Quadratic;

	public class TweenScript extends MovieClip
	{
		// 计数器
		private var counter:int=0;
		private var arry:Array = new Array;
		
        /**
		*  构造函数
		**/
		public function TweenScript()
		{
			init();
		}

        /**
		*  初始化函数
		**/
		private function init()
		{
			stage.frameRate = 30;
			//每隔100毫秒生成一个Twenn对象直到生成1000个
			var myTimer:Timer = new Timer(50,2000);
			myTimer.addEventListener("timer", createTween);
			myTimer.start();
		}
		
		/**
		*  创建缓动
		**/
		function createTween(evt:TimerEvent=null)
		{
			//生成Sprite对象，并创建缓动
			var spr:Sprite = new Sprite();
			var shape:Shape = new Shape();
			var gra:Graphics = shape.graphics;
			gra.beginFill(0x0066FF);
			gra.drawCircle(0,0,5);
			spr.addChild(shape);
			addChild(spr);
			spr.x = Math.random() * 500;
			spr.y = Math.random() * 500;
			//Tween生成
			var twn:Tween = new Tween(spr,"alpha",Quadratic.easeInOut,0,1,10,true);
			twn.addEventListener(TweenEvent.MOTION_FINISH, onFinish);
			arry.push(twn);

		}

		/**
		*  缓动结束时，输出计数器数
		**/
		function onFinish(evt:TweenEvent):void
		{
			trace("Finish", ++counter);
		}

	}

}